WTF decorate explosion

//Weapon: Pipebomb
//By: Xaser
//Uses ThingID 1999 and SpawnID 201

ACTOR D2C_Pipebomb : Weapon 25018
{
   Inventory.PickupSound "misc/w_pkup"
   Inventory.PickupMessage "You got a pipebomb!"
   Weapon.AmmoType "D2C_PipebombAmmo"
   Weapon.AmmoGive 1
   Weapon.AmmoUse 1
   Weapon.Kickback 0
   AttackSound "weapons/pbarm"
   Scale 0.1
   + NOALERT
   States
   {
   Spawn:
      PIPB A -1
      Loop
   Ready:
      PIPE A 1 A_WeaponReady
      Loop
   Deselect:
      PIPE A 1 A_Lower
      Loop
   Select:
      PIPE A 1 A_Raise
      Loop
   Fire:
      PIPE BCDEFGH 1
      PIPE Z 8
      PIPE IJKLMNOP 1
      PIPE P 0 A_FireCustomMissile("Pipebomb",0,1,0,0)
      PIPE Q 8 A_PlayWeaponSound("weapons/pbthrow")
      PIPE RSTU 1
      PIPE Z 8
      PIPE P 0 A_GiveInventory("D2C_Detonator")
      PIPE P 0 A_TakeInventory("D2C_Pipebomb")
      PIPE HGFEDCB 1
      PIPE A 4
      PIPE A 4 A_ReFire
      Goto Ready
   }
}

ACTOR D2C_Detonator : Weapon
{
   Weapon.SelectionOrder 1
   Inventory.PickupSound "misc/w_pkup"
   Inventory.PickupMessage "You should not see this message, loser!"
   Weapon.AmmoType "D2C_PipebombAmmo"
   Weapon.AmmoGive 0
   Weapon.AmmoUse 0
   Weapon.Kickback 1000
   AttackSound "weapons/mauler1"
   Scale 0.1
   + NOALERT
   States
   {
   Spawn:
      PIPB A -1
      Loop
   Ready:
      DETO A 1 A_WeaponReady
      Loop
   Deselect:
      DETO A 1 A_Lower
      Loop
   Select:
      DETO A 1 A_Raise
      Loop
   Fire:
      DETO B 2
      DETO B 0 A_AlertMonsters
      DETO B 0 Thing_Projectile(1999,201,0,0,0)
      DETO C 2 Thing_ReMove(1999)
      DETO B 2
      DETO A 8
      DETO DEFGHIJKLMNO 1
      DETO Z 8
      DETO Z 0 A_GiveInventory("D2C_Pipebomb")
      DETO Z 3 A_TakeInventory("D2C_Detonator")
      goto Deselect
   }
}

ACTOR Pipebomb : Rocket
{
    Scale 0.1
    - NOGRAVITY
    // + LOWGRAVITY
    + DOOMBOUNCE
    Damage 0
    ExplosionDamage 255
    ExplosionRadius 128
    SeeSound "weapons/pbbounce"
    DeathSound "weapons/pbbounce"
    Renderstyle Normal
    Alpha 255
    States
    {
    Spawn:
      PIPB A 1 Thing_ChangeTid(0,1999)
      Loop
    Death:
      PIPB A 1
      PIPB A 1 Thing_ChangeTid(0,1999)
      PIPB A 1
      Goto Death+2
    }
}

ACTOR PipebombExplosion
{
    SeeSound "weapons/explode"
    SpawnID 201
    Radius 8
    Height 56
    Speed 0
    ExplosionDamage 255
    ExplosionRadius 192
    States
    {
    Spawn:
        NKXP B 3 BRIGHT
        NKXP C 3 BRIGHT
        NKXP D 3 BRIGHT A_Explode
        NKXP EFGHIJKLMNOPQRSTUV 3 BRIGHT
        Stop
    }
}

ACTOR D2C_PipebombAmmo : Ammo
{
   Inventory.Amount 1
   Inventory.MaxAmount 25
   Ammo.BackpackAmount 1
   Ammo.BackpackMaxAmount 40
   Inventory.Icon PIPBB0
   Inventory.PickupMessage ""
   States
   {
   Spawn:
      PIPB C   -1
   }
}