Plugin "B"

plugins {
    id 'java'
    id 'com.gradleup.shadow' version '8.3.0'
}

dependencies {
    compileOnly "io.papermc.paper:paper-api:1.21.1-R0.1-SNAPSHOT"
    compileOnly "me.wyne:EdenorRP-api:1.0.0"
    compileOnly "me.wyne:Eden-api:1.8.0"
    implementation "dev.jorel:commandapi-bukkit-shade:9.5.3"

    implementation project(":EdenorDice:api")

    implementation "me.lucko:helper:5.6.14"
    compileOnly "dev.triumphteam:triumph-gui:3.1.10"
    implementation "com.google.inject:guice:7.0.0"

    implementation "me.wyne:WUtils-config:2.6.4"
    implementation "me.wyne:WUtils-log:3.0.5"
    implementation "me.wyne:WUtils-i18n:2.3.8"
}

shadowJar {
    archiveBaseName.set("EdenorDice")
    archiveClassifier.set("")
    def outputDir = project.hasProperty('shadowJarOutputDir') ? project.shadowJarOutputDir : "${buildDir}/libs"
    destinationDirectory = file(outputDir)
    minimize()
    relocate "me.lucko.helper", "me.wyne.edenorp.dice.shadow.lucko.helper"
/*    relocate "dev.triumphteam.gui", "me.wyne.edenorp.dice.shadow.triumphteam.gui"*/
    relocate "com.google.inject", "me.wyne.edenorp.dice.shadow.google.guice"
    relocate "com.google.common", "me.wyne.edenorp.dice.shadow.google.common"
    relocate "dev.jorel.commandapi", "me.wyne.edenorp.dice.shadow.commandapi"
    relocate "me.wyne.wutils", "me.wyne.edenorp.dice.shadow.wutils"
}

def targetJavaVersion = 21
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = "UTF-8"

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}