amiga bootchooser (added fastboot)

C:MakeDir RAM:T RAM:Clipboards RAM:ENV RAM:ENV/Sys
Assign >NIL: ENV: RAM:ENV
Assign >NIL: T: RAM:T

;BEGIN bootrequester
COPY SYS:Prefs/myBoot ENV:
IF EXISTS SYS:Prefs/myFastBoot
  SKIP myFastBoot
ENDIF

IF EXISTS SYS:Prefs/myBoot
  RequestChoice TIMEOUT 2 >ENV:myBootKeep "Keep Conf?" "Boot:$myBoot" "Y" "N" "C"
  IF $myBootKeep EQ 2
    ECHO "*NRemoving Bootchoice"
    DELETE SYS:Prefs/myBoot
  ENDIF
ENDIF

LAB myFastBoot

IF NOT EXISTS SYS:Prefs/myBoot
  RequestChoice TIMEOUT 10 >ENV:myBoot "BootchooserNG" "Default (0/1): Normal Boot*NNoAGA (2): SetPatch NOAGA*NCLI (3): Boot into CLI*N*NYou have 10 seconds!*N aminet.net/package/util/sys/MSys-1.2" "Default" "NoAGA" "CLI" "Cancel"
  COPY ENV:myBoot SYS:Prefs/
ENDIF
;END bootrequester

;BEGIN bootchooser
IF $myBoot EQ 0
  SKIP boot_def
ENDIF
IF $myBoot EQ 1
  SKIP boot_def
ENDIF
IF $myBoot EQ 2
  SKIP boot_noaga
ENDIF
IF $myBoot EQ 3
  SKIP boot_cli
ENDIF
;END bootchooser

;BEGIN bootlabels
LAB boot_def
 ECHO "*NBooting: Default ($myBoot)"
 IF EXISTS S:ss-def
   EXECUTE S:ss-def
 ELSE
   ECHO "*NS:ss-def does not exist! (LoadModule,Turbocards,SetPatch)"
 ENDIF
 SKIP boot_end
LAB boot_noaga
 ECHO "*NBooting: NoAGA ($myBoot)"
 IF EXISTS S:ss-noaga
   EXECUTE S:ss-noaga
 ELSE
   ECHO "*NS:ss-noaga does not exist! (LoadModule,Turbocards,SetPatch)"
 ENDIF
 SKIP boot_end
LAB boot_cli
 ECHO "*NBooting: CLI ($myBoot)"
 IF EXISTS S:ss-cli
   EXECUTE S:ss-cli
 ELSE
   ECHO "*NS:ss-cli does not exist! (LoadModule,Turbocards,SetPatch)"
 ENDIF
 QUIT 0
LAB boot_end
;END bootlabels

CPU CHECKINSTALL