g-desktop-suite-git

pkgname=g-desktop-suite-git
pkgver=0.3.1.r7.gf62994c
pkgrel=1
pkgdesc="Google Suite as a desktop app. Made possible with Electron."
arch=('any')
url="https://github.com/alexkim205/G-Desktop-Suite"
license=('MIT')
depends=( 'nss' 'libxss' 'gtk3')
makedepends=('git' 'yarn')
provides=("${pkgname%-git}" 'gdesktopsuite')
conflicts=("${pkgname%-git}" 'gdesktopsuite')
source=("${pkgname%-git}::git+https://github.com/alexkim205/G-Desktop-Suite.git")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/${pkgname%-git}"
    export YARN_CACHE_FOLDER="$srcdir/yarn-cache"
    yarn install
    yarn electron-builder -l pacman
}

package() {
    cd "$srcdir/${pkgname%-git}"
    bsdtar -xf dist/*.pacman -C "$pkgdir"

    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/${pkgname%-git}"

    # Link to the binary
    install -d "$pkgdir/usr/bin"
    ln -sf '/opt/G Desktop Suite/gdesktopsuite' "$pkgdir/usr/bin/gdesktopsuite"

    rm "$pkgdir"/.[^.]*
}