actor SMG : Chaingun
{
	weapon.ammotype "SMGClip"
	weapon.ammouse 1
	weapon.ammogive 0
	weapon.ammotype2 "Clip"
	weapon.ammouse2 1
	weapon.ammogive2 0
	obituary "%o was turned into Swiss cheese by %k's submachinegun."
	+weapon.ammo_optional
	inventory.pickupmessage "You swiped a submachinegun!"
	states
	{
	Spawn:
		TNT1 A 1 A_SpawnItem("SMGPack")
		stop
  	Ready:
		SUBM A 0 A_JumpIfInventory("ReloadSignal", 1, "ReloadStart")
    		SUBM A 1 A_WeaponReady
    		loop
  	Deselect:
    		SUBM A 1 A_Lower
    		loop
  	Select:
    		SUBM A 1 A_Raise
    		loop
	Fire:
		SUBM A 0 A_JumpIfInventory("SMGFireModeSwitcher", 1, "Fire2")
		SUBM A 0 A_JumpIfNoAmmo("ReloadStart")
		SUBM B 0 BRIGHT A_GunFlash
		SUBM B 2 BRIGHT A_FireBullets (5, 5, -1, 5, "R2BulletPuff",1,1536)
    		SUBM CD 1
    		SUBM A 2 A_ReFire
    		goto Ready
	Fire2:
		SUBM A 0 A_JumpIfNoAmmo("ReloadStart")
		SUBM B 0 BRIGHT A_GunFlash
		SUBM B 1 BRIGHT A_FireBullets(2.5, 2.5, -1, 5, "R2BulletPuff", 1, 1536)
		SUBM CD 1
		SUBM B 0 BRIGHT A_GunFlash
		SUBM B 1 BRIGHT A_FireBullets(2.5, 2.5, -1, 5, "R2BulletPuff", 1, 1536)
		SUBM CD 1
		SUBM B 0 BRIGHT A_GunFlash
		SUBM B 1 BRIGHT A_FireBullets(2.5, 2.5, -1, 5, "R2BulletPuff", 1, 1536)
		SUBM CD 1
		SUBM A 10
		goto Ready
	AltFire:
		SUBM A 0 A_JumpIfInventory("SMGFireModeSwitcher", 1, "AltFire2")
		SUBM A 0 A_GiveInventory("SMGFireModeSwitcher", 1)
		SUBM A 17 A_Print("Firing mode switched to 3-shot burst")
		goto Ready
	AltFire2:
		SUBM A 0 A_TakeInventory("SMGFireModeSwitcher", 999)
		SUBM A 17 A_Print("Firing mode switched to fully automatic.")
		goto Ready
	ReloadStart:
		SUBM A 0 A_JumpIfInventory("SMGClip", 0, "Ready")
		SUBM A 0 A_JumpIfInventory("Clip", 1, 1)
		goto Ready
		SUBM AAAAAAAA 1 A_Lower
		goto Reload
	Reload:
		SUBM A 0 A_JumpIfInventory("SMGClip", 0, "ReloadDone")
		SUBM A 0 A_JumpIfInventory("Clip", 1, 1)
		goto ReloadDone
		SUBM A 0 A_GiveInventory("SMGClip", 1)
		SUBM A 0 A_TakeInventory("Clip", 1)
		goto Reload
	ReloadDone:
		SUBM A 16 A_PlaySound("weapons/sshoto")
		SUBM A 1 A_Lower
		SUBM A 16 A_PlaySound("weapons/sshotl")
		SUBM A 1 A_Raise
		SUBM A 16 A_PlaySound("weapons/sshotc")
		SUBM AAAAAAAA 1 A_Raise
		SUBM A 0 A_TakeInventory("ReloadSignal", 999)
		goto Ready
  	Flash:
    		TNT1 A 2 Bright A_Light2
    		TNT1 A 2 Bright A_Light1
    		Goto LightDone
	}
}