briefcases

#define FILTERSCRIPT
#define BRIEFCASE_MESSAGE  (0xFF9999)
#define MONEY_REWARD_MIN    (2000)
#define MONEY_REWARD_MAX    (5000)
#include <a_samp>
new briefcase;
new Float:pos[][3]={
{2243.7000, 55.1287,    32.4834},
{2270.5710, 73.3599,    31.9834},
{2272.3135, 78.3514,    34.9834},
{2312.5974, 79.4399,    30.4834},
{2331.5508, 43.0789,    32.9884},
{2330.0657, 17.4735,    34.4834},
{2313.0681, -8.5367,    32.5313},
{2331.2292, -15.8728,   29.9844},
{2382.6836, 285.7477,   19.5738},
{2145.4861, 93.0942,    27.1522},
{2315.9138, -181.5118,  29.5580},
{2102.8684, 47.8232,    35.8949},
{2104.8689, 35.7487,    35.7268},
{2161.6460, -102.7084,  2.7500}};

public OnFilterScriptInit()
{
    print("\n--------------------------------------");
    print(" Geldkoffers door [LD]Legodude");
    print("--------------------------------------\n");
    SetTimer("RespawnCase",(random(5)+1)*60000,false);
    return 1;
}

public OnFilterScriptExit()
{
    return 1;
}

forward RespawnCase();
public RespawnCase()
{
    new posid=random(sizeof(pos));
    briefcase=CreatePickup(1210,1,pos[posid][0],pos[posid][1],pos[posid][2]);
    SendClientMessageToAll(BRIEFCASE_MESSAGE,"Een nieuw koffertje is verstopt!");
    return 1;
}

forward OnPlayerPickUpBriefcase(playerid);
public OnPlayerPickUpBriefcase(playerid)
{
    new str[128];
    new prize=random(MONEY_REWARD_MAX-MONEY_REWARD_MIN)+MONEY_REWARD_MIN;
    new name[MAX_PLAYER_NAME];
    GetPlayerName(playerid,name,sizeof(name));
    format(str,sizeof(str),"speler %s heeft het geldkoffertje gevonden!",name);
    SendClientMessageToAll(BRIEFCASE_MESSAGE,str);
    GivePlayerMoney(playerid,prize);
    format(str,sizeof(str),"De inhoud was %i dollar!",prize);
    SendClientMessageToAll(BRIEFCASE_MESSAGE,str);
    SendClientMessageToAll(BRIEFCASE_MESSAGE,"Over enkele minuten zal er een nieuwe worden verstopt.");
    SetTimer("RespawnCase",(random(5)+1)*60000,false);
    DestroyPickup(briefcase);
    return 1;
}


public OnPlayerPickUpPickup(playerid, pickupid)
{
    if(pickupid==briefcase)
    {
        OnPlayerPickUpBriefcase(playerid);
    }
    return 1;
}