Amiga System User Copper List Example (Rainbow)

        incdir  'includes:'
        include 'intuition/screens.i'
        include 'graphics/copper.i'
        include 'graphics/videocontrol.i'
        include 'exec/memory.i'
        include 'lvo/graphics_lib.i'
        include 'lvo/exec_lib.i'
        include 'lvo/intuition_lib.i'

; Poczatek programu
start
; Biblioteki
        lea     (intname,pc),a1
        moveq   #36,d0
        movea.l (4).w,a6
        jsr     (_LVOOpenLibrary,a6)
        move.l  d0,(intbase)
        beq     .noint

        lea     (gfxname,pc),a1
        moveq   #36,d0
        movea.l (4).w,a6
        jsr     (_LVOOpenLibrary,a6)
        move.l  d0,(gfxbase)
        beq     .nogfx

; Ekran
        suba.l  a0,a0
        lea     (stags,pc),a1
        movea.l (intbase,pc),a6
        jsr     (_LVOOpenScreenTagList,a6)
        move.l  d0,(screen)
        beq     .noscr

        move.l  #ucl_SIZEOF,d0
        move.l  #MEMF_PUBLIC!MEMF_CLEAR,d1
        movea.l (4).w,a6
        jsr     (_LVOAllocMem,a6)
        move.l  d0,(ucopl)
        beq     .nomem

        bsr     test

.nomem  movea.l (screen,pc),a0
        movea.l (intbase,pc),a6
        jsr     (_LVOCloseScreen,a6)

.noscr  movea.l (gfxbase,pc),a1
        movea.l (4).w,a6
        jsr     (_LVOCloseLibrary,a6)

.nogfx  movea.l (intbase,pc),a1
        movea.l (4).w,a6
        jsr     (_LVOCloseLibrary,a6)

.noint  moveq   #0,d0
        rts

; Test
test
        movea.l (ucopl,pc),a2

        movea.l a2,a0
        moveq   #16,d0
        movea.l (gfxbase,pc),a6
        jsr     (_LVOUCopperListInit,a6)

        movea.l a2,a1
        move.w  #0,d0
        move.w  #0,d1
        jsr     (_LVOCWait,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #$180,d0
        move.w  #$bbf,d1
        jsr     (_LVOCMove,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #50,d0
        move.w  #0,d1
        jsr     (_LVOCWait,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #$180,d0
        move.w  #$ccf,d1
        jsr     (_LVOCMove,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #100,d0
        move.w  #0,d1
        jsr     (_LVOCWait,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #$180,d0
        move.w  #$ddf,d1
        jsr     (_LVOCMove,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #150,d0
        move.w  #0,d1
        jsr     (_LVOCWait,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #$180,d0
        move.w  #$eef,d1
        jsr     (_LVOCMove,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)
        movea.l a2,a1
        move.w  #200,d0
        move.w  #0,d1
        jsr     (_LVOCWait,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #$180,d0
        move.w  #$fff,d1
        jsr     (_LVOCMove,a6)

        movea.l a2,a1
        jsr     (_LVOCBump,a6)

        movea.l a2,a1
        move.w  #10000,d0
        move.w  #255,d1
        jsr     (_LVOCWait,a6)

        movea.l (screen,pc),a3
        lea     (sc_ViewPort,a3),a3

        movea.l (4).w,a6
        jsr     (_LVOForbid,a6)

        move.l  a2,(vp_UCopIns,a3)

        movea.l (4).w,a6
        jsr     (_LVOPermit,a6)

        movea.l (vp_ColorMap,a3),a0
        lea     (utags,pc),a1
        movea.l (gfxbase,pc),a6
        jsr     (_LVOVideoControl,a6)

        movea.l (intbase,pc),a6
        jsr     (_LVORethinkDisplay,a6)

        move.w  #300-1,d2
.loop   movea.l (gfxbase),a6
        jsr     (_LVOWaitTOF,a6)
        dbra    d2,.loop

        movea.l a3,a0
        movea.l (gfxbase,pc),a6
        jsr     (_LVOFreeVPortCopLists,a6)

        movea.l (intbase,pc),a6
        jsr     (_LVORemakeDisplay,a6)

        rts

; Dane

intbase dc.l    0
gfxbase dc.l    0
screen  dc.l    0
stags   dc.l    SA_Width,       320
        dc.l    SA_Height,      256
        dc.l    SA_Depth,       4
        dc.l    SA_Quiet,       1
        dc.l    SA_Colors,      cols
        dc.l    TAG_DONE,       0

utags   dc.l    VTAG_USERCLIP_SET,      0
        dc.l    VTAG_END_CM,            0

ucopl   dc.l    0

cols    dc.w    0,      $a,     $a,     $f
        dc.w    -1,     0,      0,      0

intname dc.b    'intuition.library',0
gfxname dc.b    'graphics.library',0