imagemagick-optimize-small-or-medium-jpg-files.bat

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS
COLOR 0A
TITLE USE IMAGEMAGICK’S CACHE FILES TO OPTIMIZE SMALL AND MEDIUM-SIZED JPG FILES

:----------------------------------------------------------------------------------

REM FOR USE ON JPG SIZES 1-5 MEGABYTES
REM USE MY OTHER SCRIPTS FOR < 5 MEGABYTE JPG FILES

REM PLACE THIS SCRIPT IN THE FOLDER CONTAINING THE JPG FILES
REM THE OPTIMIZED IMAGES WILL BE PLACED IN A SUB FOLDER NAMED "OUTPUT"

REM MAKE SURE TO POINT THE VARIABLE "CONVERT" BELOW TO THE FULL PATH
REM OF IMAGEMAGICK'S "CONVERT.EXE" FILE.

REM SAVE THIS SCRIPT USING A .BAT EXTENSION

:----------------------------------------------------------------------------------

PUSHD "%~dp0"
IF NOT "%1"=="MAX" START /MAX CMD /D /C %0 MAX & GOTO :EOF

:----------------------------------------------------------------------------------

SET CONVERT=%ProgramFiles%\ImageMagick\convert.exe

:----------------------------------------------------------------------------------

REM CREATE OUTPUT FOLDERS
IF NOT EXIST "Cache_Files" MD "Cache_Files"
IF NOT EXIST "Output" MD "Output"

:----------------------------------------------------------------------------------

REM FIND ALL JPG FILES AND CONVERT THEM TO MPC FORMAT
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
SET CNT=0
FOR %%G IN (*.jpg) DO (
    FOR /F "TOKENS=1-2" %%H IN ('identify +ping -format "%%w %%h" "%%G"') DO (
        SET /A CNT+=1
        ECHO=
        ECHO [!CNT!] CACHING FILES: %%~nG.mpc ^+ %%~nG.cache
        ECHO=
        ECHO :----------------------------------------------------------------------------------
        ECHO=
        "%CONVERT%" "%%G" -monitor -filter Triangle -define filter:support=2 -thumbnail "%%Hx%%I" -strip -unsharp 0.25x0.08+8.3+0.045 -dither None -posterize 136 -quality 91 -define jpeg:fancy-upsampling=off -define png:compression-filter=5 -define png:compression-level=9 -define png:compression-strategy=1 -define png:exclude-chunk=all -interlace none -colorspace sRGB "Cache_Files\%%~nG.mpc"
        CLS
    )
)

:----------------------------------------------------------------------------------
:MAKE_JPG
:----------------------------------------------------------------------------------

REM CONVERT CACHED FILES INTO OPTIMIZED JPG IMAGES
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
SET CNT=0
FOR %%J IN ("Cache_Files\*.mpc") DO (
    SET /A CNT+=1
    ECHO=
    ECHO [!CNT!] CREATING JPG: %%~nJ.jpg
    ECHO=
    "%CONVERT%" "%%J" -monitor "Output\%%~nJ.jpg"
    CLS
    )
)

:----------------------------------------------------------------------------------

REM DELETE THE TEMP CACHE FOLDER AND OPEN THE OUTPUT FOLDER IN EXPLORER
:END
RD /S /Q "Cache_Files"
START "" /MAX EXPLORER "Output"