GameMaker LD Tips Functions

//Concatenate a series of arguments into a string
function Concat()
{
    var _string = "";
    for(var i = 0; i < argument_count; i++) _string += string(argument[i]);
    return _string;
}

//Show debug message enhanced with string concatenation
function DebugMessage()
{
    var _string = "";
    for(var i = 0; i < argument_count; i++) _string += string(argument[i]);
    show_debug_message(_string);
}



//Move value towards another value by a given amount
function Approach(_a, _b, _amount)
{
    if (_a < _b)
    {
        _a += _amount;
        if (_a > _b)
            return _b;
    }
    else
    {
        _a -= _amount;
        if (_a < _b)
            return _b;
    }
    return _a;
}

//Sine waves a value between two values over a given time.
function Wave(_from, _to, _duration, _offset)
{
    var a4 = (_to - _from) * 0.5;
    return _from + a4 + sin((((current_time * 0.001) + _duration * _offset) / _duration) * (pi*2)) * a4;
}

//Wraps a value between a minimum and a given wrap point
function Wrap(_value, _minimum, _wrapAt)
{

    var _mod = ( _value - _minimum ) mod ( _wrapAt - _minimum );
    if ( _mod < 0 ) return _mod + _wrapAt else return _mod + _minimum;
}