API tools faq
paste
thephoenixlodge

S2 plankcrafting script

thephoenixlodge
Mar 9th, 2018
267
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 17.19 KB | None | 0 0
raw download clone embed print report
  1. ////Imports
  2. import crafttweaker.item.IItemStack;
  3. import crafttweaker.item.IIngredient;
  4. import crafttweaker.item.IItemDefinition;
  5. import mods.artisanworktables.builder.RecipeBuilder;
  6.  
  7. ////Variables
  8. //Tools
  9. val planer = <earthworks:tool_hand_planer>;
  10. val heavySaw = <earthworks:tool_saw>;
  11. val artisansSaw = <ore:artisansHandsaw>;
  12. val water = <liquid:water>;
  13.  
  14. //Bark - not actually used atm, more just for reference
  15. val barkOak = <leatherworks:bark_oak>;
  16. val barkSpruce = <leatherworks:bark_spruce>;
  17. val barkBirch = <leatherworks:bark_birch>;
  18. val barkJungle = <leatherworks:bark_jungle>;
  19. val barkAcacia = <leatherworks:bark_acacia>;
  20. val barkDarkOak = <leatherworks:bark_darkoak>;
  21.  
  22. //Logs - see bark comment
  23. val logOak = <minecraft:log>;
  24. val logSpruce = <minecraft:log:1>;
  25. val logBirch = <minecraft:log:2>;
  26. val logJungle = <minecraft:log:3>;
  27. val logAcacia = <minecraft:log2>;
  28. val logDarkOak = <minecraft:log2:1>;
  29. val logSkyroot = <aether_legacy:aether_log>;
  30. val logGoldenOak = <aether_legacy:aether_log:1>;
  31. val logAshen = <plants2:nether_log>;
  32. val logBlazing = <plants2:nether_log:1>;
  33. val logBlackKauri = <plants2:log_0>;
  34. val logBrazilianPine = <plants2:log_0:1>;
  35. val logIncenseCedar = <plants2:log_0:2>;
  36. val logMurrayPine = <plants2:log_0:3>;
  37. val logCrystal = <plants2:crystal_log>;
  38. val logDarkCrystal = <plants2:crystal_log:1>;
  39. val logOlive = <rustic:log>;
  40. val logIronwood = <rustic:log:1>;
  41. val logApple = <terraqueous:trunk1>;
  42. val logCherry = <terraqueous:trunk1:1>;
  43. val logOrange = <terraqueous:trunk1:2>;
  44. val logPear = <terraqueous:trunk1:3>;
  45. val logPeach = <terraqueous:trunk1:4>;
  46. val logMango = <terraqueous:trunk2>;
  47. val logLemon = <terraqueous:trunk2:1>;
  48. val logPlum = <terraqueous:trunk2:2>;
  49. val logCoconut = <terraqueous:trunk2:3>;
  50. val logBanana = <terraqueous:trunk2:4>;
  51. val logWeedwood = <thebetweenlands:log_weedwood>;
  52. val logRubber = <thebetweenlands:log_rubber>;
  53. val logWeedwood2 = <thebetweenlands:weedwood>;
  54. val logGiantRoot = <thebetweenlands:giant_root>;
  55. val logTwilightOak = <twilightforest:twilight_log>;
  56. val logCanopyTree = <twilightforest:twilight_log:1>;
  57. val logMangrove = <twilightforest:twilight_log:2>;
  58. val logDarkwood = <twilightforest:twilight_log:3>;
  59. val logGiant = <twilightforest:giant_log>;
  60. val logWisdomwood = <wizardry:wisdom_wood_log>;
  61. val logOakDebarked = <leatherworks:debarked_log_oak>;
  62. val logSpruceDebarked = <leatherworks:debarked_log_spruce>;
  63. val logBirchDebarked = <leatherworks:debarked_log_birch>;
  64. val logJungleDebarked = <leatherworks:debarked_log_jungle>;
  65. val logAcaciaDebarked = <leatherworks:debarked_log_acacia>;
  66. val logDarkOakDebarked = <leatherworks:debarked_log_darkoak>;
  67. val logOakTimber = <earthworks:block_timber>;
  68. val logSpruceTimber = <earthworks:block_timber_spruce>;
  69. val logBirchTimber = <earthworks:block_timber_birch>;
  70. val logJungleTimber = <earthworks:block_timber_jungle>;
  71. val logAcaciaTimber = <earthworks:block_timber_acacia>;
  72. val logDarkOakTimber = <earthworks:block_timber_dark_oak>;
  73.  
  74. //planks - see note on logs
  75. val plankOak = <minecraft:planks>;
  76. val plankSpruce = <minecraft:planks:1>;
  77. val plankBirch = <minecraft:planks:2>;
  78. val plankJungle = <minecraft:planks:3>;
  79. val plankAcacia = <minecraft:planks:4>;
  80. val plankDarkOak = <minecraft:planks:5>;
  81. val plankSkyroot = <aether_legacy:skyroot_plank>;
  82. val plankAshen = <plants2:planks>;
  83. val plankBlazing = <plants2:planks:1>;
  84. val plankBlackKauri = <plants2:planks:2>;
  85. val plankBrazilianPine = <plants2:planks:3>;
  86. val plankIncenseCedar = <plants2:planks:4>;
  87. val plankMurrayPine = <plants2:planks:5>;
  88. val plankCrystal = <plants2:crystal_planks>;
  89. val plankDarkCrystal = <plants2:crystal_planks:1>;
  90. val plankOlive = <rustic:planks>;
  91. val plankIronwood = <rustic:planks:1>;
  92. val plankApple = <terraqueous:planks>;
  93. val plankCherry = <terraqueous:planks:1>;
  94. val plankOrange = <terraqueous:planks:2>;
  95. val plankPear = <terraqueous:planks:3>;
  96. val plankPeach = <terraqueous:planks:4>;
  97. val plankMango = <terraqueous:planks:5>;
  98. val plankLemon = <terraqueous:planks:6>;
  99. val plankPlum = <terraqueous:planks:7>;
  100. val plankCoconut = <terraqueous:planks:8>;
  101. val plankBanana = <terraqueous:planks:9>;
  102. val plankWeedwood = <thebetweenlands:weedwood_planks>;
  103. val plankRubber = <thebetweenlands:rubber_tree_planks>;
  104. val plankGiantRoot = <thebetweenlands:giant_root_planks>;
  105. val plankGiant = plankOak * 16;
  106. val plankWisdomwood = <wizardry:wisdom_wood_planks>;
  107. val plankOakVert = <quark:vertical_planks>;
  108. val plankSpruceVert = <quark:vertical_planks:1>;
  109. val plankBirchVert = <quark:vertical_planks:2>;
  110. val plankJungleVert = <quark:vertical_planks:3>;
  111. val plankAcaciaVert = <quark:vertical_planks:4>;
  112. val plankDarkOakVert = <quark:vertical_planks:5>;
  113.  
  114. //MistyWeird - see note on planks
  115. val woodUmbrella = <mist:acacia_block>.definition;
  116. val woodTrembling = <mist:aspen_block>.definition;
  117. val woodAraucaria = <mist:a_tree_block>.definition;
  118. val woodDeceiver = <mist:birch_block>.definition;
  119. val woodFoggyOak = <mist:oak_block>.definition;
  120. val woodFoggyPine = <mist:pine_block>.definition;
  121. val woodSwampyPoplar = <mist:poplar_block>.definition;
  122. val woodSnow = <mist:snow_block>.definition;
  123. val woodPrickly = <mist:spruce_block>.definition;
  124. val woodStone = <mist:s_tree_block>.definition;
  125. val woodTropic = <mist:t_tree_block>.definition;
  126. val woodWeeping = <mist:willow_block>.definition;
  127.  
  128. //where the magic happens
  129. // log : plank
  130. var planksForLogsModded = {
  131. <aether_legacy:aether_log> : <aether_legacy:skyroot_plank>,
  132. <aether_legacy:aether_log:1> : <aether_legacy:skyroot_plank>,
  133. <plants2:nether_log> : <plants2:planks>,
  134. <plants2:nether_log:1> : <plants2:planks:1>,
  135. <plants2:log_0> : <plants2:planks:2>,
  136. <plants2:log_0:1> : <plants2:planks:3>,
  137. <plants2:log_0:2> : <plants2:planks:4>,
  138. <plants2:log_0:3> : <plants2:planks:5>,
  139. <plants2:crystal_log> : <plants2:crystal_planks>,
  140. <plants2:crystal_log:1> : <plants2:crystal_planks:1>,
  141. <rustic:log> : <rustic:planks>,
  142. <rustic:log:1> : <rustic:planks:1>,
  143. <terraqueous:trunk1> : <terraqueous:planks>,
  144. <terraqueous:trunk1:1> : <terraqueous:planks:1>,
  145. <terraqueous:trunk1:2> : <terraqueous:planks:2>,
  146. <terraqueous:trunk1:3> : <terraqueous:planks:3>,
  147. <terraqueous:trunk1:4> : <terraqueous:planks:4>,
  148. <terraqueous:trunk2> : <terraqueous:planks:5>,
  149. <terraqueous:trunk2:1> : <terraqueous:planks:6>,
  150. <terraqueous:trunk2:2> : <terraqueous:planks:7>,
  151. <terraqueous:trunk2:3> : <terraqueous:planks:8>,
  152. <terraqueous:trunk2:4> : <terraqueous:planks:9>,
  153. <thebetweenlands:log_weedwood> : <thebetweenlands:weedwood_planks>,
  154. <thebetweenlands:log_rubber> : <thebetweenlands:rubber_tree_planks>,
  155. <thebetweenlands:weedwood> : <thebetweenlands:weedwood_planks>,
  156. <thebetweenlands:giant_root> : <thebetweenlands:giant_root_planks>,
  157. <twilightforest:twilight_log> : <minecraft:planks>,
  158. <twilightforest:twilight_log:1> : <minecraft:planks:1>,
  159. <twilightforest:twilight_log:2> : <minecraft:planks:2>,
  160. <twilightforest:twilight_log:3> : <minecraft:planks:1>,
  161. <wizardry:wisdom_wood_log> : <wizardry:wisdom_wood_planks>,
  162. <leatherworks:debarked_log_oak> : <minecraft:planks>,
  163. <leatherworks:debarked_log_spruce> : <minecraft:planks:1>,
  164. <leatherworks:debarked_log_birch> : <minecraft:planks:2>,
  165. <leatherworks:debarked_log_jungle> : <minecraft:planks:3>,
  166. <leatherworks:debarked_log_acacia> : <minecraft:planks:4>,
  167. <leatherworks:debarked_log_darkoak> : <minecraft:planks:5>,
  168. <earthworks:block_timber> : <quark:vertical_planks>,
  169. <earthworks:block_timber_spruce> : <quark:vertical_planks:1>,
  170. <earthworks:block_timber_birch> : <quark:vertical_planks:2>,
  171. <earthworks:block_timber_jungle> : <quark:vertical_planks:3>,
  172. <earthworks:block_timber_acacia> : <quark:vertical_planks:4>,
  173. <earthworks:block_timber_dark_oak> : <quark:vertical_planks:5>
  174. } as IItemStack[IItemStack];
  175. var planksForLogsVanilla = {
  176. <minecraft:log> : <minecraft:planks>,
  177. <minecraft:log:1> : <minecraft:planks:1>,
  178. <minecraft:log:2> : <minecraft:planks:2>,
  179. <minecraft:log:3> : <minecraft:planks:3>,
  180. <minecraft:log2> : <minecraft:planks:4>,
  181. <minecraft:log2:1> : <minecraft:planks:5>
  182. } as IItemStack[IItemStack];
  183. var bark = {
  184. <minecraft:log> : <leatherworks:bark_oak>,
  185. <minecraft:log:1> : <leatherworks:bark_spruce>,
  186. <minecraft:log:2> : <leatherworks:bark_birch>,
  187. <minecraft:log:3> : <leatherworks:bark_jungle>,
  188. <minecraft:log2> : <leatherworks:bark_acacia>,
  189. <minecraft:log2:1> : <leatherworks:bark_darkoak>
  190. } as IItemStack[IItemStack];
  191. var mistyWoods = {
  192. <mist:acacia_block>.definition : <mist:acacia_step>,
  193. <mist:aspen_block>.definition : <mist:aspen_step>,
  194. <mist:a_tree_block>.definition : <mist:a_tree_step>,
  195. <mist:birch_block>.definition : <mist:birch_step>,
  196. <mist:oak_block>.definition : <mist:oak_step>,
  197. <mist:pine_block>.definition : <mist:pine_step>,
  198. <mist:poplar_block>.definition : <mist:poplar_step>,
  199. <mist:snow_block>.definition : <mist:snow_step>,
  200. <mist:spruce_block>.definition : <mist:spruce_step>,
  201. <mist:s_tree_block>.definition : <mist:s_tree_step>,
  202. <mist:t_tree_block>.definition : <mist:t_tree_step>,
  203. <mist:willow_block>.definition : <mist:willow_step>
  204. } as IItemStack[IItemDefinition];
  205. var mistyLogMeta = [0,4,7,11] as int[];
  206. var mistyPlankMeta = 13;
  207.  
  208. //recipes.removeShapeless(plankOak * 64, [logGiant]);
  209.  
  210. //proof I'm going mad
  211. for log, plank in planksForLogsModded {
  212. recipes.remove(plank);
  213.  
  214. mods.recipestages.Recipes.addShapeless("free_woodcrafting", plank * 2, [log]);
  215.  
  216. RecipeBuilder.get("basic")
  217. .setShapeless([log])
  218. .setTool(artisansSaw, 1)
  219. .addOutput(plank * 4)
  220. .requireGameStages("ALL", ["woodcutting_1"])
  221. .create();
  222.  
  223. RecipeBuilder.get("basic")
  224. .setShapeless([log])
  225. .setTool(artisansSaw, 1)
  226. .setFluid(water * 50)
  227. .addOutput(plank * 6)
  228. .requireGameStages("ALL", ["woodcutting_1", "lubricated_saws"])
  229. .create();
  230.  
  231. RecipeBuilder.get("basic")
  232. .setShapeless([log])
  233. .setTool(artisansSaw, 1)
  234. .setTool(planer, 1)
  235. .addOutput(plank * 8)
  236. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2"])
  237. .create();
  238.  
  239. RecipeBuilder.get("basic")
  240. .setShapeless([log])
  241. .setTool(artisansSaw, 2)
  242. .setTool(planer, 2)
  243. .setFluid(water * 100)
  244. .addOutput(plank * 10)
  245. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "lubricated_saws"])
  246. .create();
  247.  
  248. RecipeBuilder.get("basic")
  249. .setShapeless([log])
  250. .setTool(artisansSaw, 3)
  251. .setTool(planer, 2)
  252. .setTool(heavySaw, 1)
  253. .addOutput(plank * 12)
  254. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3"])
  255. .create();
  256.  
  257. RecipeBuilder.get("basic")
  258. .setShapeless([log])
  259. .setTool(artisansSaw, 4)
  260. .setTool(planer, 3)
  261. .setTool(heavySaw, 2)
  262. .setFluid(water * 250)
  263. .addOutput(plank * 16)
  264. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3", "lubricated_saws"])
  265. .create();
  266. }
  267.  
  268. for logV, plankV in planksForLogsVanilla {
  269. recipes.removeShaped(plankV, [[logV]]);
  270. recipes.removeShapeless(plankV, [logV]);
  271.  
  272. mods.recipestages.Recipes.addShapeless("free_woodcrafting", plankV * 2, [logV]);
  273.  
  274. RecipeBuilder.get("basic")
  275. .setShapeless([logV])
  276. .setTool(artisansSaw, 1)
  277. .addOutput(plankV * 4)
  278. .requireGameStages("ALL", ["woodcutting_1"])
  279. .excludeGameStages(["bark_saving"])
  280. .create();
  281.  
  282. RecipeBuilder.get("basic")
  283. .setShapeless([logV])
  284. .setTool(artisansSaw, 1)
  285. .addOutput(plankV * 4)
  286. .setExtraOutputOne(bark[logV], 1)
  287. .setExtraOutputTwo(bark[logV], 0.2)
  288. .setExtraOutputThree(bark[logV], 0.05)
  289. .requireGameStages("ALL", ["woodcutting_1", "bark_saving"])
  290. .create();
  291.  
  292. RecipeBuilder.get("basic")
  293. .setShapeless([logV])
  294. .setTool(artisansSaw, 1)
  295. .setFluid(water * 50)
  296. .addOutput(plankV * 6)
  297. .requireGameStages("ALL", ["woodcutting_1", "lubricated_saws"])
  298. .create();
  299.  
  300. RecipeBuilder.get("basic")
  301. .setShapeless([logV])
  302. .setTool(artisansSaw, 1)
  303. .setTool(planer, 1)
  304. .addOutput(plankV * 8)
  305. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2"])
  306. .excludeGameStages(["bark_saving"])
  307. .create();
  308.  
  309. RecipeBuilder.get("basic")
  310. .setShapeless([logV])
  311. .setTool(artisansSaw, 1)
  312. .setTool(planer, 1)
  313. .addOutput(plankV * 8)
  314. .setExtraOutputOne(bark[logV], 1)
  315. .setExtraOutputTwo(bark[logV], 0.4)
  316. .setExtraOutputThree(bark[logV], 0.1)
  317. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "bark_saving"])
  318. .create();
  319.  
  320. RecipeBuilder.get("basic")
  321. .setShapeless([logV])
  322. .setTool(artisansSaw, 2)
  323. .setTool(planer, 2)
  324. .setFluid(water * 100)
  325. .addOutput(plankV * 10)
  326. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "lubricated_saws"])
  327. .create();
  328.  
  329. RecipeBuilder.get("basic")
  330. .setShapeless([logV])
  331. .setTool(artisansSaw, 3)
  332. .setTool(planer, 2)
  333. .setTool(heavySaw, 1)
  334. .addOutput(plankV * 12)
  335. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3"])
  336. .excludeGameStages(["bark_saving"])
  337. .create();
  338.  
  339. RecipeBuilder.get("basic")
  340. .setShapeless([logV])
  341. .setTool(artisansSaw, 3)
  342. .setTool(planer, 2)
  343. .setTool(heavySaw, 1)
  344. .addOutput(plankV * 12)
  345. .setExtraOutputOne(bark[logV], 1)
  346. .setExtraOutputTwo(bark[logV], 0.6)
  347. .setExtraOutputThree(bark[logV], 0.25)
  348. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3", "bark_saving"])
  349. .create();
  350.  
  351. RecipeBuilder.get("basic")
  352. .setShapeless([logV])
  353. .setTool(artisansSaw, 4)
  354. .setTool(planer, 3)
  355. .setTool(heavySaw, 2)
  356. .setFluid(water * 250)
  357. .addOutput(plankV * 16)
  358. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3", "lubricated_saws"])
  359. .create();
  360. }
  361.  
  362. for wood, timber in mistyWoods {
  363.  
  364. recipes.remove(timber);
  365. recipes.addShapeless(timber * 4, [wood.makeStack(mistyPlankMeta)]);
  366.  
  367. for i in mistyLogMeta {
  368. mods.recipestages.Recipes.addShapeless("free_woodcrafting", wood.makeStack(mistyPlankMeta) * 2, [wood.makeStack(i)]);
  369.  
  370. RecipeBuilder.get("basic")
  371. .setShapeless([wood.makeStack(i)])
  372. .setTool(artisansSaw, 1)
  373. .addOutput(wood.makeStack(mistyPlankMeta) * 4)
  374. .requireGameStages("ALL", ["woodcutting_1"])
  375. .create();
  376.  
  377. RecipeBuilder.get("basic")
  378. .setShapeless([wood.makeStack(i)])
  379. .setTool(artisansSaw, 1)
  380. .setFluid(water * 50)
  381. .addOutput(wood.makeStack(mistyPlankMeta) * 6)
  382. .requireGameStages("ALL", ["woodcutting_1", "lubricated_saws"])
  383. .create();
  384.  
  385. RecipeBuilder.get("basic")
  386. .setShapeless([wood.makeStack(i)])
  387. .setTool(artisansSaw, 1)
  388. .setTool(planer, 1)
  389. .addOutput(wood.makeStack(mistyPlankMeta) * 8)
  390. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2"])
  391. .create();
  392.  
  393. RecipeBuilder.get("basic")
  394. .setShapeless([wood.makeStack(i)])
  395. .setTool(artisansSaw, 2)
  396. .setTool(planer, 2)
  397. .setFluid(water * 100)
  398. .addOutput(wood.makeStack(mistyPlankMeta) * 10)
  399. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "lubricated_saws"])
  400. .create();
  401.  
  402. RecipeBuilder.get("basic")
  403. .setShapeless([wood.makeStack(i)])
  404. .setTool(artisansSaw, 3)
  405. .setTool(planer, 2)
  406. .setTool(heavySaw, 1)
  407. .addOutput(wood.makeStack(mistyPlankMeta) * 12)
  408. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3"])
  409. .create();
  410.  
  411. RecipeBuilder.get("basic")
  412. .setShapeless([wood.makeStack(i)])
  413. .setTool(artisansSaw, 4)
  414. .setTool(planer, 3)
  415. .setTool(heavySaw, 2)
  416. .setFluid(water * 250)
  417. .addOutput(wood.makeStack(mistyPlankMeta) * 16)
  418. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3", "lubricated_saws"])
  419. .create();
  420. }
  421. }
  422.  
  423. //Giant log is a special flower
  424. mods.recipestages.Recipes.addShapeless("free_woodcrafting", plankOak * 32, [logGiant]);
  425.  
  426. RecipeBuilder.get("basic")
  427. .setShapeless([logGiant])
  428. .setTool(artisansSaw, 1)
  429. .addOutput(plankOak * 64)
  430. .requireGameStages("ALL", ["woodcutting_1"])
  431. .create();
  432.  
  433. RecipeBuilder.get("basic")
  434. .setShapeless([logGiant])
  435. .setTool(artisansSaw, 1)
  436. .setFluid(water * 200)
  437. .addOutput(plankOak * 64)
  438. .setExtraOutputOne(plankOak * 32, 1)
  439. .requireGameStages("ALL", ["woodcutting_1", "lubricated_saws"])
  440. .create();
  441.  
  442. RecipeBuilder.get("basic")
  443. .setShapeless([logGiant])
  444. .setTool(artisansSaw, 1)
  445. .setTool(planer, 1)
  446. .addOutput(plankOak * 64)
  447. .setExtraOutputOne(plankOak * 64, 1)
  448. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2"])
  449. .create();
  450.  
  451. RecipeBuilder.get("basic")
  452. .setShapeless([logGiant])
  453. .setTool(artisansSaw, 2)
  454. .setTool(planer, 2)
  455. .setFluid(water * 400)
  456. .addOutput(plankOak * 64)
  457. .setExtraOutputOne(plankOak * 64, 1)
  458. .setExtraOutputTwo(plankOak * 32, 1)
  459. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "lubricated_saws"])
  460. .create();
  461.  
  462. RecipeBuilder.get("basic")
  463. .setShapeless([logGiant])
  464. .setTool(artisansSaw, 3)
  465. .setTool(planer, 2)
  466. .setTool(heavySaw, 1)
  467. .addOutput(plankOak * 64)
  468. .setExtraOutputOne(plankOak * 64, 1)
  469. .setExtraOutputTwo(plankOak * 64, 1)
  470. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3"])
  471. .create();
  472.  
  473. RecipeBuilder.get("basic")
  474. .setShapeless([logGiant])
  475. .setTool(artisansSaw, 4)
  476. .setTool(planer, 3)
  477. .setTool(heavySaw, 2)
  478. .setFluid(water * 1000)
  479. .addOutput(plankOak * 64)
  480. .setExtraOutputOne(plankOak * 64, 1)
  481. .setExtraOutputTwo(plankOak * 64, 1)
  482. .setExtraOutputThree(plankOak * 64, 1)
  483. .requireGameStages("ALL", ["woodcutting_1", "woodcutting_2", "woodcutting_3", "lubricated_saws"])
  484. .create();
Advertisement
Add Comment
Please, Sign In to add comment
Public Pastes
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!