GameMaker: Studio and land of network_ oddities.

/// Client connecting:
socket = network_create_socket(network_socket_tcp)
data = buffer_create(1024, buffer_fixed, 1)
if (network_connect(socket, "127.0.0.1", 7800) >= 0) {
    state = 2
    subst = 1
    buffer_write(data, buffer_u32, game_id & $ffffffff)
    network_send_packet(socket, data, buffer_tell(data))
    text += "Request (" + string(buffer_tell(data)) + ") sent.#"
} else text += "Failed to connect."
/// Client network event:
switch (ds_map_find_value(async_load, "type")) {
case network_type_data:
    var b = ds_map_find_value(async_load, "buffer"),
        n = ds_map_find_value(async_load, "size");
    text += "Response: [" + string(n) + "] "
        + buffer_hex(b, n) + "#";
    break
}

/// Server startup:
listener = network_create_server(network_socket_tcp, 7800, 1)
if (listener >= 0) {
    text += "Up on port 7800.#"
} else text += "Failed to host.#"
/// Server network event:
switch (ds_map_find_value(async_load, "type")) {
case network_type_data:
    var b = ds_map_find_value(async_load, "buffer"),
        n = ds_map_find_value(async_load, "size");
    text += "[" + string(n) + "] "
        + buffer_hex(b, n) + "#";
    text += "Matches: " + string(buffer_read(b, buffer_u32) == game_id) + "#"
    buffer_seek(data, buffer_seek_start, 0)
    buffer_write(data, buffer_u8, $D0)
    text += "Reply (" + string(buffer_tell(data)) + ") sent.#"
    network_send_packet(socket, data, buffer_tell(data))
    break
case network_type_connect: // client joined
    socket = ds_map_find_value(async_load, "socket")
    text += "Client connected.#"
    break
case network_type_disconnect:
    break
}

/// Drawing (same for client and server):
draw_set_font(fnt_test)
draw_text(x, y, text)

/// buffer_hex(buffer, length):
var o = argument0, q = buffer_tell(o), r = "", d, v;
repeat (argument1) {
    v = buffer_read(o, buffer_u8)
    d = v >> 4
    if (d < 10) r += chr(48 + d) else r += chr(55 + d)
    d = v & 15
    if (d < 10) r += chr(48 + d) else r += chr(55 + d)
    r += " "
}
buffer_seek(o, buffer_seek_start, q)
return r