prontera,155,181,5	script	Sample	757,{
mes "This is Lotti Girl";

for( set .@i,0; .@i < getarraysize( .limited_item_list ); set .@i,.@i + 1 )
	if( .limited_item_duration[.@i] < gettimetick(2) ){
		deletearray .limited_item_list[.@i],1;
		deletearray .limited_item_duration[.@i],1;
	}else{
		mes "Limited Item: ^FF0000"+getitemname( .limited_item_list[.@i] )+"^000000";
	}
set .@limited_item_size,getarraysize( .limited_item_list );

switch( select( "Exchange for Lottery Prize",( getgmlevel() < .gm_level )?"":"^0055FF[GM] Manage Limited Item^000000","Close" ) ){
	Case 1:
		if( countitem( .item[0] ) < .item[1] ){
			mes "You need ^0055FF"+.item[1]+" x "+getitemname( .item[0] )+"^000000";
		}else{
			delitem .item[0],.item[1];
			set .@rate,rand(100);
			if( .@rate < .limited_item_rate && .@limited_item_size ){
				set .@gain_item,.limited_item_list[ rand( .@limited_item_size ) ];
			}else{
				set .@gain_item,.lotti_item[ rand( .lotti_item_size ) ];
			}
			mes "Gained ^0055FF"+getitemname( .@gain_item )+"^000000.";
			announce strcharinfo(0)+" gained "+getitemname( .@gain_item )+" from Lotti Girl.",0;
			getitem .@gain_item,1;
		}
		break;
	Case 2:
		switch( select( ( .@limited_item_size >= .max_limited_item )?"":"Add Items",( !.@limited_item_size )?"":"Delete Items" ) ){
			Case 1:
				mes "Enter Item ID";
				do{
					input .@item_id,0,32767;
					if( !.@item_id ) close;
				}while( getitemname( .@item_id ) == "null" );
				mes "Enter Expiration Hours";
				mes "24 = 1 day ^777777(Max:30day)^000000";
				input .@hour,1,5040;
				next;
				mes "Item : "+getitemname( .@item_id )+"^000000";
				mes "Expire : ^0055FF"+.@hour+" Hours^000000";
				if( select( "Confirm","Close" ) == 1 ){
					set .limited_item_list[.@limited_item_size],.@item_id;
					set .limited_item_duration[.@limited_item_size],( gettimetick(2) + ( 3600 * .@hour ) );
					mes "Item Added.";
				}
				break;
			Case 2:
				mes "Select an Item to remove.";
				for( set .@i,0; .@i < getarraysize( .limited_item_list ); set .@i,.@i + 1 )
					set .@menu$,.@menu$ + getitemname( .limited_item_list[.@i] ) +":";
				set .@i,select( .@menu$ ) - 1;
				mes "Deleted "+getitemname( .limited_item_list[.@i] )+" from the list.";
				deletearray .limited_item_list[.@i],1;
				deletearray .limited_item_duration[.@i],1;
			default: break;
		}
	default: break;
}
close;

OnInit:
// lottery item + amount
setarray .item,512,2;
// GM Level
set .gm_level,90;
// Lottery Item Lists
setarray .lotti_item,512,607,608,501;
set .lotti_item_size,getarraysize( .lotti_item );

// Maximum of Limited Item
set .max_limited_item,3;
// Chance to gain limited items.
set .limited_item_rate,5;
end;
}