chcp 65001
echo off

set INPUT="C:\Users\h010c\Desktop\16630916231740.mp4"
set OUTPUTNAME=pypa

rem ====================
rem начало в (формат:00:00:00.000)
set START=00:00:01.000
rem длительность (формат:00:00:00.000)
set LENGTH=00:00:00.220
rem ====================
rem фпс вписать ОБЯЗАТЕЛЬНО
set FPS=fps=25
rem ====================
set FILTER=-filter_complex "%FPS%
rem set FILTER=%FILTER%,crop=iw:19:0:ih/2-19
set FILTER=%FILTER%,scale=200:-1:flags=sinc
set FILTER=%FILTER%"
rem ====================
rem кол-во цветов: 1-256
set COLORS=max_colors=32
rem ====================
rem алгоритмы сглаживания границ шумом
rem dither=bayer:bayer_scale=1
rem dither=bayer:bayer_scale=2
rem dither=bayer:bayer_scale=3
rem dither=floyd_steinberg
rem dither=sierra2
rem dither=sierra2_4a
rem dither=none
set DITHER=dither=bayer:bayer_scale=2
rem ====================
if not "%START%"=="" set START=-ss %START%
if not "%LENGTH%"=="" set LENGTH=-t %LENGTH%

set INPUT=-i %INPUT%
set OUTPUT=%OUTPUTNAME%.gif

..\ffmpeg %START% %LENGTH% %INPUT% %FILTER%[x];[x]palettegen="%COLORS%:reserve_transparent=0" palette.png -y
..\ffmpeg %START% %LENGTH% %INPUT% -i palette.png %FILTER%[x];[x][1:v]"paletteuse=%DITHER%" %OUTPUT% -y
if exist palette.png del palette.png

echo.
echo. [1] Открыть конечный файл
echo. [2] Выход
echo.
choice /C:12 /N /M "Введите выбор: "
if errorlevel 2 exit
if errorlevel 1 (
    start %OUTPUT%
    exit
)