miopen PKGBUILD

pkgname=miopen
pkgver=3.0.0
pkgrel=2
pkgdesc="AMD's Machine Intelligence Library"
arch=('x86_64')
url="https://github.com/ROCmSoftwarePlatform/MIOpen"
license=('NCSAOSL')
depends=(ocl-icd hip hcc rocblas clang-ocl)
makedepends=(git opencl-headers cmake gcc miopen-deps miopengemm)
source=("MIOpen-roc-${pkgver}.tar.gz::https://github.com/ROCmSoftwarePlatform/MIOpen/archive/roc-${pkgver}.tar.gz")
sha256sums=('7a5e7b6dca1e70d70683c1403d63128e739fe63a7f68d6c9fc7f9a7af1465a5c')

rocmdir="/opt/rocm"

build() {
    mkdir -p "${srcdir}/build"
    cd "${srcdir}/build"

    # compile with HCC
    export CXX="${rocmdir}/hcc/bin/hcc"

    local _cmake_args=(
        -DCMAKE_BUILD_TYPE=Release
        -DCMAKE_INSTALL_PREFIX="${rocmdir}/miopen"
        # Disable looking for .cmake files that are provided with boost>=1.70 (system)
        # so boost 1.64 from ${rocmdir}/miopen-deps is used
        -DBoost_NO_BOOST_CMAKE=ON
        -DMIOPEN_BACKEND=HIP
        -DCMAKE_PREFIX_PATH="${rocmdir}/hcc;${rocmdir}/hip;${rocmdir}/miopen-deps"
        "${srcdir}/MIOpen-roc-${pkgver}"
    )

    cmake ${_cmake_args[@]}

    make
}

package() {
    make -C ${srcdir}/build DESTDIR=${pkgdir} install

    mkdir -p ${pkgdir}/etc/ld.so.conf.d
    cat <<-EOF > ${pkgdir}/etc/ld.so.conf.d/miopen.conf
        ${rocmdir}/miopen/lib/
        EOF
}