Форматирование числа в строку с разбивкой на сотни

stock FormatIntWithDelimiters(value, result[], delimiter = '.', size = sizeof(result))
{
    static delimiter_string[2] = { '\0', '\0' };
    static len;
    delimiter_string[0] = delimiter;
    if (value != cellmin)
    {
        format(result, size, "%d", value);
    }
    else
    {
        result[0] = '\0';
        strcat(result, "-2147483648", size);
    }
    len = strlen(result);
    switch (len - _:(value < 0))
    {
        case 10:
        {
            if (len + 3 >= size)
                return 0;
            strins(result, delimiter_string, len - 3, 1);
            strins(result, delimiter_string, len - 6, 1);
            strins(result, delimiter_string, len - 9, 1);
        }
        case 7..9:
        {
            if (len + 2 >= size)
                return 0;
            strins(result, delimiter_string, len - 3, 1);
            strins(result, delimiter_string, len - 6, 1);
        }
        case 4..6:
        {
            if (len + 1 >= size)
                return 0;
            strins(result, delimiter_string, len - 3, 1);
        }
    }
    return 1;
}