minigun

actor Minigun2 : Minigun replaces Minigun {
  Weapon.SlotNumber 4
  Weapon.SlotPriority 0.75
  Decal "BulletChip"
  states {
    Fire:
      MNGG A 0 A_TakeInventory("MinigunCounter", 3)
      MNGG A 0 A_GunFlash
      MNGG A 4 A_FireBullets(2.8, 1.775, -1, 5)
      MNGG A 0 A_JumpIfNoAmmo("Down3")
      MNGG B 4 A_FireBullets(2.8, 1.775, -1, 5)
      MNGG A 0 A_JumpIfNoAmmo("Down2")
      MNGG A 0 A_GiveInventory("MinigunCounter", 1)
      MNGG A 0 A_ReFire
      goto Down2
    Hold:
      MNGG A 0 A_GunFlash
      MNGG A 0 A_JumpIfInventory("MinigunCounter", 3, "Fire3")
      MNGG A 0 A_JumpIfInventory("MinigunCounter", 2, "Fire2")
      MNGG A 0 A_Jump(32, 3)
      MNGG A 3 A_FireBullets(5.6, 3.55, -1, 5)
      MNGG A 0 A_Jump(256, 2)
      MNGG A 3 A_FireBullets(2.8, 1.775, -1, 5)
      MNGG A 0 A_JumpIfNoAmmo("Down3")
      MNGG B 0 A_Jump(32, 3)
      MNGG B 3 A_FireBullets(5.6, 3.55, -1, 5)
      MNGG B 0 A_Jump(256, 2)
      MNGG B 3 A_FireBullets(2.8, 1.775, -1, 5)
      MNGG A 0 A_JumpIfNoAmmo("Down2")
      MNGG A 0 A_GiveInventory("MinigunCounter", 1)
      MNGG A 0 A_ReFire
      goto Down + 2
    Fire2:
      MNGG A 0 A_Jump(32, 3)
      MNGG A 3 A_FireBullets(5.6, 3.55, -1, 5)
      MNGG A 0 A_Jump(256, 2)
      MNGG A 3 A_FireBullets(2.8, 1.775, -1, 5)
      MNGG A 0 A_JumpIfNoAmmo("Down1")
      MNGG B 0 A_Jump(32, 3)
      MNGG B 2 A_FireBullets(11.2, 7.1, -1, 5)
      MNGG B 0 A_Jump(256, 5)
      MNGG B 0 A_Jump(32, 3)
      MNGG B 2 A_FireBullets(5.6, 3.55, -1, 5)
      MNGG B 0 A_Jump(256, 2)
      MNGG B 2 A_FireBullets(2.8, 1.775, -1, 5)
      MNGG A 0 A_JumpIfNoAmmo("Down")
      MNGG A 0 A_GiveInventory("MinigunCounter", 1)
      MNGG A 0 A_ReFire
      goto Down
    Fire3:
      MNGG A 0 A_Jump(32, 3)
      MNGG A 2 A_FireBullets(11.2, 7.1, -1, 5)
      MNGG A 0 A_Jump(256, 5)
      MNGG A 0 A_Jump(32, 3)
      MNGG A 2 A_FireBullets(5.6, 3.55, -1, 5)
      MNGG A 0 A_Jump(256, 2)
      MNGG A 2 A_FireBullets(2.8, 1.775, -1, 5)
      MNGG A 0 A_JumpIfNoAmmo("Down1")
      MNGG B 0 A_Jump(32, 3)
      MNGG B 2 A_FireBullets(11.2, 7.1, -1, 5)
      MNGG B 0 A_Jump(256, 5)
      MNGG B 0 A_Jump(32, 3)
      MNGG B 2 A_FireBullets(5.6, 3.55, -1, 5)
      MNGG B 0 A_Jump(256, 2)
      MNGG B 2 A_FireBullets(2.8, 1.775, -1, 5)
      MNGG A 0 A_JumpIfNoAmmo("Down")
      MNGG A 0 A_ReFire
    Down:
      MNGG A 2 A_TakeInventory("MinigunCounter", 3)
    Down1:
      MNGG B 2 A_TakeInventory("MinigunCounter", 3)
    Down2:
      MNGG A 4 A_TakeInventory("MinigunCounter", 3)
    Down3:
      MNGG B 4 A_TakeInventory("MinigunCounter", 3)
      MNGG A 8
      MNGG B 8
      MNGG B 0 A_CheckReload
      goto Ready
    Flash:
      MNGF A 0 A_JumpIfInventory("MinigunCounter", 1, "Flash2")
      MNGF A 4 BRIGHT A_Light1
      MNGF B 4 BRIGHT A_Light0
      stop
    Flash2:
      MNGF A 3 BRIGHT A_Light1
      MNGF B 3 BRIGHT A_Light0
      stop
  }
}

actor MinigunCounter : Inventory {
  +INVENTORY.UNDROPPABLE
  Inventory.MaxAmount 3
}