menu.ipxe

#!ipxe
# by dialmak

set target bootitbm

:start-menu
menu  dialmak's BOOT MENU
item --gap Terabyte:
	iseq ${platform} efi || item bootitbm     ${space} BootIt Bare Metal 1.35
	iseq ${platform} efi && item iflguiefi    ${space} Image for Linux 3.05 (GUI)
	iseq ${platform} efi || item iflgui       ${space} Image for Linux 3.05 (GUI)
	item iflcui       ${space} Image for Linux 3.05 (CUI)
	item tbwinre      ${space} TBWinRE7 x64 3.04
item --gap Windows PE by Xemom1:
	iseq ${platform} efi || item pe7x86mini   ${space} WinPE7  x86 mini
	iseq ${platform} efi || item pe8x86mini   ${space} WinPE8  x86 mini
	item pe8x64mini   ${space} WinPE8  x64 mini
	iseq ${platform} efi ||  item pe10x86mini  ${space} WinPE10 x86 mini
item --gap Install:
	item ubuntu64  ${space} Ubuntu x64
item --gap Tools and Diagnostics:
	iseq ${platform} efi || item hddarts      ${space} HDD Tools and Diagnostics
	iseq ${platform} efi || item hdt          ${space} Hardware Detection Tool 0.5.2
	iseq ${platform} efi || item memtest      ${space} MemTest86 4.3.7
	iseq ${platform} efi || item memtest5     ${space} MemTest86+ 5.01
	item shell        ${space} iPXE shell
choose --default ${target} target && goto ${target}
goto start-menu


:iflguiefi
	kernel  ifl/vmlinuz uefimode=yes
	initrd --name initrmfs ifl/initrmfs || read void
	boot || read void
goto start-menu

:iflgui
initrd img/iflnet_gui.iso || goto failed
kernel memdisk iso raw || goto failed
boot || goto failed
goto start-menu

:iflcui
initrd img/iflnet_cui.iso || goto failed
kernel memdisk iso raw || goto failed
boot || goto failed
goto start-menu

:ubuntu64
kernel http://archive.ubuntu.com/ubuntu/dists/yakkety/main/installer-amd64/current/images/netboot/ubuntu-installer/amd64/linux || goto failed
initrd http://archive.ubuntu.com/ubuntu/dists/yakkety/main/installer-amd64/current/images/netboot/ubuntu-installer/amd64/initrd.gz || goto failed
boot || goto failed

:hddarts
initrd img/HDDaRTs.img || goto failed
kernel memdisk raw || goto failed
boot || goto failed
goto start-menu

:hdt
initrd img/hdt-0.5.2.img || goto failed
kernel memdisk raw || goto failed
boot || goto failed
goto start-menu

:bootitbm
initrd img/bootitbm.flp || goto failed
kernel memdisk raw || goto failed
boot || goto failed
goto start-menu

:memtest
chain img/memtest || goto failed
goto start-menu

:memtest5
chain img/memtest5 || goto failed
goto start-menu

:tbwinre
kernel wimboot pause || goto failed
initrd --name BCD bcd BCD || goto failed
initrd --name boot.sdi boot.sdi boot.sdi || goto failed
initrd --name boot.wim img/TBWinRE7x64.wim boot.wim || goto failed
boot || goto failed
goto start-menu


:pe7x86mini
kernel wimboot || goto failed
initrd bootmgr bootmgr || goto failed
initrd bcd bcd || goto failed
initrd boot.sdi boot.sdi || goto failed
initrd img/PE7x86mini.wim boot.wim || goto failed
boot || goto failed
goto start-menu

:pe8x86mini
kernel wimboot || goto failed
initrd bootmgr bootmgr || goto failed
initrd bcd bcd || goto failed
initrd boot.sdi boot.sdi || goto failed
initrd img/PE8x86mini.wim boot.wim || goto failed
boot || goto failed
goto start-menu

:pe8x64mini
kernel wimboot pause || goto failed
iseq ${platform} efi || initrd --name bootmgr bootmgr bootmgr || goto failed
iseq ${platform} efi && initrd --name bootmgfw.efi bootmgfw.efi bootmgfw.efi || goto failed
initrd --name BCD bcd BCD || goto failed
initrd --name boot.sdi boot.sdi boot.sdi || goto failed
initrd --name boot.wim img/PE8x64mini.wim boot.wim || goto failed
boot || goto failed
goto start-menu

:pe10x86mini
kernel wimboot || goto failed
initrd bootmgr bootmgr || goto failed
initrd bcd bcd || goto failed
initrd boot.sdi boot.sdi || goto failed
initrd img/PE10x86mini.wim boot.wim || goto failed
boot || goto failed
goto start-menu

:failed
echo
prompt Booting failed, press any key to back to the menu ...
goto start-menu

:shell
echo Type "help" to get the list commands.
echo Type "<command> --help" to detailed help for a command.
echo Type "exit" to get the back to the menu.
echo
shell
goto start-menu