toribio

#include <a_samp>

new TowTruckers = 0; // BeckzyBoi removed '= 0' here. However, adding '= 0' makes it more clear to the readers. This does not affect the way this statement is compiled.
new bool:IsTowTrucker[MAX_PLAYERS]; // I added the 'bool' tag to make clear that this is a boolean variable, not a random integer.

public OnFilterScriptInit()
{
    print("\n TowCars Filter Script v1.0 Loading...\n**********************\n");
    print(" By Zeruel_Angel and !damo!spiderman\n");
    print("TowCars Filter Script fully Loaded\n**********************************\n\n");
    return 1; // BeckzyBoi added this, because zeruel_angel forgot.
}

public OnFilterScriptExit()
{
    print("\n TowCars Script UnLoaded\n********************************************\n\n");
    return 1;
    /* BeckzyBoi changed this into 'return print(...)'. However, the pdf does not specify what print returns, so it could be anything. That means it's totally unreliable. We do not want to return anything, we specifically want to return 1. */
}

public OnPlayerStateChange(playerid, newstate, oldstate)
{
    if(newstate == PLAYER_STATE_DRIVER) { // Based on experience, I can tell you that using the '{' on same line as the 'if' improves readability significantly.
        if(GetVehicleModel(GetPlayerVehicleID(playerid)) == 525) {
            IsTowTrucker[playerid] = true; // Changed to 'true' instead of '1'. This makes clear to the readers that is a boolean variable.
            TowTruckers++; // Keep the variable and '++' together. Adding a space may be confusing.
            SendClientMessage(playerid, 0xFFFF00AA, "You can use the ACTION KEY to Tow cars");
        }
        else if(TowTruckers > 0) { // Always use {}s for if-statements, loops, etc.! Not using that makes your code look very sloppy and less readable. Furthermore, it will save you some time when adding multiple statements.
            SendClientMessage(playerid, 0xFFFF00AA, "If you have a problem with your car, use /TowMe to call a TowTruker");
        } // For 'else if' statements it's acceptable to omit the {}s after 'else'.
    }
    else if(newstate == PLAYER_STATE_ONFOOT && IsTowTrucker[playerid]) { // I changed this to 'else if'. It is unnecessairy to execute another if-statement if a previous one was satisfied. BeckzyBoi removed some ()s and '==1' to make the statement more readable.
        IsTowTrucker[playerid] = false; // BeckzyBoi used multiple statements on one line to make sure that the braceless if-statement works. One statement per line makes the code more readable.
        TowTruckers--;
    }
    else if(newstate == PLAYER_STATE_PASSENGER && TowTruckers > 0) {
        SendClientMessage(playerid, 0xFFFF00AA, "If you have a problem with your car, use /TowMe to call a TowTruker");
    }
    return 1;
}

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
    new playerVid = GetPlayerVehicleID(playerid); // GetPlayerVehicleID(playerid) seems to be called a lot. I saved the value in a variable now, so that we do not have to call that function all the time. This makes the code execute a little faster.

    if ((newkeys & KEY_ACTION) && IsPlayerInAnyVehicle(playerid) && GetPlayerState(playerid) == PLAYER_STATE_DRIVER && GetVehicleModel(playerVid) == 525) { // Changed to newkeys & KEY_ACTION to make it work even if other keys are pressed, and merged two if-statements
        SendClientMessage(playerid,0xFFFF00AA,"trying to tow a car");
        new Float:pX,Float:pY,Float:pZ; // BeckzyBoi changed this into a 6-cell array. That makes the code in the if-statement below impossible to understand. Variables have names for a reason. Using an array here doesn't make the code compile more efficiently.
        GetPlayerPos(playerid,pX,pY,pZ);
        new bool:Found = false;

        for(new vid = 0; vid < MAX_VEHICLES; vid++) { // Using a for-loop instead of a while loop in this case makes it very clear to the reader what it does. It also makes your code very clean. I removed the '!Found' expression. It is unnecesairy. (See why later.)
            new Float:vX,Float:vY,Float:vZ; // These variables have to be defined in this loop only. There are not needed anywhere else, and that's why I moved them here. In technical terms: I limited the scope of those variables.
            GetVehiclePos(vid,vX,vY,vZ);

            if(floatabs(pX - vX) < 7.0 && floatabs(pY - vY) < 7.0 && floatabs(pZ - vZ) < 7.0 && vid != playerVid) { // Using variable names, it becomes very clear what this condition will do. The ()s removed by BeckzyBoi also make it much more readable.
                Found = true;
                if(IsTrailerAttachedToVehicle(playerVid)) {
                    DetachTrailerFromVehicle(playerVid);
                }
                AttachTrailerToVehicle(vid,playerVid);
                SendClientMessage(playerid,0xFFFF00AA,"Car towed!");
                break; // Break! We can break out of a loop with this statement. That's why '!Found' is unnecesairy in the loop condition.
            }
        }
        if (!Found) { // At this part, BeckzyBoi got confused by zeruel_angel's weird indentation. It shows perfectly that zeruel_angel's will confuse the reader ;). BeckzyBoi thought this if-statement was part of the loop, but it isn't. This comes AFTER the loop.
            SendClientMessage(playerid, 0xFFFF00AA, "There is no car in range.");
        }
    }
    return 1;
}

public OnPlayerDisconnect(playerid)
{
    if(IsTowTrucker[playerid]) {
        IsTowTrucker[playerid] = false; // Changed to 'false' instead of '1', changed multiple-statement issue again.
        TowTruckers--;
    }
    return 1;
}

public OnPlayerCommandText(playerid, cmdtext[])
{
    if (strcmp(cmdtext, "/TowMe", true) == 0) { // BeckzyBoi changed this to '!...', which is also correct, but confusing with non-boolean return values.
        if (TowTruckers == 0) { // Same thing
            SendClientMessage(playerid, 0xFFFF00AA, "Sorry there isn't any TowTrucker Available at the moment"); // BeckzyBoi used his 'quick-return' thing here again. Again, there is no specification on what this function returns. However, it will probably return 0, which proves my point. We need to return 1 here, to make sure the 'Unknown command' message doesn't show up.
            return 1;
        }
        SendClientMessage(playerid, 0xFFFF00AA, "TowTruckers has been told of your situation, just wait.");
        SendClientMessage(playerid, 0xFFFF00AA, "REMEMBER: Your car can't be towed if you are sitting as the driver");
        new pName[MAX_PLAYER_NAME], msg[60];
        GetPlayerName(playerid, pName, sizeof(pName));
        format(msg, sizeof(msg), "*** %s (id:%d) Need to be Towed ***", pName, playerid);
        for (new i = 0; i < MAX_PLAYERS; i++) {
            if (IsTowTrucker[i]) {
                SendClientMessage(i, 0xFFFF00AA, msg);
            }
        }
        return 1;
    }
    return 0;
}