pkgbase=freeciv-git
pkgname=('freeciv-git' 'freeciv-sdl-git' 'freeciv-qt-git')
pkgver=2.6
pkgrel=1
pkgdesc='A multiuser clone of the famous Microprose game of Civilization'
arch=('i686' 'x86_64')
url='http://freeciv.org'
license=('GPL')
depends=('hicolor-icon-theme' 'sdl_mixer')
makedepends=('git' 'curl' 'libtool' 'python' 'gtk3' 'qt5-base' 'sdl2_image' 'sdl2_mixer' 'sdl2_gfx' 'sdl2_ttf')
conflicts=('freeciv' 'freeciv-svn' 'freeciv-sdl')
options=('!libtool')
source=('git+https://github.com/freeciv/freeciv.git')
sha256sums=('SKIP')

prepare() {
  cd freeciv

  autoreconf -vi
}

build() {
  cd freeciv

  ./configure --prefix=/usr --sysconfdir=/etc --enable-shared \
    --enable-client=gtk3,sdl2,qt

  make -j5
}

package_freeciv-git() {
  depends=('gtk3' 'sdl2_mixer')
  conflicts=('freeciv-sdl2-git' 'freeciv-qt-git')

  cd freeciv

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/bin/freeciv-{sdl2,qt}
  rm -rf "${pkgdir}"/usr/share/applications/freeciv-{sdl2,qt}.desktop
}

package_freeciv-sdl-git() {
  depends=('sdl2_image' 'sdl2_mixer' 'sdl2_gfx' 'sdl2_ttf')
  conflicts=('freeciv-git' 'freeciv-qt-git')

  cd freeciv

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/bin/freeciv-{gtk3,qt}
  rm -rf "${pkgdir}"/usr/share/applications/freeciv{,-qt}.desktop
}

package_freeciv-qt-git() {
  depends=('qt5-base' 'sdl2_mixer')
  conflicts=('freeciv-git' 'freeciv-sdl-git')

  cd freeciv

  make DESTDIR="${pkgdir}" install

  rm -rf "${pkgdir}"/usr/bin/freeciv-{sdl2,gtk3}
  rm -rf "${pkgdir}"/usr/share/applications/freeciv{,-sdl2}.desktop
}

# vim: ts=2 sw=2 et: