Create a new version of paste:

//@version=4
study("Candle Patterns Alert", shorttitle="CPA", overlay=true)
// Candlestick pattern alerts for strategies "Candle Patterns Strategy" and "Candle Patterns Strategy - 2".
// In order not to receive unnecessary signals, in the "Manage alerts" option should be selected "Once per bar close".

//--- Patterns Input ---

OnEngulfing = input(defval=true, title="Engulfing", type=input.bool)
OnHarami = input(defval=true, title="Harami", type=input.bool)
OnPiercingLine = input(defval=true, title="Piercing Line / Dark Cloud Cover", type=input.bool)
OnMorningStar = input(defval=true, title="Morning Star / Evening Star ", type=input.bool)
OnBeltHold = input(defval=true, title="Belt Hold", type=input.bool)
OnThreeWhiteSoldiers = input(defval=true, title="Three White Soldiers / Three Black Crows", type=input.bool)
OnThreeStarsInTheSouth = input(defval=true, title="Three Stars in the South", type=input.bool)
OnStickSandwich = input(defval=true, title="Stick Sandwich", type=input.bool)
OnMeetingLine = input(defval=true, title="Meeting Line", type=input.bool)
OnKicking = input(defval=true, title="Kicking", type=input.bool)
OnLadderBottom = input(defval=true, title="Ladder Bottom", type=input.bool)

//--- MA Filter Input ---

InpSmaFilter = input(defval=false, title="MA Filter", type=input.bool)
maPer = input(defval=50, title="MA Period", minval=1)

// --- Candlestick Patterns ---

//Engulfing 
bullish_engulfing = high[0] > high[1] and low[0] < low[1] and open[0] < open[1] and 
   close[0] > close[1] and close[0] > open[0] and close[1] < close[2] and 
   close[0] > open[1] ? OnEngulfing : na
bearish_engulfing = high[0] > high[1] and low[0] < low[1] and open[0] > open[1] and 
   close[0] < close[1] and close[0] < open[0] and close[1] > close[2] and 
   close[0] < open[1] ? OnEngulfing : na

//Harami
bullish_harami = open[1] > close[1] and close[1] < close[2] and open[0] > close[1] and 
   open[0] < open[1] and close[0] > close[1] and close[0] < open[1] and 
   high[0] < high[1] and low[0] > low[1] and close[0] >= open[0] ? OnHarami : na
bearish_harami = open[1] < close[1] and close[1] > close[2] and open[0] < close[1] and 
   open[0] > open[1] and close[0] < close[1] and close[0] > open[1] and 
   high[0] < high[1] and low[0] > low[1] and close[0] <= open[0] ? OnHarami : na

//Piercing Line/Dark Cloud Cover 
piercing_line = close[2] > close[1] and open[0] < low[1] and close[0] > avg(open[1], close[1]) and 
   close[0] < open[1] ? OnPiercingLine : na
dark_cloud_cover = close[2] < close[1] and open[0] > high[1] and close[0] < avg(open[1], close[1]) and 
   close[0] > open[1] ? OnPiercingLine : na

//Morning Star/Evening Star
morning_star = close[3] > close[2] and close[2] < open[2] and open[1] < close[2] and 
   close[1] < close[2] and open[0] > open[1] and open[0] > close[1] and 
   close[0] > close[2] and open[2] - close[2] > close[0] - open[0] ? OnMorningStar : 
   na
evening_star = close[3] < close[2] and close[2] > open[2] and open[1] > close[2] and 
   close[1] > close[2] and open[0] < open[1] and open[0] < close[1] and 
   close[0] < close[2] and close[2] - open[2] > open[0] - close[0] ? OnMorningStar : 
   na

//Belt Hold
bullish_belt_hold = close[1] < open[1] and low[1] > open[0] and close[1] > open[0] and 
   open[0] == low[0] and close[0] > avg(close[0], open[0]) ? OnBeltHold : na
bearish_belt_hold = close[1] > open[1] and high[1] < open[0] and close[1] < open[0] and 
   open[0] == high[0] and close[0] < avg(close[0], open[0]) ? OnBeltHold : na

//Three White Soldiers/Three Black Crows 
three_white_soldiers = close[3] < open[3] and open[2] < close[3] and close[2] > avg(close[2], open[2]) and 
   open[1] > open[2] and open[1] < close[2] and close[1] > avg(close[1], open[1]) and 
   open[0] > open[1] and open[0] < close[1] and close[0] > avg(close[0], open[0]) and 
   high[1] > high[2] and high[0] > high[1] ? OnThreeWhiteSoldiers : na
three_black_crows = close[3] > open[3] and open[2] > close[3] and close[2] < avg(close[2], open[2]) and 
   open[1] < open[2] and open[1] > close[2] and close[1] < avg(close[1], open[1]) and 
   open[0] < open[1] and open[0] > close[1] and close[0] < avg(close[0], open[0]) and 
   low[1] < low[2] and low[0] < low[1] ? OnThreeWhiteSoldiers : na

//Three Stars in the South
three_stars_in_the_south = open[3] > close[3] and open[2] > close[2] and open[2] == high[2] and 
   open[1] > close[1] and open[1] < open[2] and open[1] > close[2] and 
   low[1] > low[2] and open[1] == high[1] and open[0] > close[0] and 
   open[0] < open[1] and open[0] > close[1] and open[0] == high[0] and 
   close[0] == low[0] and close[0] >= low[1] ? OnThreeStarsInTheSouth : na

//Stick Sandwich
stick_sandwich = open[2] > close[2] and open[1] > close[2] and open[1] < close[1] and 
   open[0] > close[1] and open[0] > close[0] and close[0] == close[2] ? 
   OnStickSandwich : na

//Meeting Line 
bullish_ml = open[2] > close[2] and open[1] > close[1] and close[1] == close[0] and 
   open[0] < close[0] and open[1] >= high[0] ? OnMeetingLine : na
bearish_ml = open[2] < close[2] and open[1] < close[1] and close[1] == close[0] and 
   open[0] > close[0] and open[1] <= low[0] ? OnMeetingLine : na

//Kicking 
bullish_kicking = open[1] > close[1] and open[1] == high[1] and close[1] == low[1] and 
   open[0] > open[1] and open[0] == low[0] and close[0] == high[0] and 
   close[0] - open[0] > open[1] - close[1] ? OnKicking : na
bearish_kicking = open[1] < close[1] and open[1] == low[1] and close[1] == high[1] and 
   open[0] < open[1] and open[0] == high[0] and close[0] == low[0] and 
   open[0] - close[0] > close[1] - open[1] ? OnKicking : na

//Ladder Bottom
ladder_bottom = open[4] > close[4] and open[3] > close[3] and open[3] < open[4] and 
   open[2] > close[2] and open[2] < open[3] and open[1] > close[1] and 
   open[1] < open[2] and open[0] < close[0] and open[0] > open[1] and 
   low[4] > low[3] and low[3] > low[2] and low[2] > low[1] ? OnLadderBottom : na

// --- Plotting Patterns ---

plotshape(bullish_engulfing, text='Engulfing', style=shape.triangleup, color=#1FADA2, editable=true, title="Bullish Engulfing Text")
plotshape(bearish_engulfing, text='Engulfing', style=shape.triangledown, color=#F35A54, editable=true, title="Bearish Engulfing Text")
plotshape(bullish_harami, text='Harami', style=shape.triangleup, color=#1FADA2, editable=true, title="Bullish Harami Text")
plotshape(bearish_harami, text='Harami', style=shape.triangledown, color=#F35A54, editable=true, title="BEarish Harami Text")
plotshape(piercing_line, text='Piercing Line', style=shape.triangleup, color=#1FADA2, editable=false)
plotshape(dark_cloud_cover, text='Dark Cloud Cover', style=shape.triangledown, color=#F35A54, editable=false)
plotshape(morning_star, text='Morning Star', style=shape.triangleup, color=#1FADA2, editable=false)
plotshape(evening_star, text='Evening Star', style=shape.triangledown, color=#F35A54, editable=false)
plotshape(bullish_belt_hold, text='Belt Hold', style=shape.triangleup, color=#1FADA2, editable=false)
plotshape(bearish_belt_hold, text='Belt Hold', style=shape.triangledown, color=#F35A54, editable=false)
plotshape(three_white_soldiers, text='Three White Soldiers', style=shape.triangleup, color=#1FADA2, editable=false)
plotshape(three_black_crows, text='Three Black Crows', style=shape.triangledown, color=#F35A54, editable=false)
plotshape(three_stars_in_the_south, text='3 Stars South', style=shape.triangleup, color=#1FADA2, editable=false)
plotshape(stick_sandwich, text='Stick Sandwich', style=shape.triangleup, color=#1FADA2, editable=false)
plotshape(bullish_ml, text='Meeting Line', style=shape.triangleup, color=#1FADA2, editable=false)
plotshape(bearish_ml, text='Meeting Line', style=shape.triangledown, color=#F35A54, editable=false)
plotshape(bullish_kicking, text='Kicking', style=shape.triangleup, color=#1FADA2, editable=false)
plotshape(bearish_kicking, text='Kicking', style=shape.triangledown, color=#F35A54, editable=false)
plotshape(ladder_bottom, text='Ladder Bottom', style=shape.triangleup, color=#1FADA2, editable=false)

// --- Logic ---

SignalUp = bullish_engulfing or bullish_harami or piercing_line or morning_star or 
   bullish_belt_hold or three_white_soldiers or three_stars_in_the_south or 
   stick_sandwich or bullish_ml or bullish_kicking or ladder_bottom
SignalDown = bearish_engulfing or bearish_harami or dark_cloud_cover or evening_star or 
   bearish_belt_hold or three_black_crows or bearish_ml or bearish_kicking

du = sma(close, maPer)
smaF = SignalUp and high[0] > du[0] ? true : 
   SignalUp and high[0] < du[0] ? false : SignalDown and high[0] > du[0] ? false : 
   SignalDown and high[0] < du[0] ? true : na
smaFilter = InpSmaFilter ? smaF : true
duplot = InpSmaFilter ? du : na
plot(duplot, color=color.red)
bullish = SignalUp and smaFilter
bearish = SignalDown and smaFilter

// -- Alerts --
alertcondition(bullish, title='Bullish pattern', message='New bullish pattern!')
alertcondition(bearish, title='Bearish pattern', message='New bearish pattern!')
alertcondition(bullish or bearish, title='New pattern', message='New pattern!')