povray chain

#version 3.6;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }}

#include "colors.inc"
#include "textures.inc"

#declare Camera_1 = camera { ultra_wide_angle
                             angle     48
                             location  <7.7,8,-5.0>
                             right     x*image_width/image_height
                             look_at   <4.40, 0.00, 0.0>
                           }
camera{Camera_1}


light_source{<1500,2500,-2500> color White}

sky_sphere{ pigment{  color rgb<1,1,1> }}


#declare Metal_Texture =
         texture { pigment{ color rgb<1,1,1>*0.2}
                   normal { bumps 0.125 scale 0.015}
                   finish { phong 0.5 reflection 0.2}
                 }

#declare R_minor = 0.25;
#declare R_major = 0.75;
#declare Half_L = 0.25;
#declare Link_Length =  2*(R_major);

#declare Left_Half =
union{

 difference{
 torus { R_major, R_minor
           rotate<90,0,0>
       }

 box { <0,-R_major-R_minor,-R_minor>,< R_major+R_minor,R_major+R_minor,R_minor>
     }

 translate<-Half_L,0,0>

 }
 cylinder { <-Half_L,0,0>,<Half_L,0,0>, R_minor
             translate<0,R_major,0>
         }
}

# declare Chain_Link =
union{
object{ Left_Half }
object{ Left_Half scale <-1,-1,1>}
        texture { Metal_Texture
                }
}

union{
 #declare Nr = 0;
 #declare EndNr = 6;
 #while (Nr< EndNr)

   object{Chain_Link
          #if ( int(Nr/2) != Nr/2 )
           rotate<90,0,0>
          #end
           translate < Nr*Link_Length ,0,0>
         }

 #declare Nr = Nr + 1;
 #end

translate<0,0,0>}