dialog ctrlchannel {
  title "Control Channel"
  size -1 -1 328 165
  option dbu
  tab "Channel Actions", 1, 3 5 320 155
  list 5, 253 29 65 129, tab 1 size
  text "Channel List", 6, 254 20 63 8, tab 1 center
  box "Actions", 7, 5 27 246 110, tab 1
  box "", 8, 5 136 246 22, tab 1
  radio "Cambiar modos", 9, 10 46 48 10, group tab 1
  edit "", 10, 63 46 184 10, disable tab 1
  radio "Cambiar Topic", 11, 10 58 50 10, tab 1
  edit "", 12, 63 58 184 10, disable tab 1
  text "Canal Seleccionado:", 13, 10 36 50 8, tab 1
  edit "", 14, 63 35 89 10, tab 1 read
  radio "Cambiar Desc", 15, 10 70 50 10, tab 1
  edit "", 16, 63 70 184 10, disable tab 1
  button "Aplicar", 29, 170 143 37 12, tab 1
  button "Cancelar", 30, 210 143 37 12, tab 1 cancel
  tab "Channel Info", 2
  list 17, 5 21 313 135, read tab 2 size
  tab "Ban List", 3
  list 18, 8 24 255 133, read tab 3 size
  box "Acciones", 19, 267 21 54 136, tab 3
  button "Quitar Ban", 20, 273 34 43 12, tab 3 disable
  tab "User List", 4
  list 21, 8 24 255 133, tab 4 size
  box "Acciones", 22, 267 21 54 136, tab 4
  button "Ban", 23, 273 34 43 12, tab 4 disable
  button "Ban Kick", 24, 273 49 43 12, tab 4 disable
  button "Whois", 25, 273 64 43 12, tab 4 disable
  button "Who", 26, 273 79 43 12, tab 4 disable
  button "WhoWas", 27, 273 94 43 12, tab 4 disable
  button "NS Info", 28, 273 109 43 12, tab 4 disable
}

alias ctrlChnl {
  dialog -mdie ctrlchannel ctrlchannel
}
menu channel {
  .« Control Channel »: ctrlChnl
}
on *:dialog:ctrlchannel:init:0:{
  .enable #ctr.channel
  did -r $dname 5
  list
  .timer 1 3 .disable #ctr.channel
}
on *:dialog:ctrlchannel:sclick:5:{
  did -r $dname 14
  did -r $dname 17
  did -r $dname 18
  did -r $dname 21

  did -b $dname 23
  did -b $dname 24
  did -b $dname 25
  did -b $dname 26
  did -b $dname 27
  did -b $dname 28
  did -b $dname 20

  did -a $dname 14 $did($dname,5).seltext
  .enable #ctr.channel
  .cs info $did($dname,14).text all
  .mode $did($dname,14).text +b
  .who $did($dname,14).text
  .timer 1 3 .disable #ctr.channel
}
on *:dialog:ctrlchannel:sclick:20:{
  .enable #ctr.channel
  mode $did($dname,14).text -b $did($dname,18).seltext
  did -r $dname 18
  .mode $did($dname,14).text +b
  .timer 1 2 .disable #ctr.channel
}

on *:dialog:ctrlchannel:sclick:23:{
  .enable #ctr.channel
  mode $did($dname,14).text +b $address($did($dname,21).seltext,2)
  did -r $dname 18
  .mode $did($dname,14).text +b
  .timer 1 2 .disable #ctr.channel
}
on *:dialog:ctrlchannel:sclick:24:{
  .enable #ctr.channel
  mode $did($dname,14).text +b $address($did($dname,21).seltext,2)
  .timer -m 1 500 kick $did($dname,14).text $did($dname,21).seltext $?="Motivo"
  did -r $dname 18
  .mode $did($dname,14).text +b
  .timer 1 2 .disable #ctr.channel
}
on *:dialog:ctrlchannel:sclick:25:{
  whois $did($dname,21).seltext $did($dname,21).seltext
}
on *:dialog:ctrlchannel:sclick:26:{
  who $did($dname,21).seltext
}
on *:dialog:ctrlchannel:sclick:27:{
  whowas $did($dname,21).seltext
}
on *:dialog:ctrlchannel:sclick:28:{
  ns info $did($dname,21).seltext all
}
on *:dialog:ctrlchannel:sclick:21:{
  if ($did($dname,21).seltext != $null) {
    did -e $dname 23
    did -e $dname 24
    did -e $dname 25
    did -e $dname 26
    did -e $dname 27
    did -e $dname 28
  }
  else {
    did -b $dname 23
    did -b $dname 24
    did -b $dname 25
    did -b $dname 26
    did -b $dname 27
    did -b $dname 28
  }
}

on *:dialog:ctrlchannel:sclick:18:{
  if ($did($dname,18).seltext != $null) {
    did -e $dname 20
  }
  else {
    did -b $dname 20
  }
}
on *:dialog:ctrlchannel:sclick:9:{
  ;LIMPIA LOS TEXTINPUT
  did -r $dname 10
  did -r $dname 12
  did -r $dname 16

  ;DESHABILITA TEXTINPUT Y HABILITA PARA NICK
  did -e $dname 10
  did -b $dname 12
  did -b $dname 16

  ;FOCUS
  did -f $dname 10
}
on *:dialog:ctrlchannel:sclick:11:{
  ;LIMPIA LOS TEXTINPUT
  did -r $dname 10
  did -r $dname 12
  did -r $dname 16

  ;DESHABILITA TEXTINPUT Y HABILITA PARA NICK
  did -b $dname 10
  did -e $dname 12
  did -b $dname 16

  ;FOCUS
  did -f $dname 12
}
on *:dialog:ctrlchannel:sclick:15:{
  ;LIMPIA LOS TEXTINPUT
  did -r $dname 10
  did -r $dname 12
  did -r $dname 16

  ;DESHABILITA TEXTINPUT Y HABILITA PARA NICK
  did -b $dname 10
  did -b $dname 12
  did -e $dname 16

  ;FOCUS
  did -f $dname 16
}
on *:dialog:ctrlchannel:sclick:29:{
  if ($did(10).enabled) {
    .mode $did($dname,14) $did($dname,10)
  }
  if ($did(12).enabled) {
    .topic $did($dname,14) $did($dname,12)
  }
  if ($did(16).enabled) {
    .os set superadmin on
    .cs set $did($dname,14) desc $did($dname,16)
    .timer -m 1 500 .os set superadmin off
  }
}

#ctr.channel off
raw *:*:{
  if ($numeric == 321) { haltdef }
  if ($numeric == 322) {
    did -a ctrlchannel 5 $2
    haltdef
  }
  if ($numeric == 323) { haltdef }
  if ($numeric == 367) {
    did -a ctrlchannel 18 $strip($3)
    haltdef
  }
  if ($numeric == 368) { haltdef }
  if ($numeric == 352) {
    did -a ctrlchannel 21 $strip($6)
    haltdef
  }
  ;  echo #testest $numeric <> $1-
}

on *:notice:*:*:{
  if ($nick == ChanServ) {
    did -a ctrlchannel 17 $strip($1-)
    haltdef
  }
}
#ctr.channel end