LoL Server Ping Checker.bat

:start
@ECHO off
REM League of Legends Ping tester edited by xTheEc0. Original code from PlanetSide 2 Ping Tester by Sh4rkill3rSG
REM IPs copied from https://www.reddit.com/r/leagueoflegends/comments/4efy17/how_to_check_your_ping_without_getting_into_the/
REM which were provided by RIOT Laslow21
ECHO - LoL PING TESTER by xTheEc0 v0.1337
ECHO - IPs copied from https://www.reddit.com/r/leagueoflegends/4efy17/
ECHO ======================================
CALL:pingServer 104.160.141.3
ECHO - EUW: %ms%
CALL:pingServer 104.160.142.3
ECHO - EUNE:%ms%
CALL:pingServer 104.160.131.3
ECHO - NA:  %ms%
CALL:pingServer 104.160.156.1
ECHO - OCE: %ms%
CALL:pingServer 104.160.136.3
ECHO - LAN: %ms%
CALL:pingServer 104.160.152.3
ECHO - BR:  %ms%
ECHO ======================================
ECHO.
ECHO - The listed IPs are of one among the servers used in a cluster.
ECHO - Which is enough to approximately determine the ping.
ECHO.
ECHO  RIOT has ICMP protection so pings may show higher than it would be in game.
ECHO  This tool is to give general idea. Your ingame ping should be +-10ms what is shown here.

timeout 10
cls
goto Start

:pingServer
SET ms=Error
FOR /F "tokens=4 delims==" %%i IN ('ping.exe -n 1 %1 ^| FIND "ms"') DO SET ms=%%i
GOTO:EOF