ConnexionDomaine.vbs

'========================================================================
' Connexion de lecteurs réseau via domaine AD
' Auteur : Nicolas KAROLAK
' Date : 2013-06-03
' Description : Permet de connecter des lecteurs réseau d'un domaine AD
'       sur un poste non joint au domaine. (Site 40)
'========================================================================

Option Explicit
On Error Resume Next

'========================================================================
' Déclaration de variable et objets
'========================================================================

Const ADS_SECURE_AUTHENTICATION = 1
Const ADS_USE_ENCRYPTION = 2
Dim objFSO, objWshNetwork, objWshShell, objNS, objUser, objGroup
Dim strDomain, strServer, strUser, strPass, strLength, strClasse

'========================================================================
' Début du programme
'========================================================================

' Création des objets
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objWshNetwork = CreateObject("WScript.Network")
Set objWshShell = CreateObject("WScript.Shell")

' Déconnecter les lecteurs réseau
If (objFSO.DriveExists("T:") = True) Then
    objWshNetwork.RemoveNetworkDrive "T:", True, True
End If
If (objFSO.DriveExists("L:") = True) Then
    objWshNetwork.RemoveNetworkDrive "L:", True, True
End If
If (objFSO.DriveExists("P:") = True) Then
    objWshNetwork.RemoveNetworkDrive "P:", True, True
End If

' Demander le nom d'utilisateur
strUser = InputBox("Veuillez entrer votre nom d'utilisateur :","Login")
' Demander le mot de passe
strPass = InputBox("Veuillez entrer votre mot de passe :","Password")
' Domaine AD
strDomain = "STN40"
' URL du server
strServer = "10.40.1.1"

' Récupération des objets AD
Set objNS = GetObject("WinNT:")
Set objUser = objNS.OpenDSObject("WinNT://" & strDomain & "/" & strUser, strUser, strPass, ADS_SECURE_AUTHENTICATION Or ADS_USE_ENCRYPTION)

' Parcourir les groupes auquels appartient l'utilisateur
For Each objGroup In objUser.Groups
    ' S'il appartient à un groupe élève
    If InStr(objGroup.Name, "_e") Then
        ' Récupérer le nom de la classe
        strLength = Len(objGroup.Name) - 2
        strClasse = Left(objGroup.Name, strLength)
        ' Connecter le dossier commun de la classe
        objWshNetwork.MapNetworkDrive "T:", "\\" & strServer & "\" & strClasse & "$",False,strUser,strPass
        ' Connecter le répertoire personnel
        objWshNetwork.MapNetworkDrive "P:", "\\" & strServer & "\" & strUser & "$",False,strUser,strPass
    End If
    ' S'il appartient au groupe profs
    If objGroup.Name = "Profs" Then
        ' Connecter le dossier commun des profs
        objWshNetwork.MapNetworkDrive "T:", "\\" & strServer & "\profs$",False,strUser,strPass
        ' Connecter le répertoire des élèves
        objWshNetwork.MapNetworkDrive "L:", "\\" & strServer & "\Eleves",False,strUser,strPass
        ' Connecter le répertoire personnel
        objWshNetwork.MapNetworkDrive "P:", "\\" & strServer & "\" & strUser & "$",False,strUser,strPass
    End If
Next