SteamBackup.cmd

@echo off

:: ######### Configuration ###############

set STEAMDIR=C:\Program Files (x86)\Steam
set SEVENZIPDIR=C:\Program Files\7-Zip
set BACKUPDIR=SteamClientBackup\%date:~-4,4%.%date:~-7,2%.%date:~0,2%_%time:~0,2%.%time:~3,2%
set BACKUPDIR=%BACKUPDIR: =0%

:: #######################################



echo Steam-Backup-Script
echo -------------------

:: Check if Steam is running
tasklist /FO LIST|find "steam.exe" >NUL
if %ERRORLEVEL%==0 (
    echo -Steam is currently running. Please close the application
    echo. to let the backup script continue...
    echo.
    powershell -command "Wait-Process -Name 'steam'"
)


:: ### Steam Client Full ###
::
:: Exclude: game-specific files in steamapps and userdata
echo -Creating SteamClientFull.zip ...
"%SEVENZIPDIR%\7z.exe" a "%BACKUPDIR%\SteamClientFull.zip" "%STEAMDIR%"^
 -x!"Steam\steamapps\common"^
 -x!"Steam\steamapps\*.acf"^
 -x!"Steam\userdata\*\0*\"^
 -x!"Steam\userdata\*\1*\"^
 -x!"Steam\userdata\*\2*\"^
 -x!"Steam\userdata\*\3*\"^
 -x!"Steam\userdata\*\4*\"^
 -x!"Steam\userdata\*\5*\"^
 -x!"Steam\userdata\*\6*\"^
 -x!"Steam\userdata\*\7?*\"^
 -x!"Steam\userdata\*\8*\"^
 -x!"Steam\userdata\*\9*\"^
 -i!"%STEAMDIR%\steamapps\common\Steamworks Shared"^
 -i!"%STEAMDIR%\steamapps\appmanifest_228980.acf" > backup.log 2>&1

"%SEVENZIPDIR%\7z.exe" rn "%BACKUPDIR%\SteamClientFull.zip"^
 "Steamworks Shared" "Steam\steamapps\common\Steamworks Shared"^
 "appmanifest_228980.acf" "Steam\steamapps\appmanifest_228980.acf" >> backup.log 2>&1


:: ### Steam Client Light ###
::
:: Exclude: game-specific files in steamapps and userdata
:: +
:: appcache\httpcache, Backups, depotcache, dumps, logs, steamapps\downloading,
:: steamapps\shadercache, userdata\*\ugcmsgcache
echo -Creating SteamClientLight.zip ...
"%SEVENZIPDIR%\7z.exe" a "%BACKUPDIR%\SteamClientLight.zip" "%STEAMDIR%"^
 -x!"Steam\steamapps\common"^
 -x!"Steam\steamapps\*.acf"^
 -x!"Steam\userdata\*\0*\"^
 -x!"Steam\userdata\*\1*\"^
 -x!"Steam\userdata\*\2*\"^
 -x!"Steam\userdata\*\3*\"^
 -x!"Steam\userdata\*\4*\"^
 -x!"Steam\userdata\*\5*\"^
 -x!"Steam\userdata\*\6*\"^
 -x!"Steam\userdata\*\7?*\"^
 -x!"Steam\userdata\*\8*\"^
 -x!"Steam\userdata\*\9*\"^
 -x!"Steam\steamapps\shadercache"^
 -x!"Steam\steamapps\downloading"^
 -x!"Steam\appcache\httpcache"^
 -x!"Steam\Backups"^
 -x!"Steam\depotcache"^
 -x!"Steam\dumps"^
 -x!"Steam\logs"^
 -x!"Steam\userdata\*\ugcmsgcache"^
 -i!"%STEAMDIR%\steamapps\common\Steamworks Shared"^
 -i!"%STEAMDIR%\steamapps\appmanifest_228980.acf" >> backup.log 2>&1

"%SEVENZIPDIR%\7z.exe" rn "%BACKUPDIR%\SteamClientLight.zip"^
 "Steamworks Shared" "Steam\steamapps\common\Steamworks Shared"^
 "appmanifest_228980.acf" "Steam\steamapps\appmanifest_228980.acf" >> backup.log 2>&1


:: ### Steam Registry keys ###
echo -Backing up Steam Registry keys...
reg export "HKCU\Software\Valve" "%BACKUPDIR%\steam_hkcu.reg" /y >> backup.log 2>&1
reg export "HKLM\SOFTWARE\Wow6432Node\Valve" "%BACKUPDIR%\steam_hklm.reg" /y >> backup.log 2>&1

echo.
echo Backup finished!
timeout /t 4 >> backup.log 2>&1