re-main_menu_redux

newui "main" [
    // segments are independently placed

    if (! $isconnected) [
        // middle-top aligned by default, slightly offset from top, only shows in main menu
        uispace 0 0.04 [
            uialign 0 -1
            uiimage "textures/logo" $ui_default 0 0.9 0.45 [uiimageshadow $ui_menu_s]
        ]
        // center aligned by default, has uifill offset to push it left, only shows in main menu
        if $showmainplayerprev [
            uihlist 0 [
                uiplayerpreview 1 1 $ui_mainw $ui_mainh [
                    uiplayerpreviewmodel (getplayermodel)
                    uiplayerpreviewpattern (getplayerpattern)
                    uiplayerpreviewcolour (getplayercolour -1)
                    uiplayerpreviewteam (getplayerteam 1)
                    uiplayerpreviewweapselect (weapselect)
                    uiplayerpreviewvanity (getplayervanity)
                    uiplayerpreviewweapselect $weapidxmelee
                ] [
                    uipreviewinteractive 1
                    uialtrelease [uipreviewresetoffset]
                    if (! $isconnected) [
                        uipreviewskycol (modcolour (skewcolour $backgroundcolour $colourwhite 0.4) 0.2)
                        uipreviewsuncol (skewcolour $backgroundcolour $colourwhite 0.5)
                        uipreviewsundir 0 1 2
                        uipreviewexcol (modcolour $backgroundcolour 0.4)
                        uipreviewexdir 0 0 -2
                        uipreviewyaw 140
                    ]
                    ui_playerprev_easteregg
                ]
                uifill 0.4
            ]
        ]
        // bottom-left aligned by default, only shows in main menu
        uispace 0.01 0.01 [
            uialign -1 1
            uitext (format "v%1 (%2) %3" $versionstring $versionrelease (
                if $versionbuild [format "[%1:%2]" $versionbranch $versionbuild]
            )) $ui_textsmall
        ]
    ]

    // center aligned by default
    uivlist $ui_padbutton [
        uibuttonm "Play Online" "textures/servers/list" [uiopen "servers"] 0 main_servers
        uibuttonm (? $isconnected "Vote Map/Mode" "Offline Practice") "textures/icons/maps" [uiopen "maps"] 0 main_maps
        uibuttonm "Parkour Challenges" "textures/modes/race" [uiopen "challengemenu"] 0 main_sp
        uifill 0 $ui_padwin
        uibuttonm "Profile Setup" "textures/icons/player" [uiopen "profile"] 0 main_profile
        uibuttonm "Settings" "textures/icons/settings" [uiopen "settings"] 0 main_settings
        uibuttonm "Help and Support" $questiontex [uiopen "help"] 0 main_help
        if $isconnected [
            uibuttonm "Disconnect" "textures/servers/disconnect" [
                if (= $gamemode $modeidxediting) [uiopen "disconnectwarn"] [disconnect]
            ] 0 main_disconnect
        ]
        uibuttonm "Quit" "textures/icons/warning" [
            if (&& (= $gamemode $modeidxediting) $isconnected) [uiopen "quitwarn"] [quit]
        ] 0 main_quit
    ]
]