DFPR_U2_EA_XXYZ.psdc

// Balam Gonzalez Luis Humberto
// 31/Julio/2018
// UNADM
// PSE Int Algoritmo par calcular Area, Ancho o Altura de un Rectangulo según la entrada
// https://www.patadejaguar.xyz/
Algoritmo AreaRectangulo
	// Definir la variables usadas
	Definir Area Como Real;
	Definir Largo Como Real;
	Definir Ancho Como Real;
	// Inicializar las variables por defecto
	Area <- 0;
	Largo <- 0;
	Ancho <- 0;
	Escribir '-----------------------------';
	Escribir 'Bienvenido a la Caculadora Geo-UNADM 0.0.01';
	Escribir '-----------------------------';
	Escribir 'Ingrese el Area del Rectangulo(Dejar vacio si va a Calcular)';
	Leer Area;
	// Si el Area es menor a cero, obligar capturar Largo y Ancho
	Si Area<=0 Entonces;
		Mientras Largo<=0 Hacer
			Escribir 'Ingrese el [Largo] del Rectangulo';
			Leer Largo;
		FinMientras
		Mientras Ancho<=0 Hacer
			Escribir 'Ingrese el [Ancho] del Rectangulo';
			Leer Ancho;
		FinMientras
		// Ejecutar la funcion debida
		calcAreaRectangulo(Largo,Ancho);
	SiNo
		Escribir 'Ingrese el [Largo] del Rectangulo(Dejar vacio si va a Calcular)';
		Leer Largo;
		// Si Largo es menor a Cero, Obligar la entrada de Ancho
		Si Largo<=0 Entonces
			Mientras Ancho<=0 Hacer
				Escribir 'Ingrese el [Ancho] del Rectangulo';
				Leer Ancho;
			FinMientras
			// Ejecutar la funcion para calcular el Largo
			calcLargoRectangulo(Area,Ancho);
		SiNo
			// Si Area es mayor a cero y Largo tambien
			calcAnchoRectangulo(Area,Largo);
		FinSi
	FinSi
FinAlgoritmo

Funcion calcAreaRectangulo(Largo1,Ancho1)
	Definir Resultado Como Real;
	Resultado <- Largo1*Ancho1;
	Escribir 'El Area del rectangulo es : ',Resultado;
FinFuncion

Funcion calcLargoRectangulo(Area2,Ancho2)
	Definir Resultado Como Real;
	Resultado <- Area2/Ancho2;
	Escribir 'El Largo del rectangulo es : ',Resultado;
FinFuncion

Funcion calcAnchoRectangulo(Area3,Largo3)
	Definir Resultado Como Real;
	Resultado <- Area3/Largo3;
	Escribir 'El Ancho del rectangulo es : ',Resultado;
FinFuncion