A charset generated from the C64 default ROM charset

// Done by Scan/Desire
// Compile using KickAssembler
BasicUpstart2(start)

start:          sei
                lda #$33        // make character rom visible
                sta 1
                lda #$d0        // set source/destination
                sta $fc
                lda #$38
                sta $fe
copy:           ldy #$00        // blank out line 0
                tya
                sta ($fd),y
                lda ($fb),y     // copy line 0 to 1
                iny
                sta ($fd),y
                iny
                lda ($fb),y     // copy line 2, mask with 00xxxxxx
                and #%00111111
                sta ($fd),y
                iny             // copy line 3, normal
                lda ($fb),y
                sta ($fd),y
                iny
                lda ($fb),y     // copy line 4, normal
                sta ($fd),y
                iny             // get line 6, put into 5
                iny
                lda ($fb),y
                dey
                sta ($fd),y
                iny             // blank out line 7
                lda #$00
                sta ($fd),y
                iny             // copy line 8
                lda ($fb),y
                sta ($fd),y

                lda $fb         // next char
                clc
                adc #$08
                sta $fb
                sta $fd
                bcc !+
                inc $fc         // increase page
                inc $fe
!:              dex             // not done copying all chars? continue
                bne copy

                // fix up some chars that got ruined
                stx $3800+[63*8]+5
                lda #%01100110
                sta $3800+[42*8]+1
                sta $3800+[42*8]+5
                lda #%00011000
                sta $3800+[44*8]+6
                sta $3800+[59*8]+6
                sta $3800+[63*8]+6
                sta $3800+[58*8]+5
                lda #$37
                sta 1
                lda #$1e
                sta $d018
                cli
                rts