; Makro na przezbrajanie 1h -> 2h + .cios z binda.
; Nizej w kodzie trzeba ustawic sobie binda i wpisac poprawnie komende
; ktory cios ma byc gdzie uzyty - zaznaczylem w ktorych miejscach.
; Wpisac trzeba tez czas, zaleznie od inta bazowego postaci.
;
; Zmienna %cios odpowiada za uzbrajanie po uplywie czasu do specjala i odpalanie
; specjala z automatu.
; Ustawiona na 1 uzbroi 1h+tarcze, ustawiona na 2 uzbroi 2h, ustawiona na 0
; w ogole nie bedzie uzbrajac automatycznie.
;
; Zmienna %opcja odpowiada za odliczanie czasu do specjala po zdjeciu tarczy
; Jesli po zdjeciu tarczy odliczanie ma byc automatycznie wlaczane, ustaw na 1
; Jesli timer ma dzialac tylko na binda, ustaw na 0
; Podzialka:
;
; 10-20 inta 60s
; 21-30 inta 55s
; 31-40 inta 45s
; 41-50 inta 40s
; 51-60 inta 30s
; 61-70 inta 25s
; 71+ inta   20s
;
; Milego uzywania, Tinerot

set %czas 45 ; tu wpisz czas wg podzialki na gorze makra (liczba bez "s")
set %cios 0 ; Tu wpisz 0, 1 lub 2 w zaleznosci od dzialania makra (opis na gorze)
set %opcja 1 ; Tu wpisz 0 lub 1 w zaleznosci od dzialania makra (opis na gorze)

; NIE RUSZAĆ:
set %spec 0
set %lul 0

set #sysmsgcol 1082
event sysmessage [LoA] Skrypt .cios - Enabled!
event sysmessage [LoA] W dzisiejszym odcinku goscinnie wystepuje Tinerot
event sysmessage [LoA] Wersja: 20.08.2009

wait 5

init:

set #sysmsgcol 100
event sysmessage Wskaz bron 1h:
set #targcurs 1
repeat
      target 5
until #targcurs = 0
set %bron1h #ltargetid

set #sysmsgcol 100
event sysmessage Wskaz tarcze:
set #targcurs 1
repeat
      target 5
until #targcurs = 0
set %tarcza #ltargetid

set #sysmsgcol 100
event sysmessage Wskaz bron 2h:
set #targcurs 1
repeat
      target 5
until #targcurs = 0
set %bron2h #ltargetid

goto start

start:

onhotkey f4  ; zmiana 2h -> 1h, zmienic binda
{
  gosub 1h
}

onhotkey f5  ; zmiana 1h -> 2h, zmienic binda
{
  gosub 2h
  if %opcja <> 0
  {
    gosub ustawlicznik %spec
  }
}

onhotkey f + ctrl   ; licznik - zmienic binda
{
  gosub ustawlicznik %spec
}

if %lul = 0 && #SCNT >= ( %spec - 10 ) && %spec <> 0
{
 event SysMessage [LoA] Do specjala pozostalo 10 sekund !
 set %lul 1
}

if %lul = 1 && #SCNT >= %spec
{
 set %lul 0
 set %spec 0
 event SysMessage [LoA] Mozna uzyc specjala!
 if %cios = 1
 {
   gosub 1h
   goto start
 }
 if %cios = 2
 {
   gosub 2h
   goto start
 }
}

goto start

----------------------------------------- ; 2h
sub 2h

 gosub zdejmij %bron1h %tarcza
 gosub zaloz %bron2h 0
 event macro 1 0 .cios odebranie tchu ; zmienic sobie - specjal z 2h
 set %spec 0
 return

---------------------------------------- ; 1h
sub 1h
 gosub zdejmij %bron2h 0
 gosub zaloz %bron1h %tarcza
 event macro 1 0 .cios odebranie tchu
 set %spec 0
 return

--------------------------------------- ; licznik

sub ustawlicznik

set %spec #SCNT + %czas
set #sysmsgcol 1082
event sysmessage [LoA] Do specjala pozostalo %czas sekund!

return

---------------------------------------- ; zdejmowanie
sub zdejmij

if %1 <> 0
{
 repeat
       Exevent Drag %1
       wait 1
 until #LLIFTEDKIND <> 1
 repeat
       exevent Dropc #BACKPACKID
 until #LLIFTEDKIND = 0
}

if %2 <> 0
{
 repeat
       Exevent Drag %2
       wait 1
 until #LLIFTEDKIND <> 1
 repeat
       exevent Dropc #BACKPACKID
 until #LLIFTEDKIND = 0
}

return

--------------------------------------- ; zakladanie

sub zaloz

if %1 <> 0
{
 repeat
       Exevent Drag %1
       wait 1
 until #LLIFTEDKIND <> 1
 repeat
       exevent Droppd
 until #LLIFTEDKIND = 0
}

if %2 <> 0
{
 repeat
       Exevent Drag %2
       wait 1
 until #LLIFTEDKIND <> 1
 repeat
       exevent Droppd
 until #LLIFTEDKIND = 0
}

return