BioRifle Decorate code

Actor AcidAmmo : Ammo
{
    Inventory.Amount 18
    Inventory.MaxAmount 180
    Inventory.Icon "BAR1A0"
    Inventory.PickupMessage "Picked up a bio pack!"
    Inventory.PickupSound "misc/i_pkup"
    Ammo.BackpackAmount 18
    Ammo.BackpackMaxAmount 360
    +COUNTITEM
    States
    {
    Spawn:
        TNT1 A -1
        Stop
    }
}

Actor AcidBarrel : AcidAmmo replaces ExplosiveBarrel
{
    Inventory.Amount 54
    Inventory.PickupMessage "Picked up a barrel full of sludge!"
    Health 100
    Radius 10
    Height 34
    DeathSound "world/barrelx"
    Obituary "%k violated OSHA regulations."
    Damagetype Poison
    PoisonDamage 9,5,18
    +SOLID
    +COUNTITEM
    +SHOOTABLE
    +NOBLOOD
    +DONTGIB
    +NOICEDEATH
    +ADDITIVEPOISONDAMAGE
    +ADDITIVEPOISONDURATION
    States
    {
    Spawn:
        BAR1 AB 6
        Loop
    Death:
        BEXP ABC 5 Bright
        BEXP D 0 A_Scream
        BEXP D 5 A_Explode(512,128)
        TNT1 A 0 A_CustomMissile("AcidPool",0,0,0,4)
        BEXP E 10 Bright
        BEXP E 1050 A_BarrelDestroy
        BEXP E 5 A_Respawn
        Wait
    }
}

Actor SSAEBioRifle : Weapon
{
    Inventory.PickupMessage "Time to give some toxic love!"
    Weapon.AmmoGive 18
    Weapon.AmmoType "AcidAmmo"
    Weapon.AmmoUse 1
    Weapon.KickBack 100
    Weapon.SelectionOrder 1100
    Weapon.SlotNumber 6
    Weapon.SlotPriority 1
    Tag "RE-X Bio Rifle"
    +WEAPON.NOAUTOAIM
    States
    {
    Ready:
        PLSG A 1 A_WeaponReady
        Loop
    Deselect:
        PLSG A 1 A_Lower
        Loop
    Select:
        TNT1 A 1
        TNT1 A 0 A_GiveInventory("357OneChamber",6)
        TNT1 A 0 A_GiveInventory("357TwoChambers",12)
        TNT1 A 0 A_TakeInventory("SpinMeter",8)
        Goto SeLoop
    SeLoop:
        PLSG A 1 A_Raise
        Loop
    Fire:
        PLSG A 4 A_GunFlash
        PLSG A 0 A_PlaySound("weapons/rocklf",CHAN_WEAPON, 1)
        PLSG A 10 A_FireCustomMissile("AcidShot",0,1,0,0,0,5)
        PLSG A 0 A_ReFire
        Goto Ready
    Hold:
        PLSG A 0 A_GunFlash
        PLSG A 0 A_PlaySound("weapons/rocklf",CHAN_WEAPON, 1)
        PLSG A 10 A_FireCustomMissile("AcidShot",0,1,0,0,0,5)
        PLSG A 0 A_Refire
        Goto Ready
    Flash:
        PLSF A 2 Bright A_Light1
        Goto LightDone
        PLSF B 2 Bright A_Light1
        Goto LightDone
    Spawn:
        PLAS A -1
        Stop
    }
}

Actor AcidShot
{
    Damage (Random(8,16))
    Speed 56
    Radius 4
    Height 8
    DamageType Poison
    PoisonDamage 4,2,18
    BounceType "Heretic"
    DeathSound "weapons/plasmax"
    RenderStyle Add
    Alpha 0.5
    Obituary "%o was mutated by %k's toxic acid."
    //SuicideObituary "%k did not observe safety precautions."
    +FORCERADIUSDMG
    +RIPPER
    +NOBOSSRIP
    +ADDITIVEPOISONDAMAGE
    +ADDITIVEPOISONDURATION
    +BLOODSPLATTER
    +PIERCEARMOR
    +FORCEPAIN
    Projectile
    -NOGRAVITY
    States
    {
    Spawn:
        TNT1 A 0 A_CustomMissile("AcidTrailA",0,0,180)
        PLSS A 1 Bright
        TNT1 A 0 A_CustomMissile("AcidTrailA",0,0,180)
        PLSS A 1 Bright
        TNT1 A 0 A_CustomMissile("AcidTrailA",0,0,180)
        PLSS A 1 Bright
        TNT1 B 0 A_CustomMissile("AcidTrailB",0,0,180)
        PLSS B 1 Bright
        TNT1 B 0 A_CustomMissile("AcidTrailB",0,0,180)
        PLSS B 1 Bright
        TNT1 B 0 A_CustomMissile("AcidTrailB",0,0,180)
        PLSS B 1 Bright
        Loop
    Death:
        PLSE A 0 A_Jump(224,2)
        PLSE A 0 Bright A_Explode(Random(10,20),40,0,1,20)
        PLSE A 0 A_Jump(224,6)
        PLSE A 0 A_Jump(192,2)
        PLSE A 0 Bright A_Explode(Random(20,40),60,0,1,30)
        PLSE A 0 A_Jump(256,3)
        PLSE A 0 A_Jump(0,2)
        PLSE A 0 Bright A_Explode(Random(40,80),80,0,1,40)
        PLSE A 0 A_Jump(256,0)
        PLSE ABCD 3
        PLSE E 3 A_CustomMissile("AcidPool",0,0,0,4)
        Stop
    XDeath:
        PLSE A 0 A_Jump(224,2)
        PLSE A 0 Bright A_Explode(Random(10,20),40,0,1,20)
        PLSE A 0 A_Jump(224,6)
        PLSE A 0 A_Jump(192,2)
        PLSE A 0 Bright A_Explode(Random(20,40),60,0,1,30)
        PLSE A 0 A_Jump(256,3)
        PLSE A 0 A_Jump(0,2)
        PLSE A 0 Bright A_Explode(Random(40,80),80,0,1,40)
        PLSE A 0 A_Jump(256,0)
        PLSE A 3 A_CustomMissile("AcidPool",0,0,0,4)
        PLSE BCDE 3
        Stop
    }
}

Actor AcidTrailA
{
    RenderStyle ADD
    Scale 1
    Alpha 0.35
    +NOCLIP
    +NOINTERACTION
    +NOGRAVITY
    States
    {
    Spawn:
    PLSS AAABBB 1 A_FadeOut(0.01,1)
    Loop
    }
}

Actor AcidTrailB : AcidTrailA
{
    States
    {
    Spawn:
    PLSS BBBAAA 1 A_FadeOut(0.01,1)
    Loop
    }
}

Actor AcidPool
{
    Speed 0
    Radius 48
    Height 16
    Gravity 0.5
    RenderStyle Add
    Alpha 0.2
    XScale 4
    YScale 2
    DamageType Poison
    PoisonDamage 4,2,18
    +FLOATBOB
    +FLOAT
    +NOEXPLODEFLOOR
    +NODAMAGETHRUST
    +THRUGHOST
    +DONTSPLASH
    +FORCERADIUSDMG
    +ADDITIVEPOISONDAMAGE
    +ADDITIVEPOISONDURATION
    +PAINLESS
    Obituary "%o fell for %k's poison acid trap."
    // "%k tripped on %p own poison acid trap."
    States
    {
    Spawn:
        PLSS A 0 A_Playsound("vile/firecrkl",CHAN_BODY,0.4,1)
        PLSS ABABABABAB 3 A_Explode(Random(1,4),128,0,0,32)
        PLSS A 0 A_Jump(64,1)
        Loop
        TNT1 A 0
        Goto Death
    Death:
        PLSE AAABBBCCCDDDEEE 1 A_FadeOut(0.01,1)
        Stop
    }
}