Gold Star Clicker!

Let's make a game!
	name:Gold Star Clicker
	by:Ming
	desc:MEWW<//>shoot for the stars!
	created:3/12/2018
	updated:3/12/2017
	version:1

Settings
	background:https://cdn.arstechnica.net/wp-content/uploads/2018/03/heic1806a-800x533.jpg
	building cost increase:115%
	building cost refund:50%
	spritesheet:icons, 48 by 48, stuff/bunnyIcons.png
	stylesheet:stuff/bigBlue.css

CSS
  #game
  {
    background:#424242;
    font-family:"Oswald",Oswald,sansserif;
    font-size:14px;
    color:white;
  }
  .creamFX1 .thing{
    position:relative;
	height:256px;
	width:256px;
    left:160px;
	top:260px;
    }
  .creamFX2 .thing-icon{
	height:256px;
	width:256px;
    }
  .catfishFX .thing-icon{
    position:relative;
	height:100px;
	width:300px;
    }
Layout
	use default

Buttons
	*starButton
		name:Earn a Star
		desc:Click this gold star to get gold stars!!!
		on click:anim icon wobble
		on click:yield (1+(creamtracker*(creamboost))) star
		icon:https://i.imgur.com/nnWuoOe.png
		no text
		class:bigButton
		icon class:shadowed
		tooltip origin:bottom
		tooltip class:red
	*creamButton
		name:get the cream!!
		desc:Click to trade in 50 gold stars for 1 ice cream!!!
		on click:
			if (stars>=50)
				yield 1 cream
				lose 50 stars
			end
		end
		icon:https://www.emoji.co.uk/files/apple-emojis/food-drink-ios/399-soft-ice-cream.png
		no text
		class:creamFX1 creamFX2 noBackground
		icon class:shadowed
		tooltip origin:bottom
		tooltip class:red
		hidden

Resources
	*star|stars
		name:Gold Star|Gold Stars
		desc:These are your gold stars. Get to 50 gold stars for free ice cream!!!!
		icon:http://www.pngmart.com/files/1/Gold-Star-Sticker-PNG-Image.png
		on tick:if ((stars:earned)>=50) show creamButton
		class:noBackground
		show earned
	*cream|creams
		name:Ice Cream|Ice Creams
		desc:Ice cream!!!! Click to eat it and feel good! (not 2 much or u wil be sick)<//>Eaten: <b>[creamtracker]</b><//>[?creamtracker=10|<#80acf2>You are experiencing <b>brain freeze</b>. you cant eat any more ice cream :(</#>|]
		icon:http://www.stickpng.com/assets/images/580b57fcd9996e24bc43c1be.png
		on click:
			if (10>creamtracker)
				yield 1 creamtracker
				lose 1 cream
			end
		end
		class:noBackground
		show earned
		req:(creams:earned)>0
	*creamtracker
		always hidden
	*cfTime
	*cfClicked
		on tick:if ((cfClicked)>1) cfClicked is 1
		on earn:
			if ((cfStreak)>=0) yield 1 cfStreak
			else if (0>(cfStreak)) cfStreak is 1
		end
		on loss:
			if (0>=(cfStreak)) lose 1 cfStreak
			else if ((cfStreak)>0) cfStreak is -1
		end
		always hidden
	*cfStreak
		can be negative
		always hidden
	*meat
		name:Catfish Meat
		desc:i try to eat but it does NOT taste good. use as currency instead.<//><b>Catfish Info:</b><.>Total Catfish Clicks: [catfish:clicks]<.>Current Stars Stolen: [stolenStars]<.>Current Catfish Streak: [?cfStreak>0|[cfStreak] consecutive click[s?cfStreak]|[cfStreak*-1] consecutive raid[s?cfStreak*-1]]
		icon:https://img00.deviantart.net/5a0d/i/2018/303/f/f/fish_catfish_on_a_transparent_background__by_zoostock-dcqpq0a.png
		class:noBackground
		show earned
		req:(catfish:clicks)>0
	*stolenStars
		always hidden
Shinies
	*catfish
        icon:https://i.imgur.com/3RKM316.png
		movement:onRight moveLeft wiggle bobVertical
		duration:10
		on click:
			yield 1 cfClicked
			do meatyield
			toast Catfish clicked! [?stolenStars>0|+[stolenStars*1.5] stars!|]
			yield ((stolenStars)*1.5) stars
			lose stolenStars
		end
		on meatyield:
			if ((cfStreak)=0) yield random(5,6) meat
			else if (((cfStreak)=1) or ((cfStreak)=2)) yield random(4,6) meat
			else if ((cfStreak)>2) yield random(2,6) meat
			else if (((cfStreak)=-1) or ((cfStreak)=-2)) yield random(3,6) meat
			else if (-2>(cfStreak)) yield random(5,6) meat
		end
		class:catfishFX

Buildings
	*krispion|krispions
		name:Krispion|Krispions
		desc:BIG strong man to giv u gold star ((he kind of stingy tho))<//><b>Effect:</b><.>Produces a gold star every 2 seconds.
		icon:https://avatars3.githubusercontent.com/u/27762896?s=400&v=4
		cost:50 stars
		on tick:yield 0.5 stars
		unlocked

	*hamboy|hamboys
		name:Hamboy|Hamboys
		desc:cute GENEROSE smol pig to dispense MANY star ((mewmewmewm))<//><b>Effect:</b><.>Produces 5 gold stars every second.
		icon:https://cdn.discordapp.com/attachments/353739509675851777/519296723714179084/ham.png
		cost:800 stars
		on tick:yield 5 stars
		req:400 stars:earned
		unlocked

	*deryk|deryks
		name:Deryk|Deryks
		desc:VERy smol pengu to encourage other people to be nicer (nya)<//><b>Effect:</b><.>multiplies efficiency of other buildings by 10%. (additive)
		icon:https://cdn.discordapp.com/attachments/353739509675851777/519308295551451136/deryk.png
		cost:10 creams
		cost increase:100%
		passive:
			increase yield of krispion by .05
			increase yield of hamboy by .5
		end
		req:10 creamtracker
		unlocked

Upgrades
	*creamboost
		name:Sugar Rush
		desc:mewmwmemwemwemwemewmmwemew<//><b>Effect:</b><.>+1 star per click for every ice cream eaten
		icon:http://www.stickpng.com/assets/images/580b57fcd9996e24bc43c1be.png
		cost:1 cream
		req:1 creamtracker:earned

	*catfishunlock
		name:Star Beacon
		desc:summons the GREAT and MIGHTY catfish, alena...<//><b>Effect:</b><.>A catfish will spawn once every couple minutes, stealing stars unless it is clicked. Drops unique rewards when attacked, along with 150% of the stars it has stolen.
		icon:https://cdn.discordapp.com/avatars/433719780902436905/b57f697cae9ea7c6d7c45315f74379fd.png?size=64
		cost:25 cream
		on earn:cfTime=random(120,140)
		on tick:
			yield -1 cfTime
			if ((cfTime)=10) spawn catfish
			if ((cfTime)=0) do reset
		end
		on reset:
			if ((cfClicked)=0)
				$starSteal=((stars:ps)*random(45,75))
				lose $starSteal stars
				yield $starSteal stolenStars
				toast Catfish raid! You lost [$starSteal] stars.
				do loss with cfClicked
			end
			if ((cfClicked)>0) lose 1 cfClicked
			yield random(120,140) cfTime
		end
		on click:cfTime is 10
		req:25 cream:earned

Achievements
	*cheevo1
		name:You can get free ice cream!!!!!!
		desc:u got 50 stars!!.<//><i>Oh no u have bankrupted the crown :ppogsda</i>
		req:50 stars
		icon:http://www.pngmart.com/files/1/Gold-Star-Sticker-PNG-Image.png
	*cheevo2
		name:You ate ice cream!!!!!!
		desc:mew!!<//><i>krispion says eat ur dinner first but U DISOBEY (hehe)</i>
		req:1 creamtracker
		icon:http://www.pngmart.com/files/1/Gold-Star-Sticker-PNG-Image.png
	*cheevo3
		name:too much ice cream....
		desc:mew..<//><i>krpoisn warned u. bad cat.</i>
		req:10 creamtracker
		icon:http://www.pngmart.com/files/1/Gold-Star-Sticker-PNG-Image.png