Full output:
sh3eb-elf-gcc -MMD -MP -MF D:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/build/ilram.d   -ID:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/build -ID:\Downloads\PrizmSDK-master\PrizmSDK-master/include -mb -m4a-nofpu -mhitachi -nostdlib -Og -Wall -ffunction-sections -fdata-sections -c D:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/src/ilram.c -o ilram.o
sh3eb-elf-gcc -MMD -MP -MF D:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/build/main.d   -ID:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/build -ID:\Downloads\PrizmSDK-master\PrizmSDK-master/include -mb -m4a-nofpu -mhitachi -nostdlib -Og -Wall -ffunction-sections -fdata-sections -c D:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/src/main.c -o main.o
python ../link_script.py sh3eb-elf-gcc   ilram.o main.o -mb -m4a-nofpu -mhitachi -nostdlib -Wl,-static -Wl,-gc-sections  -LD:\Downloads\PrizmSDK-master\PrizmSDK-master/lib -lc -lfxcg -lgcc -o D:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/GlobalCode.bin
Memory region         Used Size  Region Size  %age Used
             rom:        7032 B         1 MB      0.67%
             ram:        6400 B        64 KB      9.77%
           ilram:           4 B         4 KB      0.10%
mkg3a -n basic:GlobalCode -i uns:../unselected.bmp -i sel:../selected.bmp D:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/GlobalCode.bin D:/Downloads/PrizmSDK-master/PrizmSDK-master/projects/GlobalCode/GlobalCode.g3a

link_script.x:

OUTPUT_FORMAT(binary)
OUTPUT_ARCH(sh3)

/* Entry point.  Not really important here, since doing binary output */
ENTRY(initialize)

MEMORY
{
        /* Loads code at 300000, skips g3a header */
        rom (rx) : o = 0x00300000, l = 1024k
        ram (rwx) : o = 0x08100004, l = 64k  /* pretty safe guess */
        ilram (rwx) : o = 0xe5200000, l = 4k /* According to http://www.cemetech.net/forum/viewtopic.php?t=9334 */
}

SECTIONS
{
        /* Code, in ROM */
        .text : {
                *(.pretext)     /* init stuff */
                main.o (.text)
        } > rom

        /* VMA in ILRAM but LMA in ROM */
        .ilram : {
                _ilramld = LOADADDR(.ilram) ;
                _silram = . ;

                /* All data in standard order */
                ilram.o (.text)
                ilram.o (.text.*)
                ilram.o (.rodata)
                ilram.o (.rodata.*)
                ilram.o (.data)
                ilram.o (.data.*)
                ilram.o (.bss)
                ilram.o (.bss*)
                ilram.o (COMMON)

			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (.text)
			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (.text.*)
			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (.rodata)
			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (.rodata.*)
			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (.data)
			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (.data.*)
			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (.bss)
			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (.bss.*)
			*lib\libfxcg.a:Bdisp_PutDisp_DD.o (COMMON)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (.text)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (.text.*)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (.rodata)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (.rodata.*)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (.data)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (.data.*)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (.bss)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (.bss.*)
			*lib\libfxcg.a:Bdisp_SetPoint_VRAM.o (COMMON)

                _eilram = . ;
        } > ilram AT> rom

        /* Rest of .text section, from main.o */
        .text : {
                *(.text)
                *(.text.*)
        } > rom

        /* Read-only data, in ROM */
        .rodata : {
                *(.rodata)
                *(.rodata.*)
        } > rom

        .comment : {
                *(.comment)
        }

        /* RW initialized data, VMA in RAM but LMA in ROM */
        .data : ALIGN(4) {
                _datald = LOADADDR(.data) ;
                _sdata = . ;
                *(.data)
                *(.data.*);
                _edata = . ;
        } >ram AT>rom

        /* Uninitialized data (fill with 0), in RAM */
        .bss : ALIGN(4) {
                _bbss = . ;
                *(.bss)
                *(.bss*)
                *(COMMON)
                _ebss = . ;
        } >ram
}