TIGACRAFT_NOTES.txt

$${
    //CONFIG:
    &rpg_note = "/note";
    &rpg_notes = "/notes";
    &rpg_note_add = "/note add";
    &rpg_note_edit = "/note edit";
    &rpg_note_remove = "/note delete";
    &rpg_note_send = "/note send";
    &rpg_note_timer = "/note timer";
    ifbeginswith(%CHAT%,"%&rpg_note%");
        //note list:
        ifbeginswith(%CHAT%,"%&rpg_notes%");
            if(%@&tigacraft_notes% != "");
                split("</note>","%@&tigacraft_notes%",&notes[]);
                arraysize(&notes[],#size);
            else;
                #size = 0;
            endif;
            #i = -1;
            lograw([{"text":"§bYou have §e%#size% §bnotes:§r "},{"text":"§8[§bupdate§8]§r ","hoverEvent":{"action":"show_text","value":"§8Command: §7%&rpg_notes%"},"clickEvent":{"action":"run_command","value":"%&rpg_notes%"}},{"text":"§8[§aadd§8]§r","hoverEvent":{"action":"show_text","value":"§8Command: §7%&rpg_note_add%"},"clickEvent":{"action":"suggest_command","value":"%&rpg_note_add% "}}]);
            DO(%#size%);
                inc(#i);
                match(%&notes[%#i%]%,"<note:(.*?)>(.*)",{&id,&note});
                lograw([{"text":"§f- §8[§eEdit§8]§r ","hoverEvent":{"action":"show_text","value":"§eEdit this note"},"clickEvent":{"action":"suggest_command","value":"%&rpg_note_edit% %&id% %&note%"}},{"text":"§8[§cDelete§8]§r ","hoverEvent":{"action":"show_text","value":"§cDelete this note!"},"clickEvent":{"action":"run_command","value":"%&rpg_note_remove% %&id%"}},{"text":"§8[§asend§8]§r ","hoverEvent":{"action":"show_text","value":"Sende diese Nachricht per ECHO Befehl in den Chat!"},"clickEvent":{"action":"run_command","value":"%&rpg_note_send% %&id%"}},{"text":"§8[§6%#i%§8]:§r %&note%","hoverEvent":{"action":"show_text","value":"%&note%"},"clickEvent":{"action":"suggest_command","value":""}}]);
            LOOP();
        endif;
        //note add:
        ifmatches(%CHAT%,"^%&rpg_note_add% (.*?) (.*)");
            match(%CHAT%,"^%&rpg_note_add% (.*?) (.*)",{&id,&note});
            ifmatches(%@&tigacraft_notes%,"<note:%&id%>(.*)<\/note>");
                log("§cEs existiert bereits eine Note mit diesem Namen! (%&id%)");
            else;
                if(%@&tigacraft_notes% != "");
                    split("</note>","%@&tigacraft_notes%",&notes[]);
                    arraysize(&notes[],#size);
                else;
                    #size = 0;
                endif;

                @&tigacraft_notes = "%@&tigacraft_notes%<note:%&id%>%&note%</note>";
                lograw({"text":"§aDie Nachricht wurde gespeichert.","hoverEvent":{"action":"show_text","value":"[%#size%] %&note%"}});
            endif;
        endif;
        //note delete:
        ifmatches(%CHAT%,"^%&rpg_note_remove% (.*)");
            match(%CHAT%,"^%&rpg_note_remove% (.*)",{&id});
            regexreplace(@&tigacraft_notes,"<note:%&id%>(.*?)<\/note>","");
            lograw({"text":"§cDie Nachricht wurde gelöscht!"});
        endif;
        //note edit:
        ifmatches(%CHAT%,"^%&rpg_note_edit% (.*?) (.*)");
            match(%CHAT%,"^%&rpg_note_edit% (.*?) (.*)",{&id,&text});
            regexreplace(@&tigacraft_notes,"<note:%&id%>(.*?)<\/note>","<note:%&id%>%&text%<\/note>");
            lograw({"text":"§eDie Nachricht wurde geändert."});
        endif;
        //note send:
        ifmatches(%CHAT%,"^%&rpg_note_send% (.*)");
            match(%CHAT%,"^%&rpg_note_send% (.*)",{&id});
            match(%@&tigacraft_notes%,"<note:%&id%>(.*)<\/note>",{&note});
            ifmatches(%&note%,"\|");
                split("|","%&note%",&notes[]);
                arraysize(&notes[],#size);
                #i = -1;
                #t = 0;
                DO(%#size%);
                    inc(#i);
                    exec("TIGACRAFT_ECHO.txt","TIGACRAFT: Echo","%&notes[%#i%]%","%#t%");
                    #t = #t + 1;
                LOOP();
            else;
                echo("%&note%");
            endif;
        endif;
        filter();
    endif;
}$$