Scrolling multiplied texture UI shader

Shader "UI/Scrolling Textures"
{
    Properties
    {
        [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
        [HDR]_Color ("Tint", Color) = (1,1,1,1)

		_UnscaledTimeScale("Unscaled Time Scale", float) = 1
		_Tex1("Layer 1", 2D) = "white" {}
		_Tex2("Layer 2", 2D) = "white" {}
		_Tex3("Layer 3", 2D) = "white" {}
		_Tex4("Layer 4", 2D) = "white" {}

        _StencilComp ("Stencil Comparison", Float) = 8
        _Stencil ("Stencil ID", Float) = 0
        _StencilOp ("Stencil Operation", Float) = 0
        _StencilWriteMask ("Stencil Write Mask", Float) = 255
        _StencilReadMask ("Stencil Read Mask", Float) = 255

        _ColorMask ("Color Mask", Float) = 15

        [Toggle(UNITY_UI_ALPHACLIP)] _UseUIAlphaClip ("Use Alpha Clip", Float) = 0
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Stencil
        {
            Ref [_Stencil]
            Comp [_StencilComp]
            Pass [_StencilOp]
            ReadMask [_StencilReadMask]
            WriteMask [_StencilWriteMask]
        }

        Cull Off
        Lighting Off
        ZWrite Off
        ZTest [unity_GUIZTestMode]
        Blend SrcAlpha OneMinusSrcAlpha
        ColorMask [_ColorMask]

        Pass
        {
            Name "Default"
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma target 2.0

            #include "UnityCG.cginc"
            #include "UnityUI.cginc"

            #pragma multi_compile __ UNITY_UI_CLIP_RECT
            #pragma multi_compile __ UNITY_UI_ALPHACLIP

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
				float2 texcoord2 : TEXCOORD1; // This can also be used as timer set from UI Vertex Effect script
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                float2 texcoord  : TEXCOORD0;
                float4 worldPosition : TEXCOORD1;
				float4 texcoordScrolling12  : TEXCOORD2;
				float4 texcoordScrolling34  : TEXCOORD3;

                UNITY_VERTEX_OUTPUT_STEREO
            };

            fixed4 _Color;
            fixed4 _TextureSampleAdd;
            float4 _ClipRect;

			//Scrolling Textures - Begin:
			sampler2D _Tex1;
			float4 _Tex1_ST;
			sampler2D _Tex2;
			float4 _Tex2_ST;
			sampler2D _Tex3;
			float4 _Tex3_ST;
			sampler2D _Tex4;
			float4 _Tex4_ST;

			float4 _UnscaledTime; // This is something you would like to set if you want your animation to continue if time scale is zero
			float _UnscaledTimeScale;
			//Scrolling Textures - End:

            v2f vert(appdata_t v)
            {
                v2f OUT;
                UNITY_SETUP_INSTANCE_ID(v);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);
                OUT.worldPosition = v.vertex;
                OUT.vertex = UnityObjectToClipPos(OUT.worldPosition);

				OUT.texcoord = v.texcoord;

				//Scrolling Textures - Begin:
				float time = _Time.y + v.texcoord2.x + _UnscaledTime.w * _UnscaledTimeScale;
				OUT.texcoordScrolling12.xy = v.texcoord.xy * _Tex1_ST.xy + _Tex1_ST.zw * time;
				OUT.texcoordScrolling12.zw = v.texcoord.xy * _Tex2_ST.xy + _Tex2_ST.zw * time;
				OUT.texcoordScrolling34.xy = v.texcoord.xy * _Tex3_ST.xy + _Tex3_ST.zw * time;
				OUT.texcoordScrolling34.zw = v.texcoord.xy * _Tex4_ST.xy + _Tex4_ST.zw * time;
				//Scrolling Textures - End:

                OUT.color = v.color * _Color;
                return OUT;
            }

            sampler2D _MainTex;

            fixed4 frag(v2f IN) : SV_Target
            {
                half4 color = (tex2D(_MainTex, IN.texcoord) + _TextureSampleAdd) * IN.color;

				//Scrolling Textures - Begin:
				float4 tex1 = tex2D(_Tex1, IN.texcoordScrolling12.xy);
				float4 tex2 = tex2D(_Tex2, IN.texcoordScrolling12.zw);
				float4 tex3 = tex2D(_Tex3, IN.texcoordScrolling34.xy);
				float4 tex4 = tex2D(_Tex4, IN.texcoordScrolling34.zw);

				color *= tex1 * tex2 * tex3 * tex4 * 8;
				//Scrolling Textures - End:


                #ifdef UNITY_UI_CLIP_RECT
                color.a *= UnityGet2DClipping(IN.worldPosition.xy, _ClipRect);
                #endif

                #ifdef UNITY_UI_ALPHACLIP
                clip (color.a - 0.001);
                #endif

                return color;
            }
        ENDCG
        }
    }
}