plugins {
    java
    id("maven-publish")
    id("gg.essential.defaults")
    id("gg.essential.defaults.loom")
}

version = project.property("mod_version") as String
group = project.property("maven_group") as String

base {
    archivesName.set(project.property("archives_base_name") as String)
}

val targetJavaVersion = 21
java {
    toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    withSourcesJar()
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}


repositories {
    maven { url = uri("https://maven.terraformersmc.com/releases/") }
    maven { url = uri("https://maven.shedaniel.me/") }
    maven { url = uri("https://maven.wispforest.io") }
    maven {
        name = "CottonMC"
        url = uri("https://server.bbkr.space/artifactory/libs-release")
    }
    maven(url = "https://s01.oss.sonatype.org/content/repositories/snapshots/") {
        name = "sonatype-oss-snapshots1"
        mavenContent { snapshotsOnly() }
    }
    mavenCentral()

    // Dev only
    maven { url = uri("https://pkgs.dev.azure.com/djtheredstoner/DevAuth/_packaging/public/maven/v1") }
}

dependencies {
    implementation("org.projectlombok:lombok:1.18.32")
    annotationProcessor("org.projectlombok:lombok:1.18.32")
    // Fabric API
    modImplementation("net.fabricmc.fabric-api:fabric-api:${project.findProperty("fabric_version")}")

    // Mod dependencies
    modApi("com.terraformersmc:modmenu:${project.findProperty("mod_menu_version")}")

    modApi("me.shedaniel.cloth:cloth-config-fabric:${project.findProperty("cloth_config_version")}") {
        exclude(group = "net.fabricmc.fabric-api")
    }

    // owo lib
    modImplementation("io.wispforest:owo-lib:${project.findProperty("owo_version")}")
    annotationProcessor("io.wispforest:owo-lib:${project.findProperty("owo_version")}")
    include("io.wispforest:owo-lib:${project.findProperty("owo_version")}")

    implementation("com.moulberry:mixinconstraints:1.0.1")
    include("com.moulberry:mixinconstraints:1.0.1")

    // MiniMessage
    modImplementation("net.kyori:adventure-platform-fabric:${project.findProperty("minimessage_version")}")
    include("net.kyori:adventure-platform-fabric:${project.findProperty("minimessage_version")}")


    // Dev only
    modRuntimeOnly("me.djtheredstoner:DevAuth-fabric:${project.findProperty("devauth_version")}")
}

tasks.processResources {
    inputs.property("version", project.version)
    inputs.property("minecraft_version", project.property("minecraft_version"))
    inputs.property("loader_version", project.property("loader_version"))
    inputs.property("cloth_config_version", project.property("cloth_config_version"))
    inputs.property("mod_menu_version", project.property("mod_menu_version"))
    inputs.property("owo_version", project.property("owo_version"))
    filteringCharset = "UTF-8"

    filesMatching("fabric.mod.json") {
        expand(
            "version" to project.version,
            "minecraft_version" to project.property("minecraft_version"),
            "fabric_version" to project.property("fabric_version"),
            "loader_version" to project.property("loader_version"),
            "cloth_config_version" to project.property("cloth_config_version"),
            "mod_menu_version" to project.property("mod_menu_version"),
            "owo_version" to project.property("owo_version")
        )
    }
}

tasks.withType<JavaCompile>().configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    options.encoding = "UTF-8"
    options.release.set(targetJavaVersion)
}

//tasks.withType<KotlinCompile>().configureEach {
//    compilerOptions.jvmTarget.set(JvmTarget.fromTarget(targetJavaVersion.toString()))
//}

tasks.jar {
    from("LICENSE") {
        rename { "${it}_${project.base.archivesName}" }
    }
}

// configure the maven publication
publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            artifactId = project.property("archives_base_name") as String
            from(components["java"])
        }
    }

    // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
    repositories {
        // Add repositories to publish to here.
        // Notice: This block does NOT have the same function as the block in the top level.
        // The repositories here will be used for publishing your artifact, not for
        // retrieving dependencies.
    }
}