import groovy.grape.Grape
import groovy.sql.Sql
import groovy.xml.StreamingMarkupBuilder
import org.dbunit.*
import org.dbunit.dataset.xml.*
import org.dbunit.database.*

@Grab('org.dbunit:dbunit:2.4.7')
@Grab('org.slf4j:slf4j-nop:1.5.10')
class DbUnitSampleTest extends GroovyTestCase {

    static {
        Grape.grab(group:'org.hsqldb', module:'hsqldb', version:'1.8.0.10', classLoader:DbUnitSampleTest.classLoader.rootLoader)
        Sql.newInstance('jdbc:hsqldb:db/sample', 'sa', '', 'org.hsqldb.jdbcDriver').execute """
            CREATE TABLE emp (
                empno INTEGER PRIMARY KEY,
                ename VARCHAR(10),
                job VARCHAR(9)
            );"""
    }

    def tester

    void setUp() {
        tester = new JdbcDatabaseTester('org.hsqldb.jdbcDriver', 'jdbc:hsqldb:db/sample', 'sa', '')
    }

    void testDelete() {
        tester.dataSet = dataSet {
            emp empno:7369, ename:'SMITH', job:'CLERK'
            emp empno:7499, ename:'ALLEN', job:'SALESMAN'
            emp empno:7521, ename:'WARD', job:'SALESMAN'
        }
        tester.onSetup()

        assert 1 == Sql.newInstance('jdbc:hsqldb:db/sample', 'sa', '', 'org.hsqldb.jdbcDriver')
            .executeUpdate('delete from emp where empno = 7499')

        Assertion.assertEquals dataSet {
            emp empno:7369, ename:'SMITH', job:'CLERK'
            emp empno:7521, ename:'WARD', job:'SALESMAN'
        }, tester.connection.createDataSet()
    }

    def dataSet(c) {
        new FlatXmlDataSet(new StringReader(new StreamingMarkupBuilder().bind{dataset c}.toString()))
    }
}