fragile_allegiance_scripts2.ahk

;autohotkey script for a keyboard interface emulation in Fragile Allegiance
;works in DosBOX, fullscreen or windowed (possibly coordinates might have to be adjusted)

SetMouseDelay 8

;---------CONFIG

;---------FUNCTIONS

; move cursor to pixel position, absolute value
absMove(x,y)
{
	MouseMove, -1640, -1480, 0, R
	MouseMove, -100, -100, 0, R
	MouseMove, x, y, 0, R
}

rMove(x,y)
{
	MouseMove, x, y, 0, R
}

;when pointing on tile, move to building menu
toBuildMenu()
{
	absMove(575,220)
	Click
	Sleep 450
}

fromBuildMenu()
{
  absMove(540, 440)
  Click
}

toNextBuildScreen()
{
  absMove(400,455)
  Click
}

buildItem(posX, posY, itemX, itemY, howMany, lastItem)
{
  ;select item
  absMove(65 + itemX * 100, 150 + itemY * 105)
  Click

  ;go out of build menu
  absMove(540, 440)
  Click
  Sleep 450

  absMove(posX, posY)
  loop, 25 ; max 25 items
  {
    if howMany < 1
      break

    howMany--

    Click
    Sleep 20
  }
  if lastItem = 0
    toBuildMenu()
}

midBuildItem(itemX, itemY, howMany, lastItem)
{
  buildItem(310, 300, itemX, itemY, howMany, lastItem)
}

lowBuildItem(itemX, itemY, howMany, lastItem)
{
  buildItem(310, 430, itemX, itemY, howMany, lastItem)
}

leftBuildItem(itemX, itemY, howMany, lastItem)
{
  buildItem(100, 300, itemX, itemY, howMany, lastItem)
}

;build up a colony
^a::
  toBuildMenu() ; start in Misc screen

  lowBuildItem(2, 2, 1, 0) ;Asteroid Engine
	lowBuildItem(1, 2, 1, 0) ;Repair
	;lowBuildItem(0, 2, 1, 0) ;Gravity nullifier
  lowBuildItem(2, 1, 1, 0) ;Refuelling depot

  toNextBuildScreen() ; Personell screen
  midBuildItem(0,0,2,0) ;Living quarters
  midBuildItem(2,0,1,0) ; Medical
  midBuildItem(0,1,2,0) ; Pleasure domes
  midBuildItem(1,1,4,0) ; security centres

  toNextBuildScreen() ; Environment screen
  midBuildItem(0,0,2,0) ; radiation filters
  midBuildItem(1,0,2,0) ; air processors
  midBuildItem(2,0,4,0) ; environment controls
  midBuildItem(0,1,2,0) ; hydroponics
  midBuildItem(1,1,2,0) ; hydration plants

  toNextBuildScreen() ; Power screen
  midBuildItem(0,0,1,0) ; power store
  midBuildItem(1,0,25,0) ; solar panels

  toNextBuildScreen() ; mining
  leftBuildItem(1,0,5,0) ; mines
  leftBuildItem(2,0,4,0) ; deep mines
  leftBuildItem(0,2,1,0) ; seismic pen.
  midBuildItem(1,1,5,0) ; p. Storage towers
  lowBuildItem(2,1,1,0) ; ore teleporter

  toNextBuildScreen() ; weapons
  midBuildItem(0,1,10,0) ; anti missile
  midBuildItem(0,2,15,0) ; photon

  toNextBuildScreen() ; Misc
  toNextBuildScreen() ; personell
  toNextBuildScreen() ; environment
  toNextBuildScreen() ; power
  midBuildItem(1,0,25,0) ; more solar panels
  midBuildItem(1,0,25,0) ; more solar panels

  toNextBuildScreen() ; mining
  toNextBuildScreen() ; weapons
  toNextBuildScreen() ; misc
  fromBuildMenu()

return

;to/from planet screen
`::
  absMove(630,110)
  MouseMove,30,0,0,R
  Click
  absMove(320, 240)

return