/warn

Trigger: /warn

$nomention

$onlyIf[$isSlash==true;]
$onlyIf[$guildID!=;]

$var[target-user;$message[user]]

$var[tick;✅]
$var[cross;❌]
$var[excla;❕]
$var[color;4ac1e4]

$if[$or[$checkUserPerms[$authorID;moderatemembers]==true;$isAdmin[$authorID]==true]==false]
    $ephemeral
    $var[excla] You do not have required permissions to run this command!
    $stop
$endif

$if[$or[$checkUserPerms[$botID;moderatemembers]==true;$isAdmin[$botID]==true]==false]
    $ephemeral
    $var[excla] Vanilla does not have `Timeout Members` permission!
    $stop
$endif

$if[$findUser[$var[target-user];no]==]
    $ephemeral
    $var[cross] That user is not in this server!
    $stop
$endif

$if[$authorID==$var[target-user]]
    $ephemeral
    $var[excla] You can not warn yourself!
    $stop
$endif

$if[$isBot[$var[target-user]]==true]
    $ephemeral
    $var[cross] You can not warn bots!
    $stop
$endif

$if[$rolePosition[$highestRole[$botID]]>$rolePosition[$highestRole[$var[target-user]]]]
    $ephemeral
    $var[cross] My role is lower in heiarchy so I can't warn them!
    $stop
$endif

$if[$rolePosition[$highestRole[$authorID]]>$rolePosition[$highestRole[$var[target-user]]]]
    $ephemeral
    $var[cross] Your role is lower is heiarchy to that user!
    $stop
$endif

$defer

$var[generate-warn-id;$replaceText[$replaceText[$optOff[$randomString[10]$randomString[10]];+;];/;]]

$if[$message[reason]==]
    $var[fetch-reason;no reason given]
$else
    $var[get-reason;$replaceText[$replaceText[$replaceText[$replaceText[$message[reason];*;];`;];_;];";]]
    $var[fetch-reason;$cropText[$var[get-reason];150;]]
$endif

$jsonSetString[timestamp;$getTimestamp]
$jsonSetString[moderator;name;$username]
$jsonSetString[moderator;id;$authorID]
$jsonSetString[warnID;$var[generate-warn-id]]
$jsonSetString[reason;$var[fetch-reason]]

$var[json;$jsonStringify]

$jsonClear

$jsonParse[$getUserVar[userWarns.json;$var[target-user]]]
$jsonArrayAppend[infractions;$var[json]]

$var[final.json;$replaceText[$replaceText[$replaceText[$jsonPretty[];"{;{];}";}];$url[decode;%5C]";"]]

$jsonParse[$var[final.json]]
$jsonSetString[total-warns;$sum[0$json[total-warns];1]]

$try
  $setUserVar[userWarns.json;$jsonStringify;$var[target-user]]
$catch
  $jsonUnset[infractions;0]
  $setUserVar[userWarns.json;$jsonStringify;$var[target-user]]
$endtry

$if[$message[dm]!=]
    $if[$message[dm]==true]
        $if[$isUserDMEnabled[$var[target-user]]==true]
            $try
                $sendEmbedMessage[$dmChannelID[$var[target-user]];;;;You were warned in $serverName[$guildID]$url[decode;%0A]Reason: $var[fetch-reason];$var[color];;;;;;;true;false]
                $var[dm.sent?;🎫 Successfully DMed the user!]
            $catch
                $var[dm.sent?;🎫 Couldn't DM the user!]
            $endtry
        $else
            $var[dm.sent?;🎫 User's DMs are disabled so i couldn't DM them]
        $endif
    $endif
$endif

$description[$var[tick] **$username[$var[target-user]]** has been warned || __$var[fetch-reason]__$url[decode;%0A]$var[dm.sent?]]
$color[$var[color]]