getDriversPlace

function getDriversPlace() {
    static
        Float: s_fDist[MAX_PLAYERS],
        s_iCP[MAX_PLAYERS],
        s_iRank[MAX_PLAYERS]
    ;
    foreach(new playerid : g_itrRacers) {
        s_iCP[playerid] = GetPVarInt(playerid, "pv_iCP");

        new
            Float: fX,
            Float: fY,
            Float: fZ
        ;
        GetPlayerPos(playerid, fX, fY, fZ);

        fX -= g_afCP[s_iCP[playerid]][0];
        fY -= g_afCP[s_iCP[playerid]][1];
        fZ -= g_afCP[s_iCP[playerid]][2];

        s_fDist[playerid] = ((fX * fX) + (fY * fY) + (fZ * fZ));
        s_iRank[playerid] = 1;
    }
    foreach(new playerid : g_itrRacers) {
        foreach(new i : g_itrRacers) {
            if(i != playerid) {
                if(s_iCP[playerid] < s_iCP[i]) {
                    s_iRank[playerid]++;
                } else if(s_iCP[playerid] == s_iCP[i]) {
                    if(s_fDist[playerid] > s_fDist[i]) {
                        s_iRank[playerid]++;
                    }
                }
            }
        }
    }
    foreach(new playerid : g_itrRacers) {
        raceUpdateTD(playerid, s_iRank[playerid], s_iCP[playerid]);
    }
}