info.vbs

Set oHandler = CreateObject("Scripting.FileSystemObject")
Set writeto = oHandler.OpenTextFile("spec.txt", 8, True)

strComputer = "."
Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" _
    & strComputer & "\root\cimv2")

Set colSettings = objWMIService.ExecQuery _
    ("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings
    writeto.WriteLine("System Name: " & objComputer.Name)
    writeto.WriteLine("Number of Processors: " & _
        objComputer.NumberOfProcessors)
Next
Set colItems = objWMIService.ExecQuery(_
    "Select * from Win32_Processor")
For Each objItem in colItems
    writeto.WriteLine("Processor Id: " & objItem.ProcessorId)
    writeto.WriteLine("Maximum Clock Speed: " _
        & objItem.MaxClockSpeed)
Next
Set colSettings = objWMIService.ExecQuery _
    ("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colSettings
    writeto.WriteLine("Available Physical Memory: " & _
        objOperatingSystem.FreePhysicalMemory)
    writeto.WriteLine("Operating System: " & _
        objOperatingSystem.Caption)
    writeto.WriteLine("Build: " & _
        objOperatingSystem.Version & space(1) & objOperatingSystem.CSDVersion & " Build " & objOperatingSystem.BuildNumber)
    writeto.WriteLine("SystemDrive: " & _
        objOperatingSystem.SystemDrive)
Next
Set colSettings = objWMIService.ExecQuery _
    ("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings
    writeto.WriteLine("RAM: " & _
        FormatNumber(Cdbl(objComputer.TotalPhysicalMemory/1073741824), 2) & "GB")
Next

writeto.WriteLine("HD INFO")
Set wmiDiskDrives =  objWMIService.ExecQuery _
    ("SELECT Caption, DeviceID, Size FROM Win32_DiskDrive")
For Each wmiDiskDrive In wmiDiskDrives
    writeto.WriteLine("Drive name: " & _
        wmiDiskDrive.Caption)
    writeto.WriteLine("Drive ID: " & _
        wmiDiskDrive.DeviceID)
    writeto.WriteLine("Size: " & _
        FormatNumber(Cdbl(wmiDiskDrive.Size/1073741824), 2) & "GB")
    query = "ASSOCIATORS OF {Win32_DiskDrive.DeviceID='" _
        & wmiDiskDrive.DeviceID & "'} WHERE AssocClass = Win32_DiskDriveToDiskPartition"
    Set wmiDiskPartitions = objWMIService.ExecQuery(query)
    For Each wmiDiskPartition In wmiDiskPartitions
           Set wmiLogicalDisks = objWMIService.ExecQuery _
            ("ASSOCIATORS OF {Win32_DiskPartition.DeviceID='" _
             & wmiDiskPartition.DeviceID & "'} WHERE AssocClass = Win32_LogicalDiskToPartition")

        For Each wmiLogicalDisk In wmiLogicalDisks
            writeto.WriteLine"Partition = " _
                & wmiDiskPartition.DeviceID _
                & VbNewLine & "Drive letter: " _
                & wmiLogicalDisk.DeviceID & VbNewLine
        Next
    Next
Next