-	script	ygg_room	-1,{

OnTalk:
set .@map$,strcharinfo(3);
if( select( ( .@map$ != .map$ )?"Enter Yggroom":"Leave Yggroom","close" ) == 1 ){
	if( callsub( OnBotCheck ) ){
		if( .@map$ != .map$ ){
			next;
			mes "You have to pay "+.zeny+" zeny to enter.";
			if( Zeny >= .zeny ){
				if( select( "Pay Zeny and Enter.","Cancel" ) == 1 ){
					set Zeny,Zeny - .zeny;
					warp .map$,0,0;
				}
			}
		}else{
			warp "SavePoint",0,0;
		}
	}
}
close;

OnPCLoginEvent:
if( strcharinfo(3) == .map$ ){
	if( !callsub( OnBotCheck ) ){
		warp "SavePoint",0,0;
	}
}
end;

OnBotCheck:
	mes "Please enter the code given.";
	set .@random$,""+rand( 10000000,999999999 );
	mes "^FF0000"+.@random$+"^000000";
	input .@input$;
	if( .@input$ == .@random$ ){
		mes "Correct";
		return 1;
	}else{
		mes "Wrong.";
	}
	return 0;

OnInit:
set .map$,"guild_vs1-4";
// zeny cost to enter ygg room
set .zeny,10000000;
end;

OnMobKilled:
getitem 607,1;
end;
}

// exit npc...
guild_vs1-4,50,50,5	script	Ygg Room Exit	757,{
	doevent "ygg_room::OnTalk";
}

// entrance npc...
prontera,155,181,5	script	Ygg Room Entrance	757,{
	doevent "ygg_room::OnTalk";
}




guild_vs1-4	mapflag	nocommand	90
guild_vs1-4	mapflag	nomobloot
guild_vs1-4	mapflag	nomvploot


// baphomet jr
guild_vs1-4,0,0,0,0	monster	Baphomet Jr.	1101,100,0,0,"ygg_room::OnMobKilled"