Ver se o resultado do Enem já saiu

#include <Inet.au3>

; Desabilita o menu padrão do AU3
Opt("TrayMenuMode", 1)

; Cria um item no menu systray pra sair
$quersair = TrayCreateItem("Sair :o")

; Se apresenta
MsgBox(0, "Oi :D", "Este programa se conecta de tempo em tempo no site do Inep e vê se o resultado do Enem " & (@YEAR-1) & " já saiu." & @CRLF & "Na próxima tela, digite o intervalo, em SEGUNDOS, para verificar se o resultado já saiu." & @CRLF & "Não exagere: colocar muito pouco tempo pode fazer o firewall do servidor bugado do Inep te dar ban." & @CRLF & "Nada que resetar seu modem não resolva... mas recomendo uns 5 minutos (que é igual a 300 segundos, tá?).")

; Pergunta quanto tempo o tempo tem
$tempo = InputBox("Preparado?", "Digite o intervalo, EM SEGUNDOS.")

If Not $tempo Then ; não digitou nada ou cancelou
    Exit ; fechar
Else
    ; converte pra valor inteiro... o que tem de usuário engraçadinho...
    ; ah, e multiplica por 1000 pq trabalhamos com milissegundos
    $tempo = Int($tempo)*1000
EndIf

MsgBox(0, "Ok", "Ok, já estou trabalhando. Só clique em Ok. Abra o Facebook, Netflix, assista àlgumas séries, jogue Lol/Battlefield/GTA ou qualquer outra coisa. Eu aviso quando o resultado sair." & @CRLF & "Eu não inicio junto com o Windows... até pq vc só vai me usar uma vez esse ano (talvez na vida toda). Então, se reiniciar o PC, me ative novamente. Ah, e se quiser que eu pare de trabalhar, meu ícone está ali no canto, ao lado do relógio (talvez vc tenha que clicar na setinha pra cima pra expandir). Só clicar com botão direito e clicar em Sair." & @CRLF & "Relaxe :) (se puder)")

; Inicia a função principal
AdlibRegister("mainloop", $tempo) ; repete a cada minuto

While 1
    ; Detecta se o cara clicou no botão de sair
    Switch TrayGetMsg()
        Case $quersair ; clicou :o
            Exit ; okay...
    EndSwitch
WEnd

; Função principal
Func mainloop()
    ; Obtém o código da página maldita
    $source = _INetGetSource("http://sistemasenem2.inep.gov.br/resultadosenem/home.seam")
    ; Se ANO_ATUAL-1 (2016-1=2015...) for encontrado na página, então saiu!
    If StringInStr($source, @YEAR-1) Then
        ; Mostra a mensagem fodástica e pergunta se quer abrir
        $iMsgBoxAnswer = MsgBox(52,"AEEEEHOOOOO","A NOTA DO ENEM SAIU :D :D :D" & @CRLF & "(só espero que isso seja, realmente, uma coisa boa)" & @CRLF & "" & @CRLF & "Abrir agora?")
        Select
            Case $iMsgBoxAnswer = 6 ; Quer abrir
                ; Abre o site
                ShellExecute("http://sistemasenem2.inep.gov.br/resultadosenem/")
                Exit ; nada mais a fazer por aqui
           Case $iMsgBoxAnswer = 7 ; Não quer abrir
                MsgBox(0, "", ":o")
                Exit ; nada mais a fazer por aqui
        EndSelect
    EndIf
EndFunc