MPE-Debug-Start

@echo off
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
::   MPE-Debug-Start.bat
::
::   Version 1.0.0.0, 02.06.2021
::
::   Copyright (c) by Rainer Ullrich, rainer@rainerullrich.de
::
::   Fehler-Reports oder Wünsche bitte per E-Mail an mich, da ich in Foren nicht mehr lese!
::
::   latest version/letzte Version:
::   https://pastebin.com/fjXt5pyi
::
::
::   -- Funktion --
::   Hilfsbatch für den installierten "My Phone Explorer", kurz MPE   https://www.fjsoft.at/
::
::   Startet den MyPhoneExplorer mit dem Switch "debug". Anschließend werden die beiden Dateien Debug.txt
::   und AndroidDebug.txt (sofern vorhanden) in ein pro Aufruf neu angelegtes Sicherungsverzeichnis (Datum
::   und Uhrzeit) gesichert und am Ende dieses Verzeichnis geöffnet.
::
::   Voreingestellt ist, dass diese Sicherungen in ein [Unter-]Verzeichnis "_DebugLogs_" gespeichert werden.
::   Diess Verzeichnis wird im MPE-Datenbank-Verzeichnis angelegt.
::
::   Außerdem wird eine Warnung ausgegeben, wenn in den Einstellungen vom MPE "Logdatei mitschreiben" bisher
::   nicht aktiviert war.
::
::
::   -- Parameter --
::   derzeit keine
::
::
::   -- Hinweis --
::   derzeit keine
::
::
::   -- History --
::   V1.0.0.0, 01.06.2021:
::     - Initial-Version, getestet Winows 7 und 10, jeweils 64 bit
::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::


:: ----- Variable vom Benutzer zu setzen/zu modifizieren - Beginn -----
::
:: Backup-Hauptverzeichnis, in das die Log-Dateien datumabhängig in Unter-Verzeichnisse gesichert werden sollen
set BackupSubDir=_DebugLogs_
::
:: ----- Variable vom Benutzer zu setzen/zu modifizieren - Ende -----


:: --- Voraussetzungen überprüfen ---
:: Überschrift setzen
title MyPhoneExplorer Debug-Start
mode con:cols=120 lines=36
cls

:: Schauen, ob MyPhoneExplorer schon läuft
tasklist|find /i "MyPhoneExplorer.exe" >nul: 2>&1
if %errorlevel% == 0 (
  call :Fehler "Der MyPhoneExplorer laeuft gerade! Bitte den MPE beenden und mittels dieser Batch starten!"
  exit /b 1
)

:: MyPhoneExplorer-Programm setzen
set MPEprog=%ProgramFiles(x86)%\MyPhoneExplorer\MyPhoneExplorer.exe
:: Überprüfen, ob das Programm installiert ist
if not exist "%MPEprog%" (
  call :Fehler "Der erwartete Pfad des MyPhoneExplorer-Programmes '%MPEprog%' existiert nicht!"
  exit /b 1
)
echo MPE-Progamm:        %MPEprog%

:: MyPhoneExplorer-Database-Pfad aus der Registry auslesen und um "MyPhoneExplorer" ergänzen (default ist der Key leer!)
FOR /F "tokens=2* delims=    " %%a IN ('REG QUERY "HKEY_CURRENT_USER\Software\MyPhoneExplorer" /v Database 2^>NUL') DO SET MPEdbPath=%%b
if "%MPEdbPath%"=="" set MPEdbPath=%appdata%
SET MPEdbPath=%MPEdbPath%\MyPhoneExplorer
:: Überprüfen, ob der erwartete Pfad auch wirklich existiert
if not exist "%MPEdbPath%" (
  call :Fehler "Der erwartete Database-Pfad '%MPEdbPath%' existiert nicht!"
  exit /b 1
)
echo MPE-Datenbank:      %MPEdbPath%

:: Sicherungs-Haupt-Verzeichnis setzen
set SaveMainDir=%MPEdbPath%\%BackupSubDir%
:: wenn das Verzeichnis nicht existiert, anlegen
if not exist "%SaveMainDir%" mkdir "%SaveMainDir%"
if not exist "%SaveMainDir%" (
  call :Fehler "Das Backup-Hauptverzeichnis '%SaveMainDir%' konnte nicht erzeugt werden!"
  exit /b 1
)
echo Backup-Verzeichnis: %SaveMainDir%

:: "Logdatei mitschreiben" in den MPE-Einstellungen aktiviert?
:: Datei
set IniFile=%MPEdbPath%\general.ini
:: Key
set IniKey=Log=
if not exist "%IniFile%" (
  call :Fehler "Die MPE-general.ini '%IniFile%' ist nicht am erwarteten Platz!"
  exit /b 1
)
for /f "delims=" %%F in ('findstr /B /i /c:"%IniKey%" "%IniFile%"') do set IniValue=%%F
if "%IniValue%"=="Log=1" (
  echo Mitloggen:          ist aktiviert
) else (
  echo Mitloggen:          ist deaktiviert
  call :Fehler "Bitte 'Logdatei mitschreiben' in den MPE-Einstellungen unter 'Verbindungen' aktivieren und Batch neu starten!" "Der MyPhoneExplorer wird nach Tastendruck gestartet!"
)


:: --- MyPhoneExplorer mit Debug-Switch starten ---
echo.
echo MyPhoneExplorer mit Debug-Switch starten...
"%MPEprog%" debug
echo MyPhoneExplorer beendet!


:: --- Debug-Dateien umkopieren ---
echo.
:: Datum und Uhrzeit für Verzeicnis ermitteln
set yyyymmddhhmmss=%date:~6,4%.%date:~3,2%.%date:~0,2%_%time:~0,2%.%time:~3,2%.%time:~6,2%
:: Blank durch Null ersetzen, also bei 1-stelliger Stundenzahl
set yyyymmddhhmmss=%yyyymmddhhmmss: =0%

:: Sicherungs-Unter-Verzeichnis setzen
set SaveSubDir=%SaveMainDir%\%yyyymmddhhmmss%
:: Das Unter-Verzeichnis anlegen
if not exist "%SaveSubDir%" mkdir "%SaveSubDir%"
if not exist "%SaveSubDir%" (
  call :Fehler "Das Backup-Unterverzeichnis '%SaveSubDir%' konnte nicht erzeugt werden!"
  exit /b 1
)

:: Dateien umkopieren
echo Dateien nach '%SaveSubDir%' umkopieren...
if exist "%MPEdbPath%\Debug.txt" (
  echo  Debug.txt
  copy "%MPEdbPath%\Debug.txt" "%SaveSubDir%\"
) else (
  echo  Debug.txt existiert nicht!
)
if exist "%MPEdbPath%\AndroidDebug.txt" (
  echo  AndroidDebug.txt
  copy "%MPEdbPath%\AndroidDebug.txt" "%SaveSubDir%\"
) else (
  echo  AndroidDebug.txt existiert nicht!
)


:: --- Ins Verzeichnis wechseln und Explorer starten ---
echo.
echo Sicherungs-Verzeichnis oeffnen...
cd /d "%SaveSubDir%"
explorer .
echo fertig!

:ENDE
cd /d %~dp0
echo.
echo.
echo Ende der MPE-Debug-Start.bat
echo.
echo.
pause

exit /b 0


:: --------------------------------- Sub-Routine[n] ---------------------------------

:: Fehler <Fehlermeldung> <Tastentext>
:Fehler
set KeyText=%~2
if "%KeyText%"=="" set KeyText=Press any key to exit...
echo.
:: color CF
color FC
echo ERROR:
echo  %~1
echo.
echo.
echo %KeyText%
pause >nul: 2>&1
color 0F
goto :EOF