// OpenAI's ChatGPT integration for LSL
// Written by PanteraPolnocy, March 2023
// Version 2.1

// Configurable
string gChatGptApiKey = "xxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx";

// Defaults, do NOT change them here - use dialog menu instead!
integer gBodyMaxLength = 16384;
string gListenMode = "Owner";
list gModelsList = ["Davinci (chat)", "DALL-E (images, slow)"];
list gOpenAiModels = [

    "Davinci (chat)",
    "Endpoint", "/v1/completions",
    "Items", 6,
    "model", "text-davinci-003",
    "temperature", 0.9,
    "max_tokens", 150,
    "top_p", 1,
    "frequency_penalty", 0.0,
    "presence_penalty", 0.6,

    "DALL-E (images, slow)",
    "Endpoint", "/v1/images/generations",
    "Items", 2,
    "n", 1,
    "size", "1024x1024"

];

// Set in runtime, do not touch
integer gEnabled;
integer gListenHandle;
integer gDialogChannel;
integer gDialogHandle;
string gCurrentEndpoint;
string gCurrentModelName;
list gCurrentModelData;
key gOwnerKey;
key gHTTPRequestId;

// Functions

setListener()
{
    key listenKey = NULL_KEY;
    if (gListenMode == "Owner")
    {
        listenKey = gOwnerKey;
    }
    gListenHandle = llListen(PUBLIC_CHANNEL, "", listenKey, "");
    llListenControl(gListenHandle, gEnabled);
    llSetText("Listener " + llList2String(["disabled", "enabled"], gEnabled), <1, 1, 1>, 0.5);
}

setModel(string modelName)
{
    integer modelPosition = llListFindList(gOpenAiModels, (list)modelName);
    if (modelPosition == -1)
    {
        llOwnerSay("Cannot find model: " + modelName);
        return;
    }
    gCurrentEndpoint = llList2String(gOpenAiModels, modelPosition + 2);
    gCurrentModelData = llList2List(gOpenAiModels, modelPosition + 5, modelPosition + 4 + llList2Integer(gOpenAiModels, modelPosition + 4) * 2);
    gCurrentModelName = modelName;
    llOwnerSay("Model selected: " + modelName);
}

stopDlialog()
{
    llSetTimerEvent(0);
    llListenRemove(gDialogHandle);
}

// Script body

default
{

    on_rez(integer sp)
    {
        llResetScript();
    }

    state_entry()
    {
        gOwnerKey = llGetOwner();
        gDialogChannel = (integer)(llFrand(-10000000)-10000000);
        if (llGetMemoryLimit() <= 16384)
        {
            gBodyMaxLength = 4096;
            llOwnerSay("Warning: You're using LSO VM. Maximum response body will be limited. Please compile script as Mono.");
        }
        setModel("Davinci (chat)");
        setListener();
    }

    touch_start(integer nd)
    {
        key toucherKey = llDetectedKey(0);
        if (toucherKey != gOwnerKey)
        {
            return;
        }
        gDialogHandle = llListen(gDialogChannel, "", toucherKey, "");
        llDialog(toucherKey, "\nThis menu can be only seen by the object owner. Select an option.\n-\nCurrent state: " + llList2String(["Disabled", "Enabled"], gEnabled) + "\nCurrent model: " + gCurrentModelName + "\nCurrent listen mode: " + gListenMode, ["ON / OFF", "Select model", "Listen to"], gDialogChannel);
        llSetTimerEvent(60);
    }

    timer()
    {
        stopDlialog();
    }

    listen(integer channel, string name, key id, string message)
    {

        if (channel == gDialogChannel)
        {
            if (message == "ON / OFF")
            {
                stopDlialog();
                gEnabled = !gEnabled;
                setListener();
                llOwnerSay("Listener " + llList2String(["disabled", "enabled"], gEnabled) + ".");
            }
            else if (message == "Select model")
            {
                llSetTimerEvent(60);
                llDialog(id, "\nSelect model. Current one: " + gCurrentModelName, gModelsList, gDialogChannel);
            }
            else if (message == "Listen to")
            {
                llSetTimerEvent(60);
                llDialog(id, "\nSelect listen mode. Current one: " + gListenMode, ["Owner", "Same group", "Everyone"], gDialogChannel);
            }
            else if (message == "Owner" || message == "Same group" || message == "Everyone")
            {
                stopDlialog();
                gListenMode = message;
                setListener();
                llOwnerSay("Listen mode set to: " + message);
            }
            else if (~llListFindList(gModelsList, (list)message))
            {
                stopDlialog();
                setModel(message);
            }
            return;
        }

        id = llGetOwnerKey(id);
        if (llGetAgentSize(id) == ZERO_VECTOR || llVecDist(llGetPos(), llList2Vector(llGetObjectDetails(id, [OBJECT_POS]), 0)) > 20 || (gListenMode == "Owner" && id != gOwnerKey) || (gListenMode == "Same group" && !llSameGroup(id)))
        {
            return;
        }
        gHTTPRequestId = llHTTPRequest("https://api.openai.com" + gCurrentEndpoint, [
            HTTP_MIMETYPE, "application/json",
            HTTP_METHOD, "POST",
            HTTP_BODY_MAXLENGTH, gBodyMaxLength,
            HTTP_CUSTOM_HEADER, "Authorization", "Bearer " + gChatGptApiKey
        ], llList2Json(JSON_OBJECT, llListInsertList(gCurrentModelData, ["prompt", message, "user", (string)id], 0)));

    }

    http_response(key request_id, integer status, list metadata, string body)
    {
        if (gHTTPRequestId != request_id)
        {
            return;
        }
        string result = llJsonGetValue(body, ["choices", 0, "text"]); // Davinci
        if (result == JSON_INVALID || result == JSON_NULL)
        {
            result = llJsonGetValue(body, ["data", 0, "url"]); // DALL-E
            if (result == JSON_INVALID || result == JSON_NULL)
            {
                llSay(0, "Something went wrong, try again in a moment.");
                llOwnerSay("[SERVER MESSAGE] " + body);
                return;
            }
        }
        llSay(0, llStringTrim(result, STRING_TRIM));
    }

    changed(integer change)
    {
        if (change & CHANGED_OWNER)
        {
            llResetScript();
        }
    }

}