Specialist VZO ETH

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © NKactive
// Original code from Specialist
//@version=5

strategy("Specialist VZO ETH", overlay=false, initial_capital=1000, default_qty_type=strategy.percent_of_equity, default_qty_value=100, pyramiding=0, slippage=1)

import EliCobra/CobraMetrics/4 as cobra
//// PLOT DATA
disp_ind = input.string ("None" , title = "Display Curve" , tooltip = "Choose which data you would like to display", options=["Strategy", "Equity", "Open Profit", "Gross Profit", "Net Profit", "None"], group = "🐍 𝓒𝓸𝓫𝓻𝓪 𝓜𝓮𝓽𝓻𝓲𝓬𝓼 🐍")
pos_table = input.string("Middle Left", "Table Position", options = ["Top Left", "Middle Left", "Bottom Left", "Top Right", "Middle Right", "Bottom Right", "Top Center", "Bottom Center"], group = "🐍 𝓒𝓸𝓫𝓻𝓪 𝓜𝓮𝓽𝓻𝓲𝓬𝓼 🐍")
type_table = input.string("None", "Table Type", options = ["Full", "Simple", "None"], group = "🐍 𝓒𝓸𝓫𝓻𝓪 𝓜𝓮𝓽𝓻𝓲𝓬𝓼 🐍")
plot(cobra.curve(disp_ind))
cobra.cobraTable(type_table, pos_table)
//
// ****************************************************************************************************************************************************************
//

//VZO
src0 = input.source(high, 'Source')
len = input.float(28.5, 'VZO Length', minval=1, step=0.5)
flen = input.float(4.0, 'Fisher Length', minval=1, step=0.5)
ud = input.int(8, 'Updown val')
var VZO_Intraday = input.bool(true, 'Smoothing')
var repaint = input.bool(false, 'Allow Repainting')
// Sauce
get_close = close[repaint ? 0 : 1]
get_vol = volume[repaint ? 0 : 1]
sym = syminfo.tickerid
VZO(length, get_close, vol) =>
    Volume_Direction = get_close > get_close[3] ? vol : -vol
    VZO_volume = ta.linreg(Volume_Direction, int(length), 0)
    Total_volume = ta.linreg(vol, int(length), 0)
    100 * VZO_volume / Total_volume

VZO_ = VZO(len, get_close, get_vol)
if VZO_Intraday
    VZO_ := ta.ema(VZO_, 9)

// Fish
fsrc = VZO_
MaxH = ta.highest(fsrc, int(flen))
MinL = ta.lowest(fsrc, int(flen))
var nValue1 = 0.0
var nFish = 0.0
nValue1 := 0.33 * 2 * ((fsrc - MinL) / (MaxH - MinL) - 0.5) + 0.67 * nz(nValue1[1])
nValue2 = (nValue1 > 0.99 ? 0.999 : (nValue1 < -0.99 ? -0.999 : nValue1))
nFish := 0.5 * math.log((1 + nValue2) / (1 - nValue2)) + 0.5 * nz(nFish[1])
f1 = nFish
f2 = nz(nFish[1])
stat = 0
fzvzo_up = f1 > f2
fzvzo_down = f1 < f2
// Can use stat or fzvzoshort and fzvzoshort for firing buy/sell signals
fzvzoshort = ta.crossunder(f1, f2)
fzvzolong = ta.crossover(f1, f2)
if fzvzolong
    stat := 1
if fzvzoshort
    stat := -1

//PLOT
plot(f1, color=color.blue)
plot(f2, color=color.yellow)
plot(stat, color=color.green)

// ****************************************************************************************************************************************************************




// ****************************************************************************************************************************************************************
// Call combine signals and execute buy/sell positions within timeframe
//.****************************************************************************************************************************************************************
// Date Range To Include
startDate = timestamp("2018-01-01T00:00")
endDate = time
// Check if the current timestamp is within the restricted range
inRestrictedRange = time >= startDate and time <= endDate
//
// Buy Signals on overbought and oversold
//
if inRestrictedRange and fzvzo_up// ADD OTHER BUY SIGNAL BOOLS
    strategy.entry("My Long Entry Id", strategy.long, 100)
if inRestrictedRange and fzvzo_down // ADD OTHER BUY SIGNAL BOOLS
    strategy.entry("My Short Entry Id", strategy.short, 100)