SaveStats(playerid)
{
	new query[128], name[MAX_PLAYER_NAME], i = Player[playerid][PlayerGang];
	GetPlayerName(playerid, name, MAX_PLAYER_NAME);
	if(Iter_Contains(Gangs, i) && i != -1)
		format(query, sizeof(query), "UPDATE `member` SET `gang` = %d, `status` = %d, `name` = '%s' WHERE `id` = '%d'", Gang[i][GangID], Player[playerid][PlayerStatus], Escape(name), Player[playerid][PlayerID]);
	else
		format(query, sizeof(query), "UPDATE `member` SET `gang` = -1, `name` = '%s' WHERE `id` = %d", Escape(name), Player[playerid][PlayerID]);
	mysql_query(query, -1, 0, connection);
	return 1;
}

SaveGang(i)
{
	new query[128];
	format(query, sizeof(query), "UPDATE `gang` SET `color` = '%s', `score` = %d WHERE `id` = '%d'", Escape(Gang[i][GangColor]), Gang[i][GangScore], Gang[i][GangID]);
	mysql_query(query, -1, 0, connection);
	return 1;
}

SaveZone(i)
{
	if(GangZone[i][ZoneOwner] != -1 && Iter_Contains(Gangs, GangZone[i][ZoneOwner]))
	{
		new query[128];
		format(query, sizeof(query), "UPDATE `zone` SET `owner` = '%d' WHERE `id` = '%d'", Gang[GangZone[i][ZoneOwner]][GangID], GangZone[i][ZoneID]);
		mysql_query(query, -1, 0, connection);
	}
	return 1;
}

LoadPlayerGang(playerid)
{
	Player[playerid][PlayerGang] = -1;
	Player[playerid][PlayerStatus] = GANG_MEMBER;
	Player[playerid][GangRequest] = -1;
	new name[MAX_PLAYER_NAME], query[128];
	GetPlayerName(playerid, name, MAX_PLAYER_NAME);
	format(query, sizeof(query), "SELECT * FROM `member` WHERE `name` = '%s'", Escape(name));
	mysql_query(query, -1, 0, connection);
	mysql_store_result(connection);
	new count = mysql_num_rows(connection);
	if(count > 0)
	{
		new xz[56], id;
		mysql_fetch_field("gang", xz, connection);
		id = strval(xz);
		foreach(new i : Gangs)
		{
			if(Gang[i][GangID] == id)
			{
				Player[playerid][PlayerGang] = i;
				break;
			}
		}
		mysql_fetch_field("status", xz, connection);
		Player[playerid][PlayerStatus] = strval(xz);
		mysql_fetch_field("id", xz, connection);
		Player[playerid][PlayerID] = strval(xz);
	}
	else
	{
		format(query, sizeof(query), "INSERT INTO `member`(`name`) VALUES ('%s')", Escape(name));
		mysql_query(query, -1, 0, connection);
		Player[playerid][PlayerID] = mysql_insert_id(connection);
	}
	mysql_free_result(connection);
	return 1;
}

SendGangMessage(i, msg[])
{
	foreach(new p : Player)
	{
		if(i == Player[p][PlayerGang])
			SendClientMessage(p, -1, msg);
	}
	return 1;
}

stock Name(playerid)
{
	new name[MAX_PLAYER_NAME];
	GetPlayerName(playerid, name, MAX_PLAYER_NAME);
	return name;
}

public OnFilterScriptInit()
{
	SetTimer("LoadFS", 5000, 0);
	return 1;
}

public OnFilterScriptExit()
{
	AutoSave();
	foreach(new i : GangZones)
	{
		GangZoneDestroy(GangZone[i][ZoneHolder]);
		Area_Delete(GangZone[i][ZoneArea]);
	}
	Iter_Clear(GangZones);
	foreach(new i : Player)
	{
		PlayerTextDrawHide(i, Player[i][TDZone][0]);
		PlayerTextDrawHide(i, Player[i][TDZone][1]);
	}
	KillTimer(AutoSaveTimer);
	print("X-Gang System Filterscript unloaded!\n");
	return 1;
}