Запрос = Новый Запрос;
		Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
		Запрос.УстановитьПараметр("Регистратор",                          Регистратор);
		Запрос.УстановитьПараметр("НачисленнаяЗарплатаИВзносы",           НачисленнаяЗарплатаИВзносы);
		Запрос.УстановитьПараметр("НачисленныйНДФЛ",                      НачисленныйНДФЛ);

		Запрос.УстановитьПараметр("МассивОсновныхНачислений",             МассивОсновныхНачислений);
		Запрос.УстановитьПараметр("НДФЛОсновныхНачислений",               Перечисления.ВидыОперацийПоЗарплате.НДФЛ);

		Запрос.УстановитьПараметр("УсловныйВидОперации",                  Перечисления.ВидыОперацийПоЗарплате.НачисленоДоход);

		Запрос.УстановитьПараметр("МассивОперацийРасходовПоСтрахованию",  МассивОперацийРасходовПоСтрахованию);

		Запрос.УстановитьПараметр("ДивидендыСотрудников",                 Перечисления.ВидыОперацийПоЗарплате.ДивидендыСотрудников);
		Запрос.УстановитьПараметр("НФДЛДивидендыСотрудникам",             Перечисления.ВидыОперацийПоЗарплате.НФДЛДивидендыСотрудникам);

		Запрос.УстановитьПараметр("Дивиденды",                            Перечисления.ВидыОперацийПоЗарплате.Дивиденды);
		Запрос.УстановитьПараметр("НФДЛДивиденды",                        Перечисления.ВидыОперацийПоЗарплате.НФДЛДивиденды);

		Запрос.УстановитьПараметр("ВыплатыБывшимСотрудникам",             Перечисления.ВидыОперацийПоЗарплате.ВыплатыБывшимСотрудникам);
		Запрос.УстановитьПараметр("НДФЛРасчетыСБывшимиСотрудниками",      Перечисления.ВидыОперацийПоЗарплате.НДФЛРасчетыСБывшимиСотрудниками);

		Запрос.УстановитьПараметр("ДоходыКонтрагентов",                   Перечисления.ВидыОперацийПоЗарплате.ДоходыКонтрагентов);
		Запрос.УстановитьПараметр("НДФЛДоходыКонтрагентов",               Перечисления.ВидыОперацийПоЗарплате.НДФЛДоходыКонтрагентов);

		Запрос.УстановитьПараметр("ПрочиеРасчетыСПерсоналом",             Перечисления.ВидыОперацийПоЗарплате.ПрочиеРасчетыСПерсоналом);
		Запрос.УстановитьПараметр("НДФЛПрочиеРасчетыСПерсоналом",         Перечисления.ВидыОперацийПоЗарплате.НДФЛПрочиеРасчетыСПерсоналом);

		Запрос.УстановитьПараметр("ПериодРегистрации",                    ПериодРегистрации);
		Запрос.УстановитьПараметр("КонецПериодаОсмотра",                  КонецПериодаОсмотра);
		Запрос.УстановитьПараметр("Организация",                          Организация);
		Запрос.УстановитьПараметр("ВидРасходаНалоги",                     Перечисления.ВидыРасходовУСН.Налоги);
		Запрос.УстановитьПараметр("ВидРасходаЗарплата",                   Перечисления.ВидыРасходовУСН.Зарплата);
		Запрос.УстановитьПараметр("СчетУчетаНДФЛ",                        ПланыСчетов.Хозрасчетный.НДФЛ);

		Запрос.УстановитьПараметр("УчитыватьСтатьюРасходов",              ПолучитьФункциональнуюОпцию("УчетЗарплатыИКадровВоВнешнейПрограмме"));

		Запрос.Текст =
		"ВЫБРАТЬ
		|	НачисленнаяЗарплатаИВзносы.ФизическоеЛицо КАК ФизическоеЛицо,
		|	НачисленнаяЗарплатаИВзносы.Сумма КАК Сумма,
		|	НачисленнаяЗарплатаИВзносы.ВидОперации КАК ВидОперации,
		|	НачисленнаяЗарплатаИВзносы.ОблагаетсяЕНВД КАК ОблагаетсяЕНВД,
		|	НачисленнаяЗарплатаИВзносы.СпособОтраженияЗарплатыВБухУчете КАК СпособОтраженияЗарплатыВБухУчете,
		|	НачисленнаяЗарплатаИВзносы.СтатьяРасходов КАК СтатьяРасходов,
		|	НачисленнаяЗарплатаИВзносы.ВидОперацииРасходовЗаСчетФСС КАК ВидОперацииРасходовЗаСчетФСС,
		|	НачисленнаяЗарплатаИВзносы.Подразделение КАК Подразделение
		|ПОМЕСТИТЬ ВР_НачисленнаяЗарплатаИВзносы
		|ИЗ
		|	&НачисленнаяЗарплатаИВзносы КАК НачисленнаяЗарплатаИВзносы
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ РАЗЛИЧНЫЕ
		|	БольничныйЛист.Ссылка КАК Ссылка,
		|	БольничныйЛист.ФизическоеЛицо КАК ФизическоеЛицо
		|ПОМЕСТИТЬ ВТ_БольничныеИОтпуска
		|ИЗ
		|	Документ.БольничныйЛист КАК БольничныйЛист
		|ГДЕ
		|	ТИПЗНАЧЕНИЯ(&Регистратор) <> ТИП(Документ.БольничныйЛист)
		|	И ТИПЗНАЧЕНИЯ(&Регистратор) <> ТИП(Документ.Отпуск)
		|	И БольничныйЛист.ФизическоеЛицо В
		|			(ВЫБРАТЬ
		|				ВР_НачисленнаяЗарплатаИВзносы.ФизическоеЛицо КАК ФизическоеЛицо
		|			ИЗ
		|				ВР_НачисленнаяЗарплатаИВзносы КАК ВР_НачисленнаяЗарплатаИВзносы)
		|	И БольничныйЛист.Организация = &Организация
		|	И НАЧАЛОПЕРИОДА(БольничныйЛист.ПериодРегистрации, МЕСЯЦ) = НАЧАЛОПЕРИОДА(&ПериодРегистрации, МЕСЯЦ)
		|
		|СГРУППИРОВАТЬ ПО
		|	БольничныйЛист.Ссылка,
		|	БольничныйЛист.ФизическоеЛицо
		|
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ РАЗЛИЧНЫЕ
		|	Отпуск.Ссылка,
		|	Отпуск.ФизическоеЛицо
		|ИЗ
		|	Документ.Отпуск КАК Отпуск
		|ГДЕ
		|	ТИПЗНАЧЕНИЯ(&Регистратор) <> ТИП(Документ.БольничныйЛист)
		|	И ТИПЗНАЧЕНИЯ(&Регистратор) <> ТИП(Документ.Отпуск)
		|	И Отпуск.ФизическоеЛицо В
		|			(ВЫБРАТЬ
		|				ВР_НачисленнаяЗарплатаИВзносы.ФизическоеЛицо КАК ФизическоеЛицо
		|			ИЗ
		|				ВР_НачисленнаяЗарплатаИВзносы КАК ВР_НачисленнаяЗарплатаИВзносы)
		|	И Отпуск.Организация = &Организация
		|	И НАЧАЛОПЕРИОДА(Отпуск.ПериодРегистрации, МЕСЯЦ) = НАЧАЛОПЕРИОДА(&ПериодРегистрации, МЕСЯЦ)
		|
		|СГРУППИРОВАТЬ ПО
		|	Отпуск.Ссылка,
		|	Отпуск.ФизическоеЛицо
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	РасходыПриУСНОбороты.Регистратор КАК Регистратор,
		|	РасходыПриУСНОбороты.РасчетныйДокумент КАК РасчетныйДокумент,
		|	СУММА(РасходыПриУСНОбороты.СуммаПриход - РасходыПриУСНОбороты.СуммаРасход) КАК СуммаПриход,
		|	РасходыПриУСНОбороты.ВидРасхода КАК ВидРасхода,
		|	РасходыПриУСНОбороты.СчетУчета КАК СчетУчета,
		|	РасходыПриУСНОбороты.ОтражениеВУСН КАК ОтражениеВУСН
		|ПОМЕСТИТЬ ВТ_РасходыПриУСНОбороты
		|ИЗ
		|	РегистрНакопления.РасходыПриУСН.Обороты(НАЧАЛОПЕРИОДА(&ПериодРегистрации, МЕСЯЦ), КОНЕЦПЕРИОДА(&ПериодРегистрации, МЕСЯЦ), Регистратор, Организация = &Организация) КАК РасходыПриУСНОбороты
		|ГДЕ
		|	РасходыПриУСНОбороты.Регистратор В
		|			(ВЫБРАТЬ
		|				ВТ_БольничныеИОтпуска.Ссылка КАК Ссылка
		|			ИЗ
		|				ВТ_БольничныеИОтпуска)
		|	И РасходыПриУСНОбороты.СуммаПриход - РасходыПриУСНОбороты.СуммаРасход > 0
		|
		|СГРУППИРОВАТЬ ПО
		|	РасходыПриУСНОбороты.Регистратор,
		|	РасходыПриУСНОбороты.РасчетныйДокумент,
		|	РасходыПриУСНОбороты.ВидРасхода,
		|	РасходыПриУСНОбороты.СчетУчета,
		|	РасходыПриУСНОбороты.ОтражениеВУСН
		|
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	РасходыПриУСНОбороты.РасчетныйДокумент,
		|	РасходыПриУСНОбороты.РасчетныйДокумент,
		|	СУММА(-РасходыПриУСНОбороты.СуммаРасход),
		|	РасходыПриУСНОбороты.ВидРасхода,
		|	РасходыПриУСНОбороты.СчетУчета,
		|	РасходыПриУСНОбороты.ОтражениеВУСН
		|ИЗ
		|	РегистрНакопления.РасходыПриУСН.Обороты(НАЧАЛОПЕРИОДА(&ПериодРегистрации, МЕСЯЦ), &КонецПериодаОсмотра, Регистратор, Организация = &Организация) КАК РасходыПриУСНОбороты
		|ГДЕ
		|	РасходыПриУСНОбороты.РасчетныйДокумент В
		|			(ВЫБРАТЬ
		|				ВТ_БольничныеИОтпуска.Ссылка КАК Ссылка
		|			ИЗ
		|				ВТ_БольничныеИОтпуска)
		|	И РасходыПриУСНОбороты.РасчетныйДокумент <> РасходыПриУСНОбороты.Регистратор
		|	И РасходыПриУСНОбороты.СуммаРасход > 0
		|	И РасходыПриУСНОбороты.ВидРасхода = &ВидРасходаЗарплата
		|
		|СГРУППИРОВАТЬ ПО
		|	РасходыПриУСНОбороты.РасчетныйДокумент,
		|	РасходыПриУСНОбороты.ВидРасхода,
		|	РасходыПриУСНОбороты.СчетУчета,
		|	РасходыПриУСНОбороты.ОтражениеВУСН,
		|	РасходыПриУСНОбороты.РасчетныйДокумент
		|
		|ИНДЕКСИРОВАТЬ ПО
		|	Регистратор
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	ВТ_РасходыПриУСНОбороты.Регистратор КАК Регистратор,
		|	ВТ_РасходыПриУСНОбороты.РасчетныйДокумент КАК РасчетныйДокумент,
		|	СУММА(ВТ_РасходыПриУСНОбороты.СуммаПриход) КАК СуммаПриход,
		|	ВТ_РасходыПриУСНОбороты.ВидРасхода КАК ВидРасхода,
		|	ВТ_РасходыПриУСНОбороты.СчетУчета КАК СчетУчета,
		|	ВТ_РасходыПриУСНОбороты.ОтражениеВУСН КАК ОтражениеВУСН
		|ПОМЕСТИТЬ ВТ_РасходыПриУСНОборотыСводная
		|ИЗ
		|	ВТ_РасходыПриУСНОбороты КАК ВТ_РасходыПриУСНОбороты
		|
		|СГРУППИРОВАТЬ ПО
		|	ВТ_РасходыПриУСНОбороты.Регистратор,
		|	ВТ_РасходыПриУСНОбороты.РасчетныйДокумент,
		|	ВТ_РасходыПриУСНОбороты.ВидРасхода,
		|	ВТ_РасходыПриУСНОбороты.СчетУчета,
		|	ВТ_РасходыПриУСНОбороты.ОтражениеВУСН
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	РасходыПриУСНОбороты.Регистратор КАК Ссылка
		|ПОМЕСТИТЬ ВТ_ДокументыИсключения
		|ИЗ
		|	ВТ_БольничныеИОтпуска КАК ВТ_БольничныеИОтпуска
		|		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_РасходыПриУСНОборотыСводная КАК РасходыПриУСНОбороты
		|		ПО ВТ_БольничныеИОтпуска.Ссылка = РасходыПриУСНОбороты.Регистратор
		|ГДЕ
		|	РасходыПриУСНОбороты.ВидРасхода = &ВидРасходаНалоги
		|	И РасходыПриУСНОбороты.СчетУчета = &СчетУчетаНДФЛ
		|	И РасходыПриУСНОбороты.Регистратор <> &Регистратор
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	ВТ_БольничныеИОтпуска.ФизическоеЛицо КАК ФизическоеЛицо,
		|	СУММА(РасходыПриУСНОбороты.СуммаПриход) КАК Сумма,
		|	РасходыПриУСНОбороты.ОтражениеВУСН КАК ОтражениеВУСН,
		|	РасходыПриУСНОбороты.РасчетныйДокумент КАК РасчетныйДокумент
		|ПОМЕСТИТЬ ВТ_РасходыМежрасчетныхВыплат
		|ИЗ
		|	ВТ_БольничныеИОтпуска КАК ВТ_БольничныеИОтпуска
		|		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_РасходыПриУСНОборотыСводная КАК РасходыПриУСНОбороты
		|		ПО ВТ_БольничныеИОтпуска.Ссылка = РасходыПриУСНОбороты.Регистратор
		|ГДЕ
		|	НЕ РасходыПриУСНОбороты.Регистратор В
		|				(ВЫБРАТЬ
		|					ВТ_ДокументыИсключения.Ссылка КАК Ссылка
		|				ИЗ
		|					ВТ_ДокументыИсключения)
		|
		|СГРУППИРОВАТЬ ПО
		|	РасходыПриУСНОбороты.РасчетныйДокумент,
		|	ВТ_БольничныеИОтпуска.ФизическоеЛицо,
		|	РасходыПриУСНОбороты.ОтражениеВУСН
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	НачисленнаяЗарплатаИВзносы.ФизическоеЛицо КАК ФизическоеЛицо,
		|	НачисленнаяЗарплатаИВзносы.Сумма КАК Сумма,
		|	НачисленнаяЗарплатаИВзносы.ВидОперации КАК ВидОперации,
		|	НачисленнаяЗарплатаИВзносы.ОблагаетсяЕНВД КАК ОблагаетсяЕНВД,
		|	НачисленнаяЗарплатаИВзносы.СпособОтраженияЗарплатыВБухУчете КАК СпособОтраженияЗарплатыВБухУчете,
		|	НачисленнаяЗарплатаИВзносы.СтатьяРасходов КАК СтатьяРасходов,
		|	НачисленнаяЗарплатаИВзносы.ВидОперацииРасходовЗаСчетФСС КАК ВидОперацииРасходовЗаСчетФСС,
		|	НачисленнаяЗарплатаИВзносы.Подразделение КАК Подразделение,
		|	NULL КАК ОтражениеВУСН,
		|	NULL КАК РасчетныйДокумент
		|ПОМЕСТИТЬ ВТ_НачисленнаяЗарплатаИВзносы
		|ИЗ
		|	ВР_НачисленнаяЗарплатаИВзносы КАК НачисленнаяЗарплатаИВзносы
		|
		|ОБЪЕДИНИТЬ ВСЕ
		|
		|ВЫБРАТЬ
		|	ВТ_РасходыМежрасчетныхВыплат.ФизическоеЛицо,
		|	ВТ_РасходыМежрасчетныхВыплат.Сумма,
		|	&УсловныйВидОперации,
		|	NULL,
		|	NULL,
		|	NULL,
		|	NULL,
		|	NULL,
		|	ВТ_РасходыМежрасчетныхВыплат.ОтражениеВУСН,
		|	ВТ_РасходыМежрасчетныхВыплат.РасчетныйДокумент
		|ИЗ
		|	ВТ_РасходыМежрасчетныхВыплат КАК ВТ_РасходыМежрасчетныхВыплат
		|
		|ИНДЕКСИРОВАТЬ ПО
		|	ФизическоеЛицо
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	НачисленныйНДФЛ.ФизическоеЛицо КАК ФизическоеЛицо,
		|	НачисленныйНДФЛ.Сумма КАК Сумма,
		|	НачисленныйНДФЛ.ВидОперации КАК ВидОперации,
		|	НачисленныйНДФЛ.РегистрацияВНалоговомОргане КАК РегистрацияВНалоговомОргане,
		|	ВЫБОР
		|		КОГДА &УчитыватьСтатьюРасходов
		|			ТОГДА НачисленныйНДФЛ.СтатьяРасходов
		|		ИНАЧЕ ЗНАЧЕНИЕ(Справочник.СтатьиРасходовЗарплата.ПустаяСсылка)
		|	КОНЕЦ КАК СтатьяРасходов
		|ПОМЕСТИТЬ ВТ_НачисленныйНДФЛ
		|ИЗ
		|	&НачисленныйНДФЛ КАК НачисленныйНДФЛ
		|
		|ИНДЕКСИРОВАТЬ ПО
		|	ФизическоеЛицо
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	ВТ_НачисленныйНДФЛ.ФизическоеЛицо КАК ФизическоеЛицо,
		|	ВТ_НачисленныйНДФЛ.ВидОперации КАК ВидОперации,
		|	ВТ_НачисленнаяЗарплатаИВзносы.СпособОтраженияЗарплатыВБухУчете КАК СпособОтраженияЗарплатыВБухУчете,
		|	ВЫБОР
		|		КОГДА &УчитыватьСтатьюРасходов
		|			ТОГДА ВТ_НачисленныйНДФЛ.СтатьяРасходов
		|		ИНАЧЕ ВТ_НачисленнаяЗарплатаИВзносы.СтатьяРасходов
		|	КОНЕЦ КАК СтатьяРасходов,
		|	ВТ_НачисленнаяЗарплатаИВзносы.ОблагаетсяЕНВД КАК ОблагаетсяЕНВД,
		|	ВТ_НачисленныйНДФЛ.Сумма КАК СуммаНалога,
		|	ВТ_НачисленнаяЗарплатаИВзносы.Сумма КАК СуммаДохода,
		|	ВТ_НачисленныйНДФЛ.РегистрацияВНалоговомОргане КАК РегистрацияВНалоговомОргане,
		|	ВТ_НачисленнаяЗарплатаИВзносы.ВидОперацииРасходовЗаСчетФСС КАК ВидОперацииРасходовЗаСчетФСС,
		|	ВЫБОР
		|		КОГДА ВТ_НачисленнаяЗарплатаИВзносы.СпособОтраженияЗарплатыВБухУчете = ЗНАЧЕНИЕ(Справочник.СпособыОтраженияЗарплатыВБухУчете.ПустаяСсылка)
		|				И ВТ_НачисленнаяЗарплатаИВзносы.ВидОперации В (&МассивОперацийРасходовПоСтрахованию)
		|			ТОГДА ЗНАЧЕНИЕ(Перечисление.ОтражениеВУСН.НеПринимаются)
		|		ИНАЧЕ ВТ_НачисленнаяЗарплатаИВзносы.ОтражениеВУСН
		|	КОНЕЦ КАК ОтражениеВУСН,
		|	ВТ_НачисленнаяЗарплатаИВзносы.РасчетныйДокумент КАК РасчетныйДокумент
		|ПОМЕСТИТЬ ВТ_ПромежуточныйНДФЛ
		|ИЗ
		|	ВТ_НачисленнаяЗарплатаИВзносы КАК ВТ_НачисленнаяЗарплатаИВзносы
		|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_НачисленныйНДФЛ КАК ВТ_НачисленныйНДФЛ
		|		ПО ВТ_НачисленнаяЗарплатаИВзносы.ФизическоеЛицо = ВТ_НачисленныйНДФЛ.ФизическоеЛицо
		|			И (ВТ_НачисленнаяЗарплатаИВзносы.ВидОперации В (&МассивОсновныхНачислений)
		|					И ВТ_НачисленныйНДФЛ.ВидОперации = &НДФЛОсновныхНачислений
		|				ИЛИ ВТ_НачисленнаяЗарплатаИВзносы.ВидОперации = &ДивидендыСотрудников
		|					И ВТ_НачисленныйНДФЛ.ВидОперации = &НФДЛДивидендыСотрудникам
		|				ИЛИ ВТ_НачисленнаяЗарплатаИВзносы.ВидОперации = &Дивиденды
		|					И ВТ_НачисленныйНДФЛ.ВидОперации = &НФДЛДивиденды
		|				ИЛИ ВТ_НачисленнаяЗарплатаИВзносы.ВидОперации = &ВыплатыБывшимСотрудникам
		|					И ВТ_НачисленныйНДФЛ.ВидОперации = &НДФЛРасчетыСБывшимиСотрудниками
		|				ИЛИ ВТ_НачисленнаяЗарплатаИВзносы.ВидОперации = &ДоходыКонтрагентов
		|					И ВТ_НачисленныйНДФЛ.ВидОперации = &НДФЛДоходыКонтрагентов
		|				ИЛИ ВТ_НачисленнаяЗарплатаИВзносы.ВидОперации = &ПрочиеРасчетыСПерсоналом
		|					И ВТ_НачисленныйНДФЛ.ВидОперации = &НДФЛПрочиеРасчетыСПерсоналом)
		|			И (ВЫБОР
		|				КОГДА &УчитыватьСтатьюРасходов
		|					ТОГДА ВТ_НачисленнаяЗарплатаИВзносы.СтатьяРасходов = ВТ_НачисленныйНДФЛ.СтатьяРасходов
		|				ИНАЧЕ ИСТИНА
		|			КОНЕЦ)
		|
		|СГРУППИРОВАТЬ ПО
		|	ВТ_НачисленныйНДФЛ.ФизическоеЛицо,
		|	ВТ_НачисленныйНДФЛ.ВидОперации,
		|	ВТ_НачисленнаяЗарплатаИВзносы.СпособОтраженияЗарплатыВБухУчете,
		|	ВТ_НачисленнаяЗарплатаИВзносы.ОблагаетсяЕНВД,
		|	ВТ_НачисленныйНДФЛ.Сумма,
		|	ВТ_НачисленнаяЗарплатаИВзносы.Сумма,
		|	ВТ_НачисленныйНДФЛ.РегистрацияВНалоговомОргане,
		|	ВТ_НачисленнаяЗарплатаИВзносы.ВидОперацииРасходовЗаСчетФСС,
		|	ВТ_НачисленнаяЗарплатаИВзносы.РасчетныйДокумент,
		|	ВЫБОР
		|		КОГДА ВТ_НачисленнаяЗарплатаИВзносы.СпособОтраженияЗарплатыВБухУчете = ЗНАЧЕНИЕ(Справочник.СпособыОтраженияЗарплатыВБухУчете.ПустаяСсылка)
		|				И ВТ_НачисленнаяЗарплатаИВзносы.ВидОперации В (&МассивОперацийРасходовПоСтрахованию)
		|			ТОГДА ЗНАЧЕНИЕ(Перечисление.ОтражениеВУСН.НеПринимаются)
		|		ИНАЧЕ ВТ_НачисленнаяЗарплатаИВзносы.ОтражениеВУСН
		|	КОНЕЦ,
		|	ВЫБОР
		|		КОГДА &УчитыватьСтатьюРасходов
		|			ТОГДА ВТ_НачисленныйНДФЛ.СтатьяРасходов
		|		ИНАЧЕ ВТ_НачисленнаяЗарплатаИВзносы.СтатьяРасходов
		|	КОНЕЦ
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	ВТ_ПромежуточныйНДФЛ.ФизическоеЛицо КАК ФизическоеЛицо,
		|	ВТ_ПромежуточныйНДФЛ.ВидОперации КАК ВидОперации,
		|	СУММА(ВТ_ПромежуточныйНДФЛ.СуммаНалога) КАК СуммаНалога,
		|	СУММА(ВТ_ПромежуточныйНДФЛ.СуммаДохода) КАК СуммаДохода,
		|	ВТ_ПромежуточныйНДФЛ.РегистрацияВНалоговомОргане КАК РегистрацияВНалоговомОргане
		|ПОМЕСТИТЬ ВТ_ПромежуточныйНДФЛИтог
		|ИЗ
		|	ВТ_ПромежуточныйНДФЛ КАК ВТ_ПромежуточныйНДФЛ
		|
		|СГРУППИРОВАТЬ ПО
		|	ВТ_ПромежуточныйНДФЛ.ФизическоеЛицо,
		|	ВТ_ПромежуточныйНДФЛ.ВидОперации,
		|	ВТ_ПромежуточныйНДФЛ.РегистрацияВНалоговомОргане
		|;
		|
		|////////////////////////////////////////////////////////////////////////////////
		|ВЫБРАТЬ
		|	ВТ_ПромежуточныйНДФЛ.ФизическоеЛицо КАК ФизическоеЛицо,
		|	ВТ_ПромежуточныйНДФЛ.ВидОперации КАК ВидОперации,
		|	ВТ_ПромежуточныйНДФЛ.СпособОтраженияЗарплатыВБухУчете КАК СпособОтраженияЗарплатыВБухУчете,
		|	ВТ_ПромежуточныйНДФЛ.СтатьяРасходов КАК СтатьяРасходов,
		|	ВТ_ПромежуточныйНДФЛ.ОблагаетсяЕНВД КАК ОблагаетсяЕНВД,
		|	ВТ_ПромежуточныйНДФЛ.РегистрацияВНалоговомОргане КАК РегистрацияВНалоговомОргане,
		|	ВЫРАЗИТЬ(ЕСТЬNULL(ВЫБОР
		|				КОГДА ЕСТЬNULL(СУММА(ВТ_ПромежуточныйНДФЛИтог.СуммаДохода), 0) = 0
		|					ТОГДА 0
		|				КОГДА ВТ_ПромежуточныйНДФЛ.СуммаДохода = СУММА(ВТ_ПромежуточныйНДФЛИтог.СуммаДохода)
		|					ТОГДА ВТ_ПромежуточныйНДФЛ.СуммаНалога
		|				ИНАЧЕ ВТ_ПромежуточныйНДФЛ.СуммаНалога * (ВТ_ПромежуточныйНДФЛ.СуммаДохода / СУММА(ВТ_ПромежуточныйНДФЛИтог.СуммаДохода))
		|			КОНЕЦ, 0) КАК ЧИСЛО(15, 2)) КАК Сумма,
		|	ВТ_ПромежуточныйНДФЛ.ВидОперацииРасходовЗаСчетФСС КАК ВидОперацииРасходовЗаСчетФСС,
		|	ВТ_ПромежуточныйНДФЛ.ОтражениеВУСН КАК ОтражениеВУСН,
		|	ВТ_ПромежуточныйНДФЛ.РасчетныйДокумент КАК РасчетныйДокумент
		|ИЗ
		|	ВТ_ПромежуточныйНДФЛ КАК ВТ_ПромежуточныйНДФЛ
		|		ЛЕВОЕ СОЕДИНЕНИЕ ВТ_ПромежуточныйНДФЛИтог КАК ВТ_ПромежуточныйНДФЛИтог
		|		ПО ВТ_ПромежуточныйНДФЛ.ФизическоеЛицо = ВТ_ПромежуточныйНДФЛИтог.ФизическоеЛицо
		|			И ВТ_ПромежуточныйНДФЛ.ВидОперации = ВТ_ПромежуточныйНДФЛИтог.ВидОперации
		|			И ВТ_ПромежуточныйНДФЛ.РегистрацияВНалоговомОргане = ВТ_ПромежуточныйНДФЛИтог.РегистрацияВНалоговомОргане
		|
		|СГРУППИРОВАТЬ ПО
		|	ВТ_ПромежуточныйНДФЛ.ФизическоеЛицо,
		|	ВТ_ПромежуточныйНДФЛ.ВидОперации,
		|	ВТ_ПромежуточныйНДФЛ.СпособОтраженияЗарплатыВБухУчете,
		|	ВТ_ПромежуточныйНДФЛ.СтатьяРасходов,
		|	ВТ_ПромежуточныйНДФЛ.ОблагаетсяЕНВД,
		|	ВТ_ПромежуточныйНДФЛ.СуммаНалога,
		|	ВТ_ПромежуточныйНДФЛ.СуммаДохода,
		|	ВТ_ПромежуточныйНДФЛ.РегистрацияВНалоговомОргане,
		|	ВТ_ПромежуточныйНДФЛ.ВидОперацииРасходовЗаСчетФСС,
		|	ВТ_ПромежуточныйНДФЛ.ОтражениеВУСН,
		|	ВТ_ПромежуточныйНДФЛ.РасчетныйДокумент
		|
		|УПОРЯДОЧИТЬ ПО
		|	ФизическоеЛицо,
		|	ВидОперации,
		|	РегистрацияВНалоговомОргане";

		Результат = Запрос.Выполнить().Выгрузить();

		Если ПолучитьФункциональнуюОпцию("УчетЗарплатыИКадровСредствамиБухгалтерии") Тогда
			ЗаполнитьСтатьюРасходовПоВидуОперации(Результат);
		КонецЕсли;