;;;; Auto Connecting To Server Gather - interSys Script ;;;;

;;;dialog;;;

alias AGJ $iif(!$dialog(AGJ),dialog -m AGJ AGJ,echo -a 04Error! 14The dialog already open ...)
dialog AGJ {
  title "interSys Gather Auto-Connect"
  size -1 -1 136 261
  option dbu
  box "Steam Location", 1, 4 38 128 68
  button "Find automatic location", 2, 7 52 60 11
  radio "X64", 3, 75 52 23 10
  radio "X32", 4, 108 52 23 10
  text "Windows Bit", 5, 84 43 33 8
  button "Find manually location", 6, 7 66 60 11
  text "Location", 7, 56 81 25 8
  edit "", 8, 8 90 122 10, disable
  box "Server Nickname", 9, 4 108 129 95
  button "Enter the type of the tag-team", 10, 11 119 116 10
  text "Tag-team A", 11, 9 131 31 8
  edit "", 12, 40 131 41 10, disable
  text "Tag-team B", 13, 9 142 31 8
  edit "", 14, 40 142 41 10, disable
  button "Enter your nickname in the server", 15, 9 159 116 10
  text "Nickname:", 16, 8 172 25 8
  edit "", 17, 36 172 63 10, disable
  check "Enable automatic nickname change", 18, 16 185 112 10
  box "Anti-Cheat location", 19, 4 201 129 56
  button "Find manually anti-cheat location", 20, 22 210 89 11
  text "Location:", 21, 51 224 25 8
  edit "", 22, 8 232 122 10, disable
  check "Enable automatic run anti-cheat", 23, 16 243 95 10
  check "Enable Gather-Autojoin", 25, 10 25 95 10
  box "General", 24, 4 17 129 20
  text "interSys Gather Auto-Connect", 26, 28 7 78 8
}
;;;dialog-event;;;

On *:Dialog:AGJ:*:*: {
  if ($devent == init) {
    if (%Windows == 64) did -c $dname 3
    if (%Windows == 32) did -c $dname 4
    if (%SLocation) did -a $dname 8 %SLocation
    if (%anick == on) did -c $dname 18
    if (%acheat == on) did -c $dname 23
    if (%AGJ == on) did -c $dname 25
    if (%tag.a) did -a $dname 12 %tag.a
    if (%tag.b) did -a $dname 14 %tag.b
    if (%nickn) did -a $dname 17 %nickn
    if (%ACLocation) did -a $dname 22 %ACLocation
  }
  if ($devent == sclick) {
    if ($did == 2) {
      if ($did(3).state) || ($did(4).state) {
        FindS
      }
      else { did -ra $dname 8 You need to select the bit of your windows }
    }
    elseif ($did(3).state) { set %Windows 64 }
    elseif ($did(4).state) { set %Windows 32 }
    if ($did == 6) {
      set %SLocation $$sfile(C:\*Steam.exe,Find your Steam.exe)
      if ($dialog(AGJ)) {
        did -ra AGJ 8 %SLocation
      }
      echo -a 1(12AGJ1) Steam location found:4 %SLocation
    }
    if ($did == 10) {
      set %tag.a $input(Type tag team A,eg,Tag Settings)
      set %tag.b $input(Type tag team B,eg,Tag Settings)
      did -ra AGJ 12 %tag.a | did -ra AGJ 14 %tag.b
    }
    elseif ($did == 15) { set %nickn $input(Type your nickname on the server,eg,Nickname Settings) | did -ra AGJ 17 %nickn }
    elseif ($did == 18) {  Set %anick $iif($did(18).state == 1,ON,OFF) }
    elseif ($did == 20) {
      set %ACLocation $$sfile(C:\,Find your Anti-Cheat.exe/AntiCheat.exe)
      if ($dialog(AGJ)) {
        did -ra AGJ 22 %ACLocation
      }
    }
    elseif ($did == 23) { Set %acheat $iif($did(23).state == 1,ON,OFF) }
    elseif ($did == 25) { Set %AGJ $iif($did(25).state == 1,ON,OFF) }
  }
}

;;;on-text;;;

On *:text:*:? : {
  if (server isin $1-) && (autorun isin $1-) && (%AGJ == on) {
    noop $regex($strip($1-),Gather (.+?): \(Team-(.+?)\) Server: (.+?) $chr(44) $+ pass: (\d{3})) $chr(44) $+ Vent:/i)
    if (%anick == on) { $iif($regml(2) == A,$NameChanger(%tag.a $+ %nickn), $NameChanger(%tag.b $+ %nickn)) }
    if (%acheat == on) { run %ACLocation }
    echo -ag 14Connecting to the gather, please wait ...
    .timer 1 40 .msg #vGames.Gathers 14 Auto connect to server gather 04(12interSys Script04)
    $iif(%acheat == on,.timer 1 10,.timer 1 5) run $+(steam://connect/,$regml(3),/,$regml(4))
  }
}
;;;aliases;;;

alias NameChanger {
  var %path = " $+ $remove(%SLocation,steam.exe) $+ steamapps\common\Half-Life\cstrike\config.cfg"
  noop $read(%path, s, name)
  write $+(-l,$readn) %path name $+($chr(34),$1,$chr(34))
  return
}
alias FindS {
  if (!$1) {
    var %x = 1
    while ($disk(%x) != $null) {
      if ($disk(%x).type == fixed) && ($findfile($+($disk(%x).path,$iif(%Windows == 64,Program Files (x86),Program Files)\),Steam.exe,0)) {
        set %SLocation $findfile($+($disk(%x).path,$iif(%Windows == 64,Program Files (x86),Program Files)\),Steam.exe,1)
        break
      }
      inc %x
    }
    if ($dialog(AGJ)) && (%SLocation) { did -ra AGJ 8 %SLocation }
    if (%SLocation) echo -a 14 Steam location found:4 %SLocation
    elseif (!%SLocation) {
      echo -a 14 Steam Location not found automatic ,try the manually way.
      if ($dialog(AGJ)) { did -ra AGJ 8 Steam Location not found automatic ,try the manually way. }
    }
  }
  elseif ($1 == Manual) { set %SLocation $$sfile(C:\*Steam.exe,Find your Steam.exe) | if ($dialog(AGJ)) { did -ra AGJ 8 %SLocation } | echo -a 14) Steam location found:4 %SLocation }
}

menu * {
  Auto Gather-Server Connect:AGJ
}