prontera,155,111,5	script	Sample#autopot	757,{
function getHealingItem;

OnSetup:
mes "Enable / Disable Auto Potion ?";
switch( select( "Settings",( @Active )?"Disable":"Enable" )){
	Case 1:
		do{
			next;
			mes "HP Item : ^FF0000"+getitemname( @HPItem )+"^000000";
			mes "SP Item : ^FF0000"+getitemname( @SPItem )+"^000000";
			mes " ";
			mes "^0055FFAutoPot Condition :^000000";
			mes "HP below ^FF0000"+@HP+" "+( ( @Mode == 1 )?"%":"" )+"^000000";
			mes "SP below ^FF0000"+@SP+" "+( ( @Mode == 1 )?"%":"" )+"^000000";
			mes "Time Interval : ^FF0000"+@MS+"^000000 ms.";
			next;
			set .@Menu,select( "[ ^0055FF"+( (@Mode == 1)? "Percent":"Value" )+"^000000 ] Mode",
							"[ ^0055FF"+( (@Mode == 1)? @HP+"%":@HP )+"^000000 ]HP - ^0055FF"+getitemname( @HPItem )+"^000000",
							"[ ^0055FF"+( (@Mode == 1)? @SP+"%":@SP )+"^000000 ]SP - ^0055FF"+getitemname( @SPItem )+"^000000",
							"[ ^0055FF"+@MS+"^000000 ]Interval",
							"Close" );
			switch( .@Menu ){
				Case 1:
					set @Mode,select("Based on HP / SP ^FF0000Percent^000000:Based on HP / SP ^FF0000Value^000000");
					break;
				Case 2:
					mes "What Item use for ^FF0000HP^000000 ?";
					set @HPItem,getHealingItem();
					mes "Heal HP when below X "+( ( @Mode == 1 )?"%":"Value" );
					input @HP,1,(( @Mode == 1 )? 99:HP );
					break;
				Case 3:
					mes "What Item use for ^FF0000SP^000000 ?";
					set @SPItem,getHealingItem();
					mes "Heal SP when below X "+( ( @Mode == 1 )?"%":"Value" );
					input @SP,1,(( @Mode == 1 )? 99:SP );
					break;
				Case 4:
					mes "Healing Interval :";
					mes "60 Seconds = 60000";
					mes "1 Seconds = 1000";
					mes "0.1 Seconds = 100";
					input @MS,100,60000;
					break;
			}
		}while( .@Menu < 5 );
		break;
	Case 2:
		percentheal 100,100;
		set @Active,!@Active;
		message strcharinfo(0),"Autopot "+( ( @Active )?"Enabled":"Disabled" );
		close2;
		while( @Active ){
			set .@CurrentHP,( ( @Mode == 1 )? (( HP * 100 )/ MaxHP ):HP );
			set .@CurrentSP,( ( @Mode == 1 )? (( SP * 100 )/ MaxSP ):SP );
			if( .@CurrentHP < @HP && countitem( @HPItem ) ) consumeitem( @HPItem,1 );
			if( .@CurrentSP < @SP && countitem( @SPItem ) ) consumeitem( @SPItem,1 );
			sleep2 @MS;
		}
		end;
}
close;

function	getHealingItem	{
	getinventorylist;
	for( set .@i,0; .@i < @inventorylist_count; set .@i,.@i + 1 )
		if( getiteminfo( @inventorylist_id[.@i],2 ) == 0 ){
			set .@ItemList[getarraysize(.@ItemList)],@inventorylist_id[.@i];
			set .@Menu$,.@Menu$ + getitemname( @inventorylist_id[.@i] )+":";
		}
	set .@i,( select( .@Menu$ ) - 1 );
	return .@ItemList[.@i];
}

}