Cats CPC

5 REM Cats CPC -- port by 240-185
10 REM ON BREAK GOSUB 1150 ' uncomment this line if you don't have a CPC464
20 MODE 2
30 CLS:FOR N = 1 TO 50:PRINT:NEXT N:GOSUB 910:PRINT:PRINT
40 INPUT "(E)ASY OR (H)ARD";d$
50 d$=UPPER$(MID$(d$,1,1))
60 IF d$="H" THEN DEFINT a-s:DEFINT u-z
70 IF d$<>"E" AND d$<>"H" THEN MODE 2:GOTO 40 ELSE MODE 2
80 S = 0:W = 0:V = 1:H = 0
90 GOSUB 800
100 FOR N = 1 TO 50
110 PRINT
120 FOR D = 1 TO 100
130 NEXT D
140 NEXT N
150 CLS
160 PRINT "  YOUR MISSION, QUITE SIMPLY, IS TO COUNT THE CATS. "
170 PRINT
180 INPUT "ENTER YOUR NAME AND OR HANDLE FOR THE SCOREBOARD:"; N$
190 PRINT:PRINT "OK "; N$; " ARE YOU READY THEN? "
200 INPUT Z$
210 FOR Y = 1 TO LEN(N$):Z = RND(1):NEXT Y
220 FOR Y = 1 TO LEN(Z$):Z = RND(1):NEXT Y
230 CLS
240 C = 0
250 GOSUB 590
260 FOR N = 1 TO 3
270 IF RND(1) > 0.25 THEN GOTO 290
280 GOSUB 590
290 PRINT
300 NEXT N
310 PRINT "PRETTY LAME EH? ";
320 GOSUB 630
330 PRINT "YEA NOW WE GONNA PLAY FOR REAL."
340 L = 1:GOSUB 830
350 REM FAST ROUND
360 FOR D = 1 TO 1500:NEXT D
370 C = 0:CLS
380 PRINT "--------- LEVEL ";L;" ---------"
390 FOR N = 1 TO 80:PRINT TAB(10);81-N:FOR D = 1 TO E(L):NEXT D:NEXT N
400 FOR N = 1 TO 50
410 IF RND(1) < T(L) THEN GOTO 430
420 GOSUB 590:GOTO 440
430 PRINT
440 FOR D = 1 TO R(L):NEXT D:NEXT N
450 FOR N = 1 TO 80:PRINT TAB(N/4);".":FOR D = 1 TO E(L):NEXT D:NEXT N
460 GOSUB 630
470 IF (S + W <> 2) THEN GOTO 490
480 PRINT "MY MISSION IS TO MAKE SURE YOU NEVER SEE LEVEL 10."
490 IF (C=U) THEN L = L + 1
500 IF (C<>U) THEN L = L - 1
510 IF (L < 1) THEN L = 1
520 IF (L > 10) THEN L = 10
530 GOSUB 830
540 IF (H > 10) THEN GOTO 560
550 GOTO 360
560 CLS:PRINT "DAM, YOU BEAT ME."
570 END
580 REM PUT THING
590 I = INT(RND(1)*V+1):IF I=1 THEN C=C+1
600 X = RND(1) * 40 :PRINT TAB(X);A$(I)
610 RETURN
620 REM SCORE RESULT
630 WHILE INKEY$<>"":WEND
640 INPUT "HOW MANY CATS DID YOU COUNT "; U
650 PRINT
660 IF C <> U THEN GOTO 700
670 S=S+1:PRINT "YAY! YOU GOT IT!"
680 IF L = 10 THEN H = H + 1
690 GOTO 730
700 W=W+1:PRINT "ER, NO."
710 Z = U:IF Z > 10 THEN Z = 10
720 FOR D = 1 TO Z:T(L) = RND(1):NEXT D
730 T(L) = S+W:PRINT "YOUR SCORE IS ";S;"/"T(L)"
740 RETURN
750 REM PUT A SOMETHING
760 FOR N = 1 TO 50
770 IF RND(1) < T(L) THEN GOTO 790
780 GOSUB 590
790 RETURN
800 DATA CAT,DOG,BADGER,SNAKE,BAT,MAT,HAT,ELEPHANT,RAT,CAR
810 RESTORE 800:DIM A$(10):FOR i=1 TO 10:READ A$(i):NEXT
820 RETURN
830 v=l+1:IF v>10 THEN v=10
840 RESTORE 870:FOR j=1 TO 10:READ r(j):NEXT
850 RESTORE 880:FOR j=1 TO 10:READ e(j):NEXT
860 RESTORE 890:FOR j=1 TO 10:READ t(j):NEXT
870 DATA 80,70,65,62,60,55,52,50,45,48
880 DATA 60,55,50,45,42,40,38,35,32,30
890 DATA 0.8,0.75,0.6,0.5,0.4,0.4,0.25,0.2,0.15,0.1
900 RETURN
910 PRINT "                                  ."
920 PRINT "                          ,*:. .;SC,"
930 PRINT "                          ;CCC#CCCC+"
940 PRINT "                           SCCCCCCCS"
950 PRINT "                           :CCCCCC#:"
960 PRINT "                         .,+CCCCCC*"
970 PRINT "                   .:*%S#CCCCCCCCC#"
980 PRINT "                 ,?#CCCCCCCCCCCCCCC."
990 PRINT "                *CCCCCCCCCCCCCCCCC+"
1000 PRINT "               ?CCCCCCCCCCCCCCCC%."
1010 PRINT "              *CCCCCCCCCCCCCCCC?"
1020 PRINT "             ,CCCCCCCCCCCCCCCCC."
1030 PRINT "             ?CCCCCCCCCCCC##CC#"
1040 PRINT "            :CCCCCCCCCCCC;  *CC."
1050 PRINT "          ,?CCCCCCCCCCCC:   .#C%."
1060 PRINT "      .:*SCC#S#CCCCCCCCCS%,  .%CC:"
1070 PRINT "    :%C#%*:.   ,,,,,,,,,,,.    .:."
1080 PRINT "    #C*"
1090 PRINT "    :%%,
1100 PRINT "      .."
1110 PRINT
1120 PRINT "      CATS GAME BY RUE MOHR"
1130 PRINT "                   2025"
1140 RETURN
1150 PRINT"CHEATER CHEATER CHEATER!!!!!!!":RUN